Groovy&Grails-代码剪辑-对象关系

最新推荐文章于 2024-08-09 21:25:57 发布

weixin_34121282

最新推荐文章于 2024-08-09 21:25:57 发布

阅读量75

点赞数

文章标签：数据库 python java

原文链接：https://my.oschina.net/65304586/blog/165698

版权

2019独角兽企业重金招聘Python工程师标准>>>

One To One

一张脸上只有一个鼻子。

<!-- lang: groovy -->
class Face {
    Nose nose
}

class Nose {
}

这是一个简单的单向关联，从face对象可以查到这个nose的信息，从nose就没办法了。如果要达到这个效果，需要把这个关联修改成双向的，代码如下：

<!-- lang: groovy -->
class Face {
    Nose nose
}

class Nose {
    Face face
}

这样双向查询就没有问题了，但是不能级联更新，如果需要更新需要一个对象一个对象的增加。如果我们在实例化Face的时候同时把Nose也增加一条信息，则需要增加一个级联更新属性，代码如下：

<!-- lang: groovy -->
class Face {
    Nose nose
}

class Nose {
    static belongsTo = [face:Face]
}

在这里，我们使用belongsTo 表示Nose "属于" Face。其结果就是我们创建并保存它时，数据库可以_级联_更新/插入 Nose，实例化代码如下：

<!-- lang:groovy -->
new Face(nose:new Nose()).save()

上面这段代码会将fase和nose都保存到数据库，需要注意的是反向操作是不行的，错误代码如下：

<!-- lang:groovy -->
new Nose(face:new Face()).save() // 这样会报错

belongsTo 的另一个重要作用是，如果你删除了一个Face 实例，那么相关的Nose也会被删除，操作代码如下：

<!-- lang:groovy -->
def f = Face.get(1)
f.delete() // Face和Nose实例都会被删除

如果没有 belongsTo 的话，将不会级联删除，你会得到一个外键约束的错误，除非你手工去删除Nose。

<!-- lang:groovy -->
// 如果没有belongsTo会报错，因为有约束
def f = Face.get(1)
f.delete()

// 所以没有belongsTo时需要手工删除
def f = Face.get(1)
f.nose.delete()
f.delete()

如果在删除Face实例的时候，我们不想自动删除和face关联的nose实例，需要将belongsTo修改一下，代码如下：

<!-- lang:groovy -->
class Face {
    Nose nose
}

class Nose {
    static belongsTo = Face
}

注意：我们没有用明确的语法声明映射关系，所以这个关联是单向的，并且不能设置成双向，否则会出现映射错误。

##One to Many##

一对多的关系是指，当一个类(比如Author)拥有另一个类(Book)的多个实例这种情况。在Grails中，你可以使用 hasMany 来定义这种关联

<!-- lang: groovy -->
class Author {
    static hasMany = [ books : Book ]
    String name
}

class Book {
   String title
}

这样我们有了一个一对多的单向关联。Grails在数据库级别将默认使用外键映射来映射这种关联关系。Grails 将会根据hasMany 设置为domain类自动注入一个类型为java.util.Set的属性。这个可以被用来遍历集合，代码如下：

<!-- lang: groovy -->
def a = Author.get(1)
a.books.each {
    println it.title
}

上面的代码遍历所有a作家的所著的所有图书。在上面的关联关系下，book对象可以级联保存和更新，但是不能级联删除，如果删除author的某个实例还要将和这个实例相关的book也删除，则需要使用belongTo关键字，代码如下：

<!-- lang: groovy -->
class Author {
    static hasMany = [ books : Book ]
   String name
}

class Book {
   static belongsTo = [author:Author]
   String title
}

其数据操作方法就可以参考OneToOne了。

在数据映射对象中，如果对象有多个属性有映射关系，则需要使用mappedBy关键字来指定他们分别映射的是哪个集合，代码如下：

<!-- lang: groovy -->
class Airport {
    static hasMany = [flights:Flight] //一个机场有多条航线
    static mappedBy = [flights:"departureAirport"] //离港机场
}
class Flight { //一条航线涉及到入港机场和出港机场
    Airport departureAirport
    Airport destinationAirport
}

一条航线涉及到入港机场和出港机场，针对哪条航线的入港机场是什么，出港机场是什么，其映射关系需要指定。

更为明细的指定如下：

<!-- lang: groovy -->
class Airport {
    static hasMany = [outboundFlights:Flight, inboundFlights:Flight] //入站航班和出站航班
    static mappedBy = [outboundFlights:"departureAirport", inboundFlights:"destinationAirport"]
}
class Flight {
    Airport departureAirport
    Airport destinationAirport
}

##Many to Many##

这种关联需要在关联的两方都定义hasMany，并在关联的被拥有方定义belongsTo（可用来指某物属于某人）:

<!-- lang: groovy -->
class Book {
   static belongsTo = Author
   static hasMany = [authors:Author]
   String title
}
class Author {
   static hasMany = [books:Book]
   String name
}

Grials在数据库层使用连接表来映射多对多关联。关联的拥有方，在这里是Author,负责持久化这个关联，并且它是唯一可以级联保存对方的一方。

比如下面的代码可以工作，并且会级联保存:

<!-- lang: groovy -->
new Author(name:"Stephen King")
    .addToBooks(new Book(title:"The Stand"))
    .addToBooks(new Book(title:"The Shining"))		
    .save()

但是下面的代码只保存 Book 而不保存authors!

<!-- lang: groovy -->
new Book(name:"Groovy in Action")
    .addToAuthors(new Author(name:"Dierk Koenig"))
    .addToAuthors(new Author(name:"Guillaume Laforge"))		
    .save()

这正是我们期望的行为，跟Hibernate中一样，多对多关联中只有一方可以管理关联。

转载于:https://my.oschina.net/65304586/blog/165698