一、程序包package、子程序的区别
子程序是命名的PL/SQL块，可带参数并可在需要时随时调用。PL/SQL有两种类型的子程序，即存储过程和函数。
1.存储过程用于执行特定的任务 2.函数用于执行任务并返回值
程序包是对相关类型、变量、常量、游标、异常、存储过程和函数的封装。
程序包由包规范和包主体两部分组成。类似于bo和boimpl
1.包规范是包的接口，包含公用对象及其类型。
2.包主体实现包规范中的游标和子程序，包主体中的声明仅限于在包内使用。
程序包中游标的定义分为游标规范和游标主体两部分。
二、语法及示例：
1、存储过程 PROCEDURE
创建存储过程的语法：
CREATE [OR REPLACE] PROCEDURE procedure_name[(parameter_list)]
{IS|AS}
[local_declarations]
BEGIN
executable_statements
[EXCEPTION
exception_handlers]
END [procedure_name];
其中：procedure_name是过程的名称。
parameter_list是参数列表。
local_declarations是局部声明。
executable_statements是可执行语句。
exception_handlers是异常处理程序。
示例1：演示创建过程(参数列表中为IN参数赋予一个默认值，不能为OUT、IN OUT参数赋予默认值)
create or replace procedure find_emp(emp_no in number:=7900)
as
empname varchar2(20);
begin
select ename into empname from emp where empno=emp_no;
dbms_output.put_line('雇员姓名是 '||empname);
exception
when no_data_found then
dbms_output.put_line('雇员编号未找到');
end find_emp;
调用过程：EXECUTE procudure_name(parameters_list); 也可以在过程里面调用，直接写上procudure_name而不必写EXECUTE。
示例2：演示创建带OUT参数的过程
CREATE OR REPLACE PROCEDURE TEST(VALUE1 VARCHAR2, VALUE2 OUT NUMBER) IS
IDENTITY NUMBER;
BEGIN
SELECT SAL
INTO IDENTITY FROM EMP WHERE EMPNO = VALUE1;
IF IDENTITY < 2000 THEN VALUE2 := 1000;
ELSE VALUE2 := 500;
END IF;
END;
调用带OUT参数的过程：
DECLARE
VALUE2 NUMBER;
BEGIN
TEST('7900', VALUE2);
DBMS_OUTPUT.PUT_LINE(VALUE2);
END;
示例3：演示创建带IN OUT参数的过程
CREATE OR REPLACE PROCEDURE SWAP(P1 IN OUT NUMBER, P2 IN OUT NUMBER) IS
V_TEMP NUMBER;
BEGIN
V_TEMP := P1;
P1 := P2;
P2 := V_TEMP;
END;
调用带IN OUT参数的过程：
DECLARE
NUM1 NUMBER := 100;
NUM2 NUMBER := 200;
BEGIN
SWAP(NUM1, NUM2);
DBMS_OUTPUT.PUT_LINE('num1= ' || NUM1);
DBMS_OUTPUT.PUT_LINE('num2= ' || NUM2);
END;
示例4：将过程的执行权限授予其他用户
GRANT EXECUTE ON find_emp TO scott;
GRANT EXECUTE ON swap TO PUBLIC;
将find_emp过程的执行权限授予给用户scott，将执行swap过程的权限授予所有数据库用户。
删除过程语法：DROP PROCEDURE procudure_name;
2、函数 FUNCTION
定义函数的语法如下：
CREATE [OR REPLACE] FUNCTION function_name[(parameter_list)]
RETURN datatype
{IS|AS}
[local_declarations]
BEGIN
executable_statements
[EXCEPTION
exception_handlers]
END [function_name];
其中：function_name是函数的名称。
parameter_list是参数列表。
local_declarations是局部声明。
executable_statements是可执行语句。
exception_handlers是异常处理程序。
使用函数时注意：形式参数必须只使用数据库类型，不得使用PL/SQL类型。函数的返回类型也必须是数据库类型。
函数不能单独执行，只能通过SQL语句或PL/SQL程序块来调用。
示例5：演示如何创建函数
CREATE OR REPLACE FUNCTION FUN_HELLO RETURN VARCHAR2 IS
BEGIN
RETURN '朋友，您好';
END;
调用函数：select fun_hello from dual;
函数的授权：同过和的授权一样具体请看示例4。
删除函数：DROP FUNCTION function_name
CREATE OR REPLACE FUNCTION "ADD_MONTHS_STRING" (SOURCE VARCHAR2,
ADD_NUM INTEGER)
RETURN VARCHAR2 IS
BEGIN
IF SOURCE IS NULL OR LENGTH(SOURCE) < 6 THEN
RETURN TO_CHAR(ADD_MONTHS(SYSDATE, ADD_NUM), 'YYYYMM');
ELSE
RETURN TO_CHAR(ADD_MONTHS(TO_DATE(SOURCE, 'YYYYMM'), ADD_NUM),'YYYYMM');
END IF;
END;
总结： 过程和函数的差异
过程 函数
作为PL/SQL语句执行 作为表达式的一部分调用
在规范中不包含RETURN子句 必须在规范中包含RETURN子句
不返回任何值 必须返回单个值
可以包含RETURN语句，但是与函数不同，它不能用于返回值 必须包含至少一条RETURN语句
3、程序包
创建包规范的语法：
CREATE [OR REPLACE] PACKAGE package_name
IS|AS
[Public type and item declarations]
[Subprogram specifications]
END [package_name];
其中：package_name是包的名称。
Public type and item declarations是声明类型、常量、变量、异常和游标等。
Subprogram specifications声明PL/SQL子程序。
示例6：演示创建程序包规范
CREATE OR REPLACE PACKAGE PACK_OP IS
PROCEDURE PRO_PRINT_ENAME(ID NUMBER);
PROCEDURE PRO_PRINT_SAL(ID NUMBER);
FUNCTION FUN_RE_DATE(ID NUMBER) RETURN DATE;
END;
创建包主体的语法：
CREATE [OR REPLACE] PACKAGE BODY package_name
IS|AS
[Public type and item declarations]
[Subprogram bodies]
[BEGIN
Initialization_statements]
END [package_name];
其中：package_name是包的名称。
Public type and item declarations是声明类型、常量、变量、异常和游标等。
Subprogram bodies是定义公共和私有PL/SQL子程序。
示例7：演示创建程序包主体
CREATE OR REPLACE PACKAGE BODY PACK_OP IS
PROCEDURE PRO_PRINT_ENAME(ID NUMBER) IS
NAME EMP.ENAME%TYPE;
BEGIN
SELECT ENAME INTO NAME FROM EMP WHERE EMPNO = ID;
DBMS_OUTPUT.PUT_LINE('职员姓名：' || NAME);
END PRO_PRINT_ENAME;
PROCEDURE PRO_PRINT_SAL(ID NUMBER) IS
SALARY EMP.SAL%TYPE;
BEGIN
SELECT SAL INTO SALARY FROM EMP WHERE EMPNO = ID;
DBMS_OUTPUT.PUT_LINE('职员工资：' || SALARY);
END PRO_PRINT_SAL;
FUNCTION FUN_RE_DATE(ID NUMBER) RETURN DATE IS
BEDATE EMP.HIREDATE%TYPE;
BEGIN
SELECT HIREDATE INTO BEDATE FROM EMP WHERE EMPNO = ID;
RETURN BEDATE;
END FUN_RE_DATE;
END PACK_OP;
示例8：调用程序包中创建的过程和函数
exec pack_op.pro_print_ename(7900);
exec pack_op.pro_print_sal(7900);
select pack_op.fun_re_date(7900) from dual;
示例9：演示程序包中的游标
创建包规范：
CREATE OR REPLACE PACKAGE PACK_EMP IS
CURSOR CUR_EMP RETURN EMP%ROWTYPE;
PROCEDURE PRO_CUR;
END PACK_EMP;
创建包主体：
CREATE OR REPLACE PACKAGE BODY PACK_EMP IS
--游标
CURSOR CUR_EMP RETURN EMP%ROWTYPE IS
SELECT * FROM EMP;--游标表示 EMP表的每一列
--过程
PROCEDURE PRO_CUR IS
REC_EMP EMP%ROWTYPE; --记录REC_EMP 表示表EMP的列
BEGIN
OPEN CUR_EMP;
LOOP --循环表的每一列
FETCH CUR_EMP
INTO REC_EMP;
EXIT WHEN CUR_EMP%NOTFOUND;
IF REC_EMP.SAL < 1000 THEN
DBMS_OUTPUT.PUT_LINE('员工工资：' || REC_EMP.SAL || '，需加倍努力争取提高工资');
ELSIF REC_EMP.SAL >= 1000 AND REC_EMP.SAL < 2000 THEN
DBMS_OUTPUT.PUT_LINE('员工工资：' || REC_EMP.SAL || '，工资一般，争取搞个部门经理做做');
ELSE
DBMS_OUTPUT.PUT_LINE('员工工资：' || REC_EMP.SAL || '，工资不错，争取搞个总经理做做');
END IF;
END LOOP;
END PRO_CUR;
END PACK_EMP;
调用程序包中的过程以调用程序包中的游标
exec pack_emp.pro_cur;
示例10：存储过程返回游标的子程序包(此程序包返回r_cur游标)
CREATE OR REPLACE PACKAGE SCOTT.PK_WT IS
TYPE MYTYPE IS REF CURSOR; --REF Cursor游标 弱类型REF游标,不指定return type，能和任何类型的CURSOR变量匹配，用于获取任何结果集
PROCEDURE P_WT(MYCS OUT MYTYPE);
END;
CREATE OR REPLACE PACKAGE BODY SCOTT.PK_WT IS
PROCEDURE P_WT(MYCS OUT MYTYPE) AS
R_CUR MYTYPE;
BEGIN
OPEN R_CUR FOR
SELECT * FROM EMP;--查询语句返回结果集
MYCS := R_CUR;
END P_WT;
END PK_WT;
查询有关过程、函数和程序包的信息：USER_OBJECTS数据字典视图
column object_name format a18
select object_name,object_type from user_objects where object_type in ('PROCEDURE','FUNCTION','PACKAGE','PACKAGE BODY');
扫一扫
230
被折叠的 条评论
为什么被折叠?
到【灌水乐园】发言
