oracle ou屏蔽,Oracle数据屏蔽

在12c中使用功能STANDARD_HASH可以轻松解决此问题.

以前版本中的解决方案只是稍微复杂一点.围绕DBMS_CRYPTO构建一个简单的包装器,其行为类似于STANDARD_HASH：

--Imitation of the 12c function with the same name.

--Remember to drop this function when you upgrade!

create or replace function standard_hash(

p_string varchar2,

p_method varchar2 default 'SHA1'

) return varchar2 is

v_method number;

v_invalid_identifier exception;

pragma exception_init(v_invalid_identifier, -904);

begin

--Intentionally case-sensitive, just like the 12c version.

if p_method = 'SHA1' then

v_method := dbms_crypto.hash_sh1;

--These algorithms are only available in 12c and above.

$IF NOT DBMS_DB_VERSION.VER_LE_11 $THEN

elsif p_method = 'SHA256' then

v_method := dbms_crypto.hash_sh256;

elsif p_method = 'SHA384' then

v_method := dbms_crypto.hash_sh384;

elsif p_method = 'SHA512' then

v_method := dbms_crypto.hash_sh512;

$END

elsif p_method = 'MD5' then

v_method := dbms_crypto.hash_md5;

else

raise v_invalid_identifier;

end if;

return rawToHex(dbms_crypto.hash(utl_raw.cast_to_raw(p_string), v_method));

end;

/

您可能需要使用SYS登录并授予用户对DBMS_CRYPTO的访问权才能使该功能正常工作：

grant execute on sys.dbms_crypto to ;

创建一个公共同义词,将其授予所有人,其工作方式完全相同.

create public synonym standard_hash for .standard_hash;

grant execute on standard_hash to public;

select standard_hash('Some text', 'MD5') from dual;

9DB5682A4D778CA2CB79580BDB67083F

select standard_hash('Some text', 'md5') from dual;

ORA-00904: : invalid identifier

这是使用函数的简单示例：

update some_table

set column1 = standard_hash(column1),

column2 = standard_hash(column2);

但是更新大量数据可能会很慢.创建新表,删除旧表,重命名新表等可能会更快.哈希值可能大于列的大小,可能有必要更改表some_table修改column1 varchar2(40字节)；

让我惊讶的是,有多少产品和工具可以做到如此简单.