bat执行java输出重定向,cmd - 显示Windows命令提示符输出并将其重定向到fi

cmd - 显示Windows命令提示符输出并将其重定向到fi

如何在Windows命令提示符下运行命令行应用程序并同时显示输出并重定向到文件？

例如，如果我要运行命令dir > test.txt，则会将输出重定向到名为test.txt的文件，而不显示结果。

我怎么能写一个命令来显示输出并将输出重定向到Windows命令提示符中的文件，类似于Unix上的tee命令？

27个解决方案

116 votes

我能够找到将输出重定向到文件然后重定向到控制台的解决方案/解决方法：

dir > a.txt | type a.txt

其中dir是需要重定向输出的命令，a.txt是存储输出的文件。

NSPKUWCExi2pr8wVoGNk answered 2019-02-04T17:54:26Z

113 votes

要扩展davor的答案，您可以像这样使用PowerShell：

powershell "dir | tee test.txt"

如果您尝试重定向当前目录中exe的输出，则需要在文件名上使用.\，例如：

powershell ".\something.exe | tee test.txt"

Saxon Druce answered 2019-02-04T17:54:55Z

86 votes

有一个Unix tee命令的Win32端口就是这样做的。 见[http://unxutils.sourceforge.net/]或[http://getgnuwin32.sourceforge.net/]

Brian Rasmussen answered 2019-02-04T17:55:17Z

45 votes

看看这个：冬天

不需要cygwin。

我确实遇到并报告了一些问题。

你也可以检查unxutils，因为它包含tee(并且不需要cygwin)，但要注意输出EOL在这里类似于UNIX。

最后，但并非最不重要的，如果您有PowerShell，您可以尝试Tee-Object。 在PowerShell控制台中键入get-help tee-object以获取更多信息。

Davor Josipovic answered 2019-02-04T17:56:06Z

38 votes

@ tori3852

我找到

dir > a.txt | type a.txt

没有工作(前几行dir列表 - 怀疑某种过程分叉和第二部分，'type'命令在可怕列表完成之前终止？)，所以我使用了：

dir > z.txt && type z.txt

它做了 - 顺序命令，一个在第二个开始之前完成。

Andy Welch answered 2019-02-04T17:56:47Z

21 votes

不幸的是没有这样的事情。

Windows控制台应用程序只有一个输出句柄。 (好吧，有两个STDOUT，STDERR，但这里没关系)>将正常写入控制台句柄的输出重定向到文件句柄。

如果你想要某种多路复用，你必须使用一个外部应用程序，你可以将输出转移到。 然后，此应用程序可以再次写入文件和控制台。

Daniel Rikowski answered 2019-02-04T17:57:23Z

21 votes

一个简单的C＃控制台应用程序可以做到这一点：

using System;

using System.Collections.Generic;

using System.IO;

namespace CopyToFiles

{

class Program

{

static void Main(string[] args)

{

var buffer = new char[100];

var outputs = new List();

foreach (var file in args)

outputs.Add(new StreamWriter(file));

outputs.Add(Console.Out);

int bytesRead;

do

{

bytesRead = Console.In.ReadBlock(buffer, 0, buffer.Length);

outputs.ForEach(o => o.Write(buffer, 0, bytesRead));

} while (bytesRead == buffer.Length);

outputs.ForEach(o => o.Close());

}

}

}

要使用它，只需将source命令传递给程序，并提供要复制输出的任何文件的路径。 例如：

dir | CopyToFiles files1.txt files2.txt

将显示dir的结果，并将结果存储在files1.txt和files2.txt中。

请注意，上面的错误处理方式并不多(任何事情！)，实际上可能并不需要支持多个文件。

Richard answered 2019-02-04T17:58:04Z

17 votes

虽然它有点难看，但这有效：

dir >_ && type _ && type _ > a.txt

它比其他一些解决方案更灵活，因为它可以逐个语句地工作，因此您也可以使用它进行追加。 我在批处理文件中使用这一点来记录和显示消息：

ECHO Print line to screen and log to file. >_ && type _ && type _ >> logfile.txt

是的，您可以重复ECHO语句(一次用于屏幕，第二次重定向到日志文件)，但这看起来一样糟糕，并且有点维护问题。 至少这种方式您不必在两个地方对消息进行更改。

请注意，_只是一个简短的文件名，因此您需要确保在批处理文件的末尾删除它(如果您使用的是批处理文件)。

MTS answered 2019-02-04T17:58:47Z

14 votes

mtee是一个小型实用程序，可以很好地实现此目的。 它是免费的，源是开放的，它只是工作。

你可以在[http://www.commandline.co.uk。]找到它。

在批处理文件中用于显示输出并同时创建日志文件，语法如下所示：

someprocess | mtee /+ mylogfile.txt

其中/ +表示附加输出。

假设您已将mtee复制到PATH中的文件夹中，当然。

Mark answered 2019-02-04T17:59:35Z

9 votes

我同意Brian Rasmussen的观点，unxutils端口是最简单的方法。 在他的脚本页面的批处理文件部分中，Rob van der Woude提供了有关使用MS-DOS和CMD命令的大量信息。 我认为他可能有一个原生的解决方案来解决你的问题，在那里挖掘后我发现了TEE.BAT，这似乎只是一个MS-DOS批量语言实现的tee。 这是一个非常复杂的批处理文件，我的倾向仍然是使用unxutils端口。

Steve Crane answered 2019-02-04T17:59:58Z

8 votes

我想对Saxon Druce的优秀答案进行一些扩展。

如上所述，您可以在当前目录中重定向可执行文件的输出，如下所示：

powershell ".\something.exe | tee test.txt"

但是，这只记录something.exe到something.exe.它也不记录2>&1。

显而易见的解决方案是使用这样的东西：

powershell ".\something.exe 2>&1 | tee test.txt"

但是，这不适用于所有something.exes。 一些something.exes会将2>&1解释为参数并失败。 正确的解决方案是在something.exe周围只有撇号和它的开关和参数，如下所示：

powershell ".\something.exe --switch1 --switch2 … arg1 arg2 …" 2>&1 | tee test.txt

アリスター answered 2019-02-04T18:00:47Z

7 votes

如果您在Windows环境路径中有cygwin，则可以使用：

dir > a.txt | tail -f a.txt

jkdba answered 2019-02-04T18:01:09Z

5 votes

dir 1>a.txt 2>&1 | type a.txt

这将有助于重定向STDOUT和STDERR

rashok answered 2019-02-04T18:01:37Z

4 votes

我也在寻找相同的解决方案，经过一番尝试，我成功地在命令提示符中实现了这一点。 这是我的解决方案：

@Echo off

for /f "Delims=" %%a IN (xyz.bat) do (

%%a > _ && type _ && type _ >> log.txt

)

@Echo on

它甚至还捕获任何PAUSE命令。

Koder101 answered 2019-02-04T18:02:06Z

4 votes

将输出发送到控制台，附加到控制台日志，删除当前命令的输出

dir >> usb-create.1 && type usb-create.1 >> usb-create.log | type usb-create.1 && del usb-create.1

Dennis answered 2019-02-04T18:02:28Z

3 votes

这是我根据其他答案之一使用的样本

@echo off

REM SOME CODE

set __ERROR_LOG=c:\errors.txt

REM set __IPADDRESS=x.x.x.x

REM Test a variable

if not defined __IPADDRESS (

REM Call function with some data and terminate

call :TEE %DATE%,%TIME%,IP ADDRESS IS NOT DEFINED

goto :EOF

)

REM If test happens to be successful, TEE out a message and end script.

call :TEE Script Ended Successful

goto :EOF

REM THE TEE FUNCTION

:TEE

for /f "tokens=*" %%Z in ("%*") do (

> CON ECHO.%%Z

>> "%__ERROR_LOG%" ECHO.%%Z

goto :EOF

)

Ed Radke answered 2019-02-04T18:02:50Z

3 votes

@echo on

set startDate=%date%

set startTime=%time%

set /a sth=%startTime:~0,2%

set /a stm=1%startTime:~3,2% - 100

set /a sts=1%startTime:~6,2% - 100

fullprocess.bat > C:\LOGS\%startDate%_%sth%.%stm%.%sts%.LOG | fullprocess.bat

这将创建一个包含当前日期时间的日志文件，您可以在此过程中使用控制台行

7thSphere answered 2019-02-04T18:03:12Z

3 votes

我知道这是一个非常古老的话题，但在之前的答案中，并没有完全实现以批处理方式编写的实时Tee。 我的解决方案是Batch-JScript混合脚本，它使用JScript部分来获取管道命令的输出，但数据处理在Batch部分完成。 这种方法的优点是任何Batch程序员都可以修改该程序以满足特定需求。 该程序还正确处理其他批处理文件生成的CLS命令的输出，即在检测到CLS命令输出时清除屏幕。

@if (@CodeSection == @Batch) @then

@echo off

setlocal EnableDelayedExpansion

rem APATee.bat: Asynchronous (real time) Tee program, Batch-JScript hybrid version

rem Antonio Perez Ayala

rem The advantage of this program is that the data management is written in Batch code,

rem so any Batch programmer may modify it to fit their own needs.

rem As an example of this feature, CLS command is correctly managed

if "%~1" equ "" (

echo Duplicate the Stdout output of a command in the screen and a disk file

echo/

echo anyCommand ^| APATee teeFile.txt [/A]

echo/

echo If /A switch is given, anyCommand output is *appended* to teeFile.txt

goto :EOF

)

if "%2" equ ":TeeProcess" goto TeeProcess

rem Get the output of CLS command

for /F %%a in ('cls') do set "cls=%%a"

rem If /A switch is not provided, delete the file that receives Tee output

if /I "%~2" neq "/A" if exist %1 del %1

rem Create the semaphore-signal file and start the asynchronous Tee process

echo X > Flag.out

if exist Flag.in del Flag.in

Cscript //nologo //E:JScript "%~F0" | "%~F0" %1 :TeeProcess

del Flag.out

goto :EOF

:TeeProcess

rem Wait for "Data Available" signal

if not exist Flag.in goto TeeProcess

rem Read the line sent by JScript section

set line=

set /P line=

rem Set "Data Read" acknowledgement

ren Flag.in Flag.out

rem Check for the standard "End Of piped File" mark

if "!line!" equ ":_EOF_:" exit /B

rem Correctly manage CLS command

if "!line:~0,1!" equ "!cls!" (

cls

set "line=!line:~1!"

)

rem Duplicate the line in Stdout and the Tee output file

echo(!line!

echo(!line!>> %1

goto TeeProcess

@end

// JScript section

var fso = new ActiveXObject("Scripting.FileSystemObject");

// Process all lines of Stdin

while ( ! WScript.Stdin.AtEndOfStream ) {

// Read the next line from Stdin

var line = WScript.Stdin.ReadLine();

// Wait for "Data Read" acknowledgement

while ( ! fso.FileExists("Flag.out") ) {

WScript.Sleep(10);

}

// Send the line to Batch section

WScript.Stdout.WriteLine(line);

// Set "Data Available" signal

fso.MoveFile("Flag.out", "Flag.in");

}

// Wait for last "Data Read" acknowledgement

while ( ! fso.FileExists("Flag.out") ) {

WScript.Sleep(10);

}

// Send the standard "End Of piped File" mark

WScript.Stdout.WriteLine(":_EOF_:");

fso.MoveFile("Flag.out", "Flag.in");

Aacini answered 2019-02-04T18:03:35Z

3 votes

这样的事情应该做你需要的吗？

%DATE%_%TIME% > c:\a.txt & type c:\a.txt

ipconfig >> c:\a.txt & type c:\a.txt

ping localhost >> c:\a.txt & type c:\a.txt

pause

Richard K answered 2019-02-04T18:03:57Z

2 votes

这是MTS先前答案的变体，但它添加了一些可能对其他人有用的功能。 这是我使用的方法：

命令被设置为变量，可以在以后的整个代码中使用，输出到命令窗口并附加到日志文件，使用set _Temp_Msg_Cmd=该命令已使用胡萝卜net use M: /D /Y %_Temp_Msg_Cmd%字符转义重定向，因此最初不会评估命令

创建一个临时文件，其文件名类似于正在运行的批处理文件，名为net use M: /D /Y %_Temp_Msg_Cmd%，它使用命令行参数扩展语法%~n0来获取批处理文件的名称。

输出附加到单独的日志文件net use M: /D /Y %_Temp_Msg_Cmd%

这是命令序列：

输出和错误消息被发送到临时文件net use M: /D /Y %_Temp_Msg_Cmd%

然后临时文件的内容都是：附加到日志文件net use M: /D /Y %_Temp_Msg_Cmd%

输出到命令窗口net use M: /D /Y %_Temp_Msg_Cmd%

带有该消息的临时文件已删除net use M: /D /Y %_Temp_Msg_Cmd%

这是一个例子：

net use M: /D /Y %_Temp_Msg_Cmd%

这样，命令可以简单地在批处理文件中的后续命令之后添加，该批处理文件看起来更清晰：

net use M: /D /Y %_Temp_Msg_Cmd%

这也可以添加到其他命令的末尾。 据我所知，当消息有多行时它将起作用。 例如，如果出现错误消息，则以下命令输出两行：

net use M: /D /Y %_Temp_Msg_Cmd%

ClearBlueSky85 answered 2019-02-04T18:05:49Z

1 votes

我使用带有“for”语句的批处理子例程来一次获取一行命令输出，并将该行写入文件并将其输出到控制台。

@echo off

set logfile=test.log

call :ExecuteAndTee dir C:\Program Files

Exit /B 0

:ExecuteAndTee

setlocal enabledelayedexpansion

echo Executing '%*'

for /f "delims=" %%a in ('%* 2^>^&1') do (echo.%%a & echo.%%a>>%logfile%)

endlocal

Exit /B 0

Cody Barnes answered 2019-02-04T18:06:11Z

0 votes

如果你想要在屏幕上看到的东西，即使批处理文件被重定向到文件，以下内容也会有所帮助。 如果重定向到文件，也可以使用设备CON

例：

ECHO first line on normal stdout. maybe redirected

ECHO second line on normal stdout again. maybe redirected

ECHO third line is to ask the user. not redirected >CON

ECHO fourth line on normal stdout again. maybe redirected

另请参阅良好的重定向说明：[http://www.p-dd.com/chapter7-page14.html]

answered 2019-02-04T18:06:42Z

0 votes

如何显示和重定向输出   到一个文件。 假设我使用dos   命令，dir＆gt; test.txt，这个命令   将输出重定向到文件test.txt   没有显示结果。 如何   写一个命令来显示输出   并使用输出将输出重定向到文件   DOS即Windows命令提示符，而不是   在UNIX / LINUX中。

您可能会发现biterscripting([http://www.biterscripting.com])中的这些命令很有用。

var str output

lf > $output

echo $output # Will show output on screen.

echo $output > "test.txt" # Will write output to file test.txt.

system start "test.txt" # Will open file test.txt for viewing/editing.

P M answered 2019-02-04T18:07:11Z

0 votes

这实时工作，但也有点难看，性能很慢。 还未经过充分测试：

@echo off

cls

SET MYCOMMAND=dir /B

ECHO File called 'test.bat' > out.txt

for /f "usebackq delims=" %%I in (`%MYCOMMAND%`) do (

ECHO %%I

ECHO %%I >> out.txt

)

pause

djangofan answered 2019-02-04T18:07:33Z

0 votes

另一种方法是在程序中将stdout发送到stderr：

在java中：

System.setOut(new PrintStream(new TeeOutputStream(System.out, System.err)));

然后，在您的dos批处理文件中：java program > log.txt

stdout将转到日志文件，stderr(相同的数据)将显示在控制台上。

The Coordinator answered 2019-02-04T18:08:15Z

0 votes

就像unix一样

dir | tee a.txt

工作在Windows XP上，它需要安装mksnt

它会显示在提示符上并附加到文件中

user2346926 answered 2019-02-04T18:08:56Z

0 votes

我在大多数机器上安装了perl，所以使用perl：tee.pl来回答

my $file = shift || "tee.dat";

open $output, ">", $file or die "unable to open $file as output: $!";

while()

{

print $_;

print $output $_;

}

close $output;

dir | perl tee.pl要么dir | perl tee.pl dir.bat

原油和未经测试。

DannyK answered 2019-02-04T18:09:31Z