sas读取服务器上的log文件,关于处理SAS的Log文件的宏-经管之家官网！

%macro GetTimeTableForSASLog(InFilePath,TargetTable);

/**********************************************************************/

/* 此宏的作用是读取SAS系统生成的Log文件，并将得到的步骤名称和对应的运 */

/* 行时间保存至结果表格中。其中，InFilePath指定的Log文件，要写全从根 */

/* 目录至最后的文件名称；TargetTable是结果表格。 */

/* */

/* 最终得到的是原始Log文件中包含的步骤名称和对应的运行时间(实际时间 */

/* 和CPU时间)，其中N是步骤在原始Log文件中的行号。 */

/* */

/* Created on 2013.12.10 */

/* Modified on 2013.12.11 */

/**********************************************************************/

/* 检查InFilePath的合法性，后缀必须为TXT或LOG */

%if %SYSFUNC(FIND(&InFilePath,%STR(.))) EQ 0 OR (%SYSFUNC(FIND(&InFilePath,%STR(.))) NE 0 AND %UPCASE(%SCAN(&InFilePath,-1,%STR(.))) NE TXT AND %UPCASE(%SCAN(&InFilePath,-1,%STR(.))) NE LOG) %then %do;

%put ERROR: The suffix of InFilePath should be txt or log, please check it again.;

%goto exit;

%end;

/* 检查TargetTable的存在性 */

%if &TargetTable EQ %STR() %then %do;

%put ERROR: The TargetTable should not be blank, please check it again.;

%goto exit;

%end;

/* 开始进行计算 */

/* 第一步：导入LOG文件 */

proc import datafile="&InfilePath" out=&TargetTable replace;

getnames=no;

run;

/* 第二步：处理结果表格 */

data &TargetTable;

set &TargetTable;

N=_N_;

if SUBSTR(UPCASE(VAR1),1,10) EQ 'NOTE: DATA' OR SUBSTR(UPCASE(VAR1),1,15) EQ 'NOTE: PROCEDURE' OR

SUBSTR(UPCASE(VAR1),1,9) EQ 'REAL TIME' OR SUBSTR(UPCASE(VAR1),1,8) EQ 'CPU TIME';

run;

data &TargetTable;

set &TargetTable;

if SUBSTR(UPCASE(VAR1),1,5) EQ 'NOTE:' then do;

Name=SUBSTR(VAR1,7,FIND(UPCASE(VAR1),'USED')-8);

end;

else if SUBSTR(UPCASE(VAR1),1,9) EQ 'REAL TIME' then do;

Real_Time=SUBSTR(VAR1,PRXMATCH('/\d+.\d+/',VAR1));

end;

else if SUBSTR(UPCASE(VAR1),1,9) EQ 'CPU TIME' then do;

CPU_Time=SUBSTR(VAR1,PRXMATCH('/\d+.\d+/',VAR1));

end;

run;

data &TargetTable(keep=Col_N Col_Name Col_Content);

set &TargetTable;

retain Col_N;

length Col_Name $50;

length Col_Content $100;

if Name NE '' then do;

Col_N=N;

Col_Name='Name';

Col_Content=Name;

output;

end;

else if Real_Time NE '' then do;

Col_Name='Real_Time_Temp';

Col_Content=Real_Time;

output;

end;

else if CPU_Time NE '' then do;

Col_Name='CPU_Time_Temp';

Col_Content=CPU_Time;

output;

end;

run;

proc transpose data=&TargetTable out=&TargetTable;

by Col_N;

id Col_Name;

var Col_Content;

run;

/* 第三步：处理结果表格中的时间变量 */

data &TargetTable(keep=N Name Real_Time CPU_Time);

retain N Name Real_Time CPU_Time;

set &TargetTable(rename=(Col_N=N));

format Real_Time TIME10.4;

format CPU_Time TIME10.4;

if FIND(UPCASE(Real_Time_Temp),'SECONDS') NE 0 then Real_Time=HMS(0,0,SCAN(Real_Time_Temp,1,' '));

else if LENGTH(COMPRESS(Real_Time_Temp,'.','d')) EQ 2 then Real_Time=HMS(SCAN(Real_Time_Temp,1,':'),SCAN(Real_Time_Temp,2,':'),SCAN(Real_Time_Temp,3,':'));

else if LENGTH(COMPRESS(Real_Time_Temp,'.','d')) EQ 1 then Real_Time=HMS(0,SCAN(Real_Time_Temp,1,':'),SCAN(Real_Time_Temp,2,':'));

if FIND(UPCASE(CPU_Time_Temp),'SECONDS') NE 0 then CPU_Time=HMS(0,0,SCAN(CPU_Time_Temp,1,' '));

else if LENGTH(COMPRESS(CPU_Time_Temp,'.','d')) EQ 2 then CPU_Time=HMS(SCAN(CPU_Time_Temp,1,':'),SCAN(CPU_Time_Temp,2,':'),SCAN(CPU_Time_Temp,3,':'));

else if LENGTH(COMPRESS(CPU_Time_Temp,'.','d')) EQ 1 then CPU_Time=HMS(0,SCAN(CPU_Time_Temp,1,':'),SCAN(CPU_Time_Temp,2,':'));

run;

%exit:

%mend;