通过日志还原，最重要的是：

1.必须有一个完整的备份，且这个备份必须是在修改、删除数据之前做的。

2.在更新、删除数据之后，做日志备份，该log备份将用于还原之前的数据

 

下面步骤的目的：还原被删除的表

在SQL Server Management可视化操作步骤：

1.创建数据库并完整备份：

 
  
  1. --创建测试数据库  
  2. CREATE DATABASE Db  
  3. GO  
  4.  
  5. --对数据库进行备份  
  6. BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT  
  7. GO 
 
  
2.创建一个空表
 
  
 
  
  1. --创建测试表  
  2. CREATE TABLE Db.dbo.TB_test(ID int)  
 
  
3.删除刚刚建的这个空表，假设这个表被误删除了
 
  
 
  
  1. --假设我们现在误操作删除了 Db.dbo.TB_test 这个表  
  2. DROP TABLE Db.dbo.TB_test  
 
  
到了这一步，我们想还原被删除的TB_Test表，这个时候，记住删除表之前的时间，后面会用到
 
  
这个时候，需要备份日志，可以用SQL Management界面操作备份，也可以用T-SQL备份
 
  
 
  
  1. BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT  
  2. GO 
 
  
4.还原数据库，可以替换原来数据库，或者还原成一个新的数据库DB1,这里新的数据库DB1
 
  
如果是界面操作：
 
  
“任务”- “还原” - “数据库”：
 
  
在“常规”选择页中的设备后面选择我们之前的完整备份：db.bak,
 
  
目标数据库：DB1
 
  
在“恢复状态”下选择第2项“不对数据库执行任何操作，不回滚提交的事务。。” ，点确定后，可以看到DB1数据库的状态变成“正在还原。。”
 
  
接下来：在DB1数据库上点右键--还原--事务日志，选择刚刚我们删除表后备份的事务日志：db_log.bak，
 
  
在下面选择时间点，这个时间是上面我们记住的删除表之前的时间，点击确定后，还原成功。可以看到被删除的表又回来了。
 
  
 
 
  
完整的脚本：
 
  
 
 
  
 
  
  1. --创建测试数据库  
  2. CREATE DATABASE Db  
  3. GO  
  4.  
  5. --对数据库进行备份  
  6. BACKUP DATABASE Db TO DISK='c:\db.bak' WITH FORMAT  
  7. GO  
  8.  
  9. --创建测试表  
  10. CREATE TABLE Db.dbo.TB_test(ID int)  
  11.  
  12. --延时1秒钟,再进行后面的操作(这是由于SQL Server的时间精度最大为百分之三秒,不延时的话,可能会导致还原到时间点的操作失败)  
  13. WAITFOR DELAY '00:00:01' 
  14. GO  
  15.  
  16. --假设我们现在误操作删除了 Db.dbo.TB_test 这个表  
  17. DROP TABLE Db.dbo.TB_test  
  18.  
  19. --保存删除表的时间  
  20. SELECT dt=GETDATE() INTO #  
  21. GO  
  22.  
  23. --在删除操作后,发现不应该删除表 Db.dbo.TB_test  
  24.  
  25. --下面演示了如何恢复这个误删除的表 Db.dbo.TB_test  
  26.  
  27. --首先,备份事务日志(使用事务日志才能还原到指定的时间点)  
  28. BACKUP LOG Db TO DISK='c:\db_log.bak' WITH FORMAT  
  29. GO  
  30.  
  31. --接下来,我们要先还原完全备份(还原日志必须在还原完全备份的基础上进行)  
  32. RESTORE DATABASE Db FROM DISK='c:\db.bak' WITH REPLACE,NORECOVERY  
  33. GO  
  34.  
  35. --将事务日志还原到删除操作前（这里的时间对应上面的删除时间，并比删除时间略早  
  36. DECLARE @dt datetime  
  37. SELECT @dt=DATEADD(ms,-20,dt) FROM #  --获取比表被删除的时间略早的时间  
  38. RESTORE LOG Db FROM DISK='c:\db_log.bak' WITH RECOVERY,STOPAT=@dt  
  39. GO  
  40.  
  41. --查询一下,看表是否恢复  
  42. SELECT * FROM Db.dbo.TB_test  
  43.  
  44. /*--结果:  
  45. ID            
  46. -----------   
  47.  
  48. （所影响的行数为 0 行）  
  49. --*/  
  50.  
  51. --测试成功  
  52. GO  
  53.  
  54. --最后删除我们做的测试环境  
  55. DROP DATABASE Db  
  56. DROP TABLE #