oracle把列数据串成一个字符串,一组数据，如何根据一个字段值分组后，把另一字段的字符串累加连接起来？...

connstr函数：

CREATE OR REPLACE TYPE CONNSTRIMPL AS OBJECT

(

CURRENTSTR VARCHAR2(4000),

CURRENTSEPRATOR VARCHAR2(8),

STATIC FUNCTION ODCIAGGREGATEINITIALIZE(SCTX IN OUT CONNSTRIMPL) RETURN NUMBER,

MEMBER FUNCTION ODCIAGGREGATEITERATE(SELF IN OUT CONNSTRIMPL,VALUE IN VARCHAR2) RETURN NUMBER,

MEMBER FUNCTION ODCIAGGREGATETERMINATE(SELF IN CONNSTRIMPL,RETURNVALUE OUT VARCHAR2, FLAGS IN NUMBER) RETURN NUMBER,

MEMBER FUNCTION ODCIAGGREGATEMERGE(SELF IN OUT CONNSTRIMPL,CTX2 IN CONNSTRIMPL) RETURN NUMBER

);

/

CREATE OR REPLACE TYPE BODY CONNSTRIMPL IS

STATIC FUNCTION ODCIAGGREGATEINITIALIZE(SCTX IN OUT CONNSTRIMPL)

RETURN NUMBER IS

BEGIN

SCTX := CONNSTRIMPL('',',');------------------字符串分割符，修改替换成你需要的

RETURN ODCICONST.SUCCESS;

END;

MEMBER FUNCTION ODCIAGGREGATEITERATE(SELF IN OUT CONNSTRIMPL, VALUE IN VARCHAR2) RETURN NUMBER IS

BEGIN

IF SELF.CURRENTSTR IS NULL THEN

SELF.CURRENTSTR := VALUE;

ELSE

SELF.CURRENTSTR := SELF.CURRENTSTR ||CURRENTSEPRATOR || VALUE;

END IF;

RETURN ODCICONST.SUCCESS;

END;

MEMBER FUNCTION ODCIAGGREGATETERMINATE(SELF IN CONNSTRIMPL, RETURNVALUE OUT VARCHAR2, FLAGS IN NUMBER) RETURN NUMBER IS

BEGIN

RETURNVALUE := SELF.CURRENTSTR;

RETURN ODCICONST.SUCCESS;

END;

MEMBER FUNCTION ODCIAGGREGATEMERGE(SELF IN OUT CONNSTRIMPL, CTX2 IN CONNSTRIMPL) RETURN NUMBER IS

BEGIN

IF CTX2.CURRENTSTR IS NULL THEN

SELF.CURRENTSTR := SELF.CURRENTSTR;

ELSIF SELF.CURRENTSTR IS NULL THEN

SELF.CURRENTSTR := CTX2.CURRENTSTR;

ELSE

SELF.CURRENTSTR := SELF.CURRENTSTR || CURRENTSEPRATOR || CTX2.CURRENTSTR;

END IF;

RETURN ODCICONST.SUCCESS;

END;

END;

/

CREATE OR REPLACE FUNCTION CONNSTR (INPUT VARCHAR2) RETURN VARCHAR2

PARALLEL_ENABLE AGGREGATE USING CONNSTRIMPL;

/