碰巧我在现实生活中做过类似的事情。所以这是一个纯SQL解决方案。
首先,您需要具有CREATE ANY DIRECTORY权限(可能是DBA)的人来创建目录对象:
create directory load_dir as '/home/temp'
/
grant read, write on directory load_dir to
/以下PL/SQL块打开文件并读取它。对于文件中的每一行,它创建一个表,从中计数并获取最大ID值。
declare
fh_tabs utl_file.file_type;
table_name varchar2(30);
snapshot_name varchar2(30);
stmt varchar2(4000) ;
cnt_row pls_integer;
cnt_tab pls_integer := 0;
max_id pls_integer;
begin
fh_tabs := utl_file.fopen('LOAD_DIR', 'file.name', 'R');
<< tables >>
loop
begin
utl_file.get_line(fh_tabs, table_name);
cnt_tab := cnt_tab + 1;
snapshot_name := 'snapshot'||trim(to_char(cnt_tab));
stmt := 'create table '||snapshot_name
||' as select * from '||table_name;
execute immediate stmt;
execute immediate 'select count(*) from '
||snapshot_name into cnt_row;
dbms_output.put_line('New table '||snapshot_name||' has '
||to_char(cnt_row)||' records.');
execute immediate 'select max(id) from '
||snapshot_name into max_id;
dbms_output.put_line('Highest primary key = '||max_id);
exception
when no_data_found then
utl_file.fclose(fh_tabs);
dbms_output.put_line('End of file!. Tables created = '
||to_char(cnt_tab));
exit;
end;
end loop tables;
end;
/我假设您的文件只包含表名,并且您希望快照表具有相同的名称,并且ID列在所有表上具有相同的名称。可以修改脚本以更改这些假设,但附加数据必须来自某个地方。它可能属于输入文件,在这种情况下,您需要对读取行进行标记。