windows 一键安装 mysql

2019独角兽企业重金招聘Python工程师标准>>>

第一：批处理文件

@Echo OFF
set tm1=%time:~0,2% 
set tm2=%time:~3,2% 
set tm3=%time:~6,2% 

set path_home_mysql=%~d0%~p0
set path_bin_mysql=%path_home_mysql%bin\

rem MySQL参数设置
set database_mysql=mysql
set user_mysql=root
set password_mysql=root

TITLE 一键安装MySQL工具  [%date% %tm1%:%tm2%:%tm3%]。 
:Swtch

CLS

ECHO =========================================
ECHO            MySQL 一键安装
ECHO            ver:201308191321
ECHO             by yunnet
ECHO.  
ECHO 请选择要进行的操作，然后按回车 
ECHO.  
ECHO 1. 备份用户表 
ECHO 2. 恢复用户表
ECHO 3. 安装MySQL      (第一次安装必须备份用户表)
ECHO 4. 卸载MySQL
ECHO 5. 启动MySQL
ECHO 6. 停止MySQL
ECHO 0. 退出 
ECHO =========================================
ECHO.


:ChoLine
SET Choice=
SET /P Choice=选择: 
rem 设定变量"Choice"为用户输入的字符 
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1 
ECHO.
IF /I "%Choice%"=="1" GOTO Backup
IF /I "%Choice%"=="2" GOTO Reset
IF /I "%Choice%"=="3" GOTO Install 
IF /I "%Choice%"=="4" GOTO Uninstall 
IF /I "%Choice%"=="5" GOTO Start 
IF /I "%Choice%"=="6" GOTO Stop 
IF /I "%Choice%"=="0" GOTO End
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号 
rem 注意,IF语句需要双等于号 
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入... 
ECHO.
GOTO ChoLine 

:Start
NET START MySQL
ECHO 按任意键继续... 
PAUSE >nul 
GOTO Swtch 

:Stop
NET STOP MySQL
ECHO 按任意键继续... 
PAUSE >nul 
GOTO Swtch 

:Backup
XCOPY %path_home_mysql%data\mysql\user.*  %path_home_mysql%bak\  /i /s /c /y
ECHO 按任意键继续... 
PAUSE >nul 
GOTO Swtch 

:Reset
XCOPY %path_home_mysql%bak\*.* %path_home_mysql%data\mysql\   /i /s /c /y
ECHO 按任意键继续... 
PAUSE >nul 
GOTO Swtch 

:Install
ECHO 开始安装MySQL
%path_bin_mysql%mysqld -install MySQL --defaults-file="%path_home_mysql%my.ini"
ECHO MySQL ....... ok

ECHO start MySQL
net start MySQL

ECHO 更新root用户密码
%path_bin_mysql%mysqladmin -u %user_mysql% password %password_mysql%
ECHO update password ....... ok

ECHO 执行user.sql
%path_bin_mysql%mysql -u%user_mysql% -p%password_mysql% %database_mysql% < user.sql
ECHO execute sql ....... ok
ECHO 按任意键继续... 
PAUSE >nul 
GOTO Swtch 


:Uninstall
@ECHO OFF 
ECHO 停止MySQL
net stop MySQL

ECHO 卸载MySQL
.\bin\mysqld -remove MySQL

ECHO 按任意键继续... 
PAUSE >nul 
GOTO Swtch 



:End 
EXIT

第二：需要执行SQL

TRUNCATE TABLE `user`;
INSERT INTO `user` VALUES ('%', 'root', password('root'), 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', 'Y', '', '', '', '', '0', '0', '0', '0', '', '');
FLUSH PRIVILEGES;
DROP DATABASE IF EXISTS track;
CREATE DATABASE track;

第三：需要注意 一键安装工具 可以引导快速安装，注意第一次安装，必须备份用户表， 如果安装失败，请先恢复用户表。

转载于:https://my.oschina.net/yunnet/blog/155317