该楼层疑似违规已被系统折叠 隐藏此楼查看此楼
@echo off
cd /d %~dp0
if /i "%PROCESSOR_IDENTIFIER:~0,3%" == "X86" (
set "Reg64="
) else (
set "Reg64=Wow6432Node\"
)
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\%Reg64%UniHan\FONT" /v "Version" /d "8.0" /f >nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\%Reg64%UniHan\SKQS\BROWSER" /v "RootPath" /d "%cd%" /f >nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\%Reg64%UniHan\SKQS\SERVER" /v "RootPath" /d "%cd%\4KServer" /f >nul
reg add "HKEY_LOCAL_MACHINE\SOFTWARE\%Reg64%UniHan\SKQS\VERSION" /v "Version" /d "Standalone" /f >nul
copy %cd%\Fonts\Sk4.TTF %windir%\fonts\ >nul
del /s/q %cd%\4KServer\Etc\CdPaths.conf >nul 2>nul
(
echo # Copyright ^(c^) 1998 UniHan co.
echo # This file contains all 4KText CDs path
echo.
echo # Image CDs
for /l %%i in (0,1,164) do (
set numStr=00%%i
call set numStr=%%numStr:~-3%%
call echo CD%%numStr%%=[Compact Disk]
)
echo.
echo # Text CDs
for /l %%i in (201,1,208) do (
echo CD%%i=%cd%\skqs\CD %%i\
)
echo.
echo # Index CDs
for /l %%i in (301,1,308) do (
echo CD%%i=%cd%\skqs\CD %%i\
)
)>>.\4KServer\Etc\CdPaths.conf
pause