awk:

    awk,可以说是一门独立的语言, 对于文本的处理有着很强大的功能. 并能对处理的结果做各种样式的处理.现在来对它做一些总结

awk: 报告生成器 

基本语法

awk [options] 'program' file file ...

awk [options] 'PATTERN{action}' file file ...

-F CHAR：输入分隔符

-F CHAR：输入分隔符

1、awk的输出

 

print item1, item2,...

要点：

(1) 各项目之间使用逗号分隔，而输出时则使用输出分隔符分隔；

[root@php5_6 data]# awk -F: '{print $1,$7}' /etc/passwd =>如,以':' 分隔 /etc/passwd中的行,并取第1,第7列输出

(2) 输出的各item可以字符串或数值、当前记录的字段、变量或awk的表达式；数值会被隐式转换为字符串后输出；

(3) print后面item如果省略，相当于print $0；输出空白，使用pirnt ""；

[root@php5_6 data]# awk -F: '{print}' /etc/passwd

2、awk的变量

内置变量，自定义变量

2.1 内置变量

FS：Field Seperator, 输入时的字段分隔符

 awk 'BEGIN{FS=":"}{print $1,$7}' /etc/passwd  ==>当然,这种写法,真心不如 awk -F:  '{print $1,$7}' /etc/passwd

RS：Record Seperator, 输出行分隔符 

OFS: Output Field Seperator, 输出时的字段分隔符;

[root@php5_6 data]# awk 'BEGIN{FS=":";OFS="*"}{print $1,$7}' /etc/passwd 例如,输入时指定以 ":" 为分隔符,输出时以 "*" 为分隔符

ORS: Outpput Row Seperator, 输出时的行分隔符；  =>行分隔符一般默认为 \n, 很少用到,这里不做演示

NF：Numbers of Field，字段数

[root@php5_6 data]# awk -F: '{print NF}' /etc/passwd  =>查看文件中,每一行以':'分隔之后,有多少列

NR：Numbers of Record, 行数；所有文件的一并计数；

 [root@php5_6 data]# awk -F: '/root/{print NR}' /etc/passwd =>查看包含有root字串的行所处的行号

FNR：行数；各文件分别计数； 

 将/etc/passwd, /etc/group 两个文件拷到 /tmp下,

[root@php5_6 tmp]# awk -F: '{print NR,FNR,$0}' passwd group =>这样是查看,这两个文件 合并显示每一行,所处的行号,以及各自在自己文件中所处的行号

ARGV：数组，保存命令本身这个字符，awk '{print $0}' 1.txt 2.txt，意味着ARGV[0]保存awk,  ARGV[1] 是 1.txt ,ARGV[2] 是 2.txt   

ARGC: 保存awk命令中参数的个数； 

FILENAME： awk正在处理的当前文件的名称；

[root@php5_6 tmp]# awk -F: '/root/{print ARGV[0],ARGV[1],ARGV[2],ARGC,FILENAME}' passwd group  =>查看该命令处理生成的数组,以及正在处理的文件
awk passwd group 3 passwd 
awk passwd group 3 passwd 
awk passwd group 3 group

2.2 可自定义变量

-v var_name=VALUE

当然,我们也可以在BEGIN模式中定义变量,还可以在action中定义 

变量名区分字符大小写； 

(1) 可以program中定义变量；

(2) 可以命令行中通过-v选项自定义变量；

在BEGIN中定义

[root@php5_6 tmp]# awk 'BEGIN{wh="how are you";FS=":"}/root/{print wh,$1}' passwd 
how are you root 
how are you operator

在命令选项中定义

[root@php5_6 tmp]# awk -v wh="hi" 'BEGIN{FS=":"}/root/{print wh,$1}' passwd

3、awk的printf命令 =>这个用得足够多了......

命令的使用格式：printf format, item1, item2,...

要点：

(1) 要指定format；

(2) 不会自动换行；如需换行则需要给出\n

(3) format用于为后面的每个item指定其输出格式；

format格式的指示符都%开头，后跟一个字符：

%c: 显示字符的ASCII码；

%d, %i: 十进制整数；

%e, %E: 科学计数法显示数值；

%f: 显示浮点数； =>默认是6位精度

%g, %G: 以科学计数法格式或浮点数格式显示数值；

%s: 显示字符串；

%u: 显示无符号整数；

%%: 显示%自身；

修饰符：

#：显示宽度

-：左对齐

+：显示数值的符号

.#: 取值精度

显示结果,每列占位10个字符, 并且左对齐显示

[root@php5_6 tmp]# awk -v wh="hi" 'BEGIN{FS=":"}/root/{printf "%-10s%-10s\n", wh,$1}' passwd 
hi root 
hi operator

[root@php5_6 tmp]# awk 'BEGIN{printf "%15.3f\n",99999}' =>值得注意的是, 长度修饰后面,加上 .# 则是指明要输出的数值精确长度

4、awk输出重定向

print items > output-file

print items >> output-file

print items | command

特殊文件描述符：

/dev/stdin: 标准输入

/dev/stdout: 标准输出

/dev/stderr: 错误输出  

==>以上使用的可能性不大,这里略过

5、awk的操作符

算术操作符：

x+y

x-y

x*y

x/y

x**y, x^y

x%y

-x：负值

+x：转换为数值

字符串操作符：连接

赋值操作符：

=

+=

-=

*=

/=

%=

^=

**=

++

--

如果模式自身是=号，要写为/=/

比较操作符：

<

<=

>

>=

==

!=

~：模式匹配，左边的字符串能够被右边的模式所匹配为真，否则为假；

!~:

逻辑操作符：

&&： 与

||：或

条件表达式:

