【关路灯】【MM不哭】

先看题：

关路灯　　

描述

某一村庄在一条路线上安装了n盏路灯，每盏灯的功率有大有小（即同一段时间内消耗的电量有多有少）。老张就住在这条路中间某一路灯旁，他有一 项工作就是每天早上天亮时一盏一盏地关掉这些路灯。为了给村里节省电费，老张记录下了每盏路灯的位置和功率，他每次关灯时也都是尽快地去关，但是老张不知 道怎样去关灯才能够最节省电。他每天都是在天亮时首先关掉自己所处位置的路灯，然后可以向左也可以向右去关灯。开始他以为先算一下左边路灯的总功率再算一 下右边路灯的总功率，然后选择先关掉功率大的一边，再回过头来关掉另一边的路灯，而事实并非如此，因为在关的过程中适当地调头有可能会更省一些。现在已知 老张走的速度为1m/s，每个路灯的位置（是一个整数，即距路线起点的距离，单位：m）、功率（W），老张关灯所用的时间很短而可以忽略不计。

请你为老张编一程序来安排关灯的顺序，使从老张开始关灯时刻算起所有灯消耗电最少（灯关掉后便不再消耗电了）。

输入

文件第一行是两个数字n(0 < n < 50，表示路灯的总数)和c(1 < ＝ c < =n老张所处位置的路灯号)；

接下来n行，每行两个数据，表示第1盏到第n盏路灯的位置和功率。

输出

一个数据，即最少的功耗(单位：J，1J＝1W·s)。

样例输入

5 3                              
2 10
3 20
5 20
6 30
8 10

样例输出

270  {此时关灯顺序为3 4 2 1 5，不必输出这个关灯顺序}

MM不哭

描述 Description   在一个数轴上,有n个MM(绝非恐龙!)在哭泣(5555~一直哭). tcboy也在这个数轴上,并恰好看到了这一幕,由于每个MM哭都会让tcboy损失一定的rp,于是tcboy有必要去安慰她们.(真命苦啊 T.T) 开始时，tcboy站在k号MM的旁边. 现在知道第i个MM哭泣每秒钟会使tcboy降低 w[i]的rp (单位rp/s). 而tcboy的行走速度很慢只有1m/s . tcboy安慰MM的方式很特别(怎么安慰随便大家YY了..#@$%^%$#@),不需要花费时间. 请计算tcboy安慰完所有MM,会消耗掉的rp的最小值. 输入格式 Input Format     输入文件的第一行包含一个整数N，2<=N<=1000，表示MM的数量。 第二行包含一个整数V，1<=V<=N，表示开始时tcboy站在几号MM的旁边. 接下来的N行中，每行包含两个用空格隔开的整数D和W，用来描述每个MM，其中0<=D<=1000，0<=W<=1000。D表示MM在数轴上的位置(单位: m)，W表示每秒钟会使tcboy降低W的rp。 输出格式 Output Format   输出只有一行：一个整数，即消耗rp之和的最小值。结果不超过1,000,000,000。

样例输入 Sample Input

4
3
2 2
5 8
6 1
8 7

　　   样例输出 Sample Output            56


　　看完这两道题，你就会发现，其实他们的模型是一样的。也许有人看到数据范围不同，会怀疑两道题的算法有区别…… 　　两道题的区别：起点不同，数据强度不同。 　　既然这样，我们着重分析相对较难的一个，就是“MM不哭”。
　　我们约定起点为S，那么每一次“安慰”之后，已经被安慰的MM一定构成一个包含S的连续区间。这个很容易证明，因为如果要从i到j，那么i到j路径上的MM一定能被顺手照顾到了，否则就不是最优解。 　　假设我们当前已经安慰的MM的区间表示为[i,j]，那么我们下一步可以选择安慰第i-1个或者安慰j+1个。那我们知道，我们安慰完一个MM之后，就会停在MM那个地方，而且那个MM一定是区间[i,j]的左端点或右端点。那么针对上面说的决策，我们当前又有两个状态，当前位置为i或者当前位置为j。 　　 　　至此，我们已经可以列出状态转移方程： 　　设f[i,j,k](k=0或1)表示已经安慰过的MM区间为[i,j]，k=0表示当前在左端点i位置，k=1表示当前在右端点j位置。 　　　　　　f[i,j,0]=min{ f[i+1,j,1] + (w[i] + (w[n] - w[j]))*(d[i+1] - d[i]), 　　　　　　　　　　　　  f[i+1,j,2] + (w[i]+ (w[n] - w[j]))*(d[i+1] - d[i]) }  　　　 　　 f[i,j,2]=min{ f[i,j-1,1] + (w[i-1] + (w[n] - w[j-1]))*(d[j] - d[i]), 　   　　　　　　　　　　  f[i,j-1,2] + (w[i-1] + (w[n] - w[j-1]))*(d[j] - d[j-1]) } 　　　　这里需要预处理一下w，求和。
　　初始状态：f[s,s,1]=s[s,s,2]=0 　　目标状态：min{ f[1,n,1] , f[1,n,2] } 　　时间复杂度：O(n^2)
　　Caution：注意给出的坐标不一定是有序的。我不知他是不是有序的，反正我预先排序了，这样比较保险。　　
　　附第二题代码。写完之后看了看网上其他人的，感觉自己的还是比价精炼的，方程摆的很显眼。

var f:Array[0..1009,0..1009,1..2]of int64;
    D,W:Array[1..1000]of int64;
    n,s,i,j:longint;

function min(a,b:int64):int64;
begin
     if a<b then exit(a);
     exit(b);
end;

procedure quicksort(head,tail:longint);
var i,j,x,t:longint;
begin
     i:=head;j:=tail;x:=D[random(tail-head+1)+head];
     repeat
           while d[i]<x do inc(i);
           while d[j]>x do dec(j);
           if i<=j then
              begin
                   t:=D[i];D[i]:=D[j];D[j]:=t;
                   t:=W[i];W[i]:=W[j];W[j]:=t;
                   inc(i);dec(j);
              end;
     until i>j;
     if i<tail then quicksort(i,tail);
     if j>head then quicksort(head,j);
end;

begin
     randomize;
     readln(n);
     readln(s);
     for i:=1 to n do
         readln(D[i],W[i]);
     quicksort(1,n);
     f[s,s,1]:=0;f[s,s,2]:=0;
     for i:=2 to n do W[i]:=W[i]+W[i-1];
     fillchar(f,sizeof(f),$7f);
     for i:=s downto 1 do
         for j:=s to n do
             if i<>j then
             begin
                  f[i,j,1]:=min(f[i+1,j,1]+(W[i]+W[n]-W[j])*(D[i+1]-D[i]),
                                f[i+1,j,2]+(W[i]+W[n]-W[j])*(D[j]-D[i]));
                  f[i,j,2]:=min(f[i,j-1,1]+(W[i-1]+W[n]-W[j-1])*(D[j]-D[i]),
                                f[i,j-1,2]+(W[i-1]+W[n]-W[j-1])*(D[j]-D[j-1]));
             end;
     writeln(min(f[1,n,1],f[1,n,2]));
end.

我现在快排只会写随机化了囧……以前怎么写忘记了……我是弱菜啊……

转载于:https://www.cnblogs.com/Delostik/archive/2011/04/12/2014113.html