TeeChart Pro ActiveX教程（十九）：TeeChart工具集（六）

下载TeeChart Pro ActiveX最新版本

本文将续讲工具集中的页码工具、饼图切片工具、旋转工具和系列动画工具。

一、页码工具

页码工具显示一个完全可配置的文本框，其中包含所选的页码编号系统。

设计时：

页码工具的文本及其所在的框都可以完全配置。“Options”选项卡允许您输入所需的文本，并指定其对齐方式以及鼠标悬停在工具上时显示的光标类型。 “Position”选项卡指定页码工具的默认位置或自定义位置。 “Callout”选项卡定义“Page Tool”的“Callout”对象，该对象用于从注释中绘制线到图表中的任何位置。“Format”选项卡配置文本框，允许您更改其颜色，框架，图案，斜角，大小，圆度和透明度。 “Text”选项卡可以设置文本字体，颜色，轮廓和间距以及文本阴影的颜色和大小。 “Gradient”选项卡配置文本框渐变的属性，而“Shadow”选项卡配置文本框阴影的属性。

运行时：

With TChart1
    .Tools.Add tcPageNumber
    With .Tools.Items(0)
        .Active = True
        .asPageNum.Position = ppRightTop
        .asPageNum.Shape.Gradient.Visible = True
    End With
End With

二、饼图切片工具

“Pie Slices Tool/饼图切片工具”通过在其周围绘制边框或通过将其从饼图系列的其余部分展开来突出显示鼠标下的饼图切片。

设计时：

饼图切片工具必须与特定的Pie系列相关联才能显示。样式指定工具是否将焦点放在鼠标悬停的饼图上，或者是否会将其从其余部分中分离出来。Border指定围绕焦点饼图绘制的边框的笔特征。

运行时：

With TChart1
    .Aspect.View3D = False
    .AddSeries scPie
    .Series(0).asPie.Circled = False
    .Series(0).FillSampleValues 6
    
    .Tools.Add tcPie
    With .Tools.Items(0).asPie
        .Series = TChart1.Series(0)
        .Style = ptFocus
    End With
End With

三、旋转工具

将鼠标拖到图表上时，“Rotate/旋转”工具会更改图表的标高和旋转。

设计时：

旋转工具设计时可配置属性包括Inverted在旋转图表时反转鼠标移动的效果，Style指定图表是旋转、标高还是两者都有，Button指定用于旋转图表的鼠标按钮，而Outline配置图表轮廓可以是在移动指定的鼠标按钮时绘制。

运行时：

With TChart1
    .Tools.Add tcRotate
    With .Tools.Items(0)
        .Active = True
        .asRotate.Button = mbRight
    End With
End With

四、系列动画工具

系列动画工具执行系列点的增长动画。

设计时：

系列动画工具必须与特定系列相关联。 步骤定义系列动画工具所采用的动画步数，“开始时最小值/Start at Min value”将从minium Series YValue开始动画，而“Start value/开始值”指定“Start at Min value/最小值时开始”值设置为false时的起始值。 绘制每个将以n个点的组绘制系列。

请查看以下系列动画工具的工作示例：

运行时：

Private Sub Command1_Click()
On Error Resume Next
HScroll1.Enabled = False
Command1.Enabled = False
TChart1.Tools.Items(0).asSeriesAnimation.Execute
HScroll1.Enabled = True
Command1.Enabled = True
End Sub
 
Private Sub Command2_Click()
TChart1.Tools.Items(0).ShowEditor
HScroll1.Value = TChart1.Tools.Items(0).asSeriesAnimation.Steps
End Sub
 
Private Sub Check1_Click()
  If Check1.Value = 1 Then
     TChart1.Tools.Items(0).asSeriesAnimation.DrawEvery = 1
  Else
     TChart1.Tools.Items(0).asSeriesAnimation.DrawEvery = 0
  End If
End Sub
 
Private Sub Form_Load()
TChart1.AddSeries scBar
TChart1.Series(0).ColorEachPoint = True
TChart1.Tools.Add tcSeriesAnimation
HScroll1.Min = 1
HScroll1.Max = 255
HScroll1.Value = 100

TChart1.Series(0).FillSampleValues 6
TChart1.Legend.Visible = False
TChart1.Series(0).ValueFormat = "000"
TChart1.Tools.Items(0).asSeriesAnimation.Series = TChart1.Series(0)
TChart1.Tools.Items(0).asSeriesAnimation.StartAtMin = False
End Sub
 
Private Sub HScroll1_Change()
TChart1.Tools.Items(0).asSeriesAnimation.Steps = HScroll1.Value
Label2.Caption = HScroll1.Value
End Sub
 
Private Sub HScroll1_Scroll()
Label2.Caption = HScroll1.Value
End Sub
 
Private Sub TChart1_OnSeriesAnimationToolStep(ByVal Tool As Long, ByVal Step As Long)
If Tool = 0 Then
    With TChart1
        .Series(0).PointColor(0) = RGB(255 - Step, Step, Step)
        .Series(0).PointColor(1) = RGB(Step, 255 - Step, Step)
        .Series(0).PointColor(2) = RGB(Step, Step, 255 - Step)
        .Series(0).PointColor(3) = RGB(255 - Step, 255 - Step, Step)
        .Series(0).PointColor(4) = RGB(Step, 255 - Step, 255 - Step)
        .Series(0).PointColor(5) = RGB(255 - Step, Step, 255 - Step)
    End With
End If
End Sub

查看Teechart.Net系列教程>>

转载于:https://juejin.im/post/5ca18749518825440341a0e5