selector?if-true-expression:if-false-expression

# awk -F: '{$3>=500?utype="common user":utype="admin or system user";print $1,"is",utype}' /etc/passwd

函数调用：

function_name(argu1,argu2)

6、模式

(1) Regexp: 格式为/PATTERN/

仅处理被/PATTERN/匹配到的行；

[root@php5_6 tmp]# awk -F: '/root/{print $1,$7}' passwd    =>例如,匹配含有 root 字串的行
root /bin/bash 
operator /sbin/nologin

(2) Expression: 表达式，其结果为非0或非空字符串时满足条件；

仅处理满足条件的行；

[root@php5_6 tmp]# awk -F: '$3>500{print $1,$7}' passwd 
robert /bin/bash 
gentoo /bin/bash 
nginx /bin/bash

(3) Ranges: 行范围，此前地址定界，startline, endline

仅处理范围内的行

[root@php5_6 tmp]# awk -F: 'NR>25{printf "%-15s%15s%15s\n",$1,$7,NR}' passwd    ==>显示行号大于25行的行
L Server 26 
rob /bin/bash 27 
robert /bin/bash 28 
gentoo /bin/bash 29 
nginx /bin/bash 30

(4) BEGIN/END: 特殊模式，仅在awk命令的program运行之前（BEGIN）或运行之后（END）执行一次；

(5) Empty:空模式，匹配任意行；

7、常用的action

(1) Expressions

(2) Control statements

(3) Compound statements

(4) input statements

(5) output statements

8、控制语句

8.1 if-else

格式：if (condition) {then body} else {else body}

# awk -F: '{if ($3>=500) {print $1,"is a common user"} else {print $1, "is an admin or system user"}}' /etc/passwd

# awk '{if (NF>=8) {print}}' /etc/inittab

8.2 while

格式：while (condition) {while body}

# awk '{i=1; while (i<=NF){printf "%s ",$i;i+=2};print ""}' /etc/inittab

# awk '{i=1; while (i<=NF){if (length($i)>=6) {print $i}; i++}}' /etc/inittab

length()函数：取字符串的长度

8.3 do-while循环

格式：do {do-while body} while (condition)

8.4 for循环

格式：for (variable assignment; condition; iteration process) {for body}

# awk '{for (i=1;i<=NF;i+=2){printf "%s ",$i};print ""}' /etc/inittab =>同一行不同列在循环时不想换行输出,用这个 printf "%s "

# awk '{for (i=1;i<=NF;i++){if (length($i)>=6) print $i}}' /etc/inittab

在/etc/passwd 中以 : 分隔, 打印奇数列

awk 'BEGIN{FS=":"}{if(NF>5){lengths=split($0,line,":");for(ib=0;ib<=lengths;ib++){if(ib%2){printf "%s ",line[ib]}};print NR"\n"}}' /etc/passwd


for循环可用来遍历数组元素：

语法：for (i in array) {for body}

8.5 case语句

语法：switch (expression) {case VALUE or /RGEEXP/: statement1;... default: stementN}

8.6 循环控制

break

continue

8.7 next

提前结束对本行的处理进而进入下一行的处理；  也就是比brealk,continue更狠的进入下一行

# awk -F: '{if($3%2==0) next;print $1,$3}' /etc/passwd   =>id号为奇数的才显示其用户名和id号

# awk -F: '{if(NR%2==0) next; print NR,$1}' /etc/passwd

9、数组

关联数组：

array[index-expression]

index-expression: 可以使用任意字符串; 如果某数组元素事先不存在，那么在引用时，awk会自动创建此元素并将其初始化为空串；因此，要判断某数组是否存在某元素，必须使用“index in array”这种格式；

A[first]="hello awk"

print A[second]

要遍历数组中的每一个元素，需要使用如下特殊结构：

for (var in array) {for body}

其var会遍历array的索引；

state[LISTEN]++

state[ESTABLISHED]++

# netstat -tan | awk '/^tcp/{++state[$NF]}END{for (s in state) {print s,state[s]}}'

# awk '{ip[$1]++}END{for (i in ip) {print i,ip[i]}}' /var/log/httpd/access_log

删除数组元素：

delete array[index]

10、awk的内置函数

split(string,array[,fieldsep[,seps]])：

功能：将string表示的字符串以fieldsep为分隔符进行切片，并切片后的结果保存至array为名的数组中；数组下标从1开始；

root:x:0:0::/root:/bin/bash

user[1]="root", user[2]

此函数有返回值，返回值为切片后的元素的个数

# netstat -tn | awk '/^tcp/{lens=split($5,client,":");ip[client[lens-1]]++}END{for (i in ip) print i,ip[i]}'

[root@mode_11 ~]# netstat -tna|awk '/^tcp/{stat[$NF]++}END{for(i in stat){print i,stat[i]}}' 查看不同状态的数据量


[root@mode_11 httpd]# awk '{arr[$1]++}END{for(i in arr){print i,arr[i]}}' /var/log/httpd/access_log   ==>统计httpd服务各ip访问的次数

length(string)

功能：返回给定字串的长度

[root@mode_11 httpd]# awk 'BEGIN{str="this is a very good test!";ok=length(str);print ok}'

25

substr(string,start[,length])

功能：从string中取子串，从start为起始位置为取length长度的子串；

截取string中,第五个字符开始,一直到末尾的字串,

[root@mode_11 httpd]# awk 'BEGIN{str="this is a very good test!";ok=substr(str,5);print ok}'

 is a very good test!

截取string中,第五个字符开始,及其后边五个字串

[root@mode_11 httpd]# awk 'BEGIN{str="this is a very good test!";ok=substr(str,5,5);print ok}'

 is a