c语言网红时钟代码源码,网红文本时钟PC版

.版本 2

.支持库 iext2

.程序集 窗口程序集_启动窗口

.程序集变量 集_小时, 整数型, , "0"

.程序集变量 集_分钟, 整数型, , "0"

.程序集变量 集_秒, 整数型, , "0"

.程序集变量 集_内容, 整数型, , "2"

.子程序 __启动窗口_创建完毕

.局部变量 n1, 整数型

其他内容 ()

.计次循环首 (60, n1)

.如果真 (n1 ≤ 24)

创建时间物体 (160, (n1 － 1) × 15, 0, 取文本小时 (n1 － 1, 真))

.如果真结束

创建时间物体 (220, (n1 － 1) × 6, 1, 取文本分钟 (n1 － 1, 真))

创建时间物体 (280, (n1 － 1) × 6, 2, 取文本秒 (n1 － 1, 真))

.计次循环尾 ()

时钟1.时钟周期 ＝ 1000

.子程序 其他内容

.局部变量 标识, 整数型

.局部变量 字体, 字体

.局部变量 局_宽度, 整数型

.局部变量 局_高度, 整数型

字体.字体名称 ＝ “隶书”

字体.字体大小 ＝ 30

字体.加粗 ＝ 真

动画框1.画矩形 (450, 425, 645, 450)

标识 ＝ 动画框1.创建物体 (, 20, 20, 真, )

动画框1.置文本 (标识, “网红文本时钟”, 字体, #蓝色)

局_宽度 ＝ 动画框1.取物体宽度 (标识)

动画框1.趋向色变换 (标识, #红色, 50)

动画框1.置物体位置 (标识, (动画框1.宽度 － 局_宽度) ÷ 2, 20, )

字体.字体名称 ＝ “楷体”

字体.字体大小 ＝ 16

标识 ＝ 动画框1.创建物体 (, 20, 80, 真, )

动画框1.置文本 (标识, “明明什么都没有干就已经：”, 字体, #褐绿)

动画框1.趋向色变换 (标识, #蓝色, 30)

标识 ＝ 动画框1.创建物体 (, 20, 110, 真, )

动画框1.置文本 (标识, 取文本小时 (0, 真) ＋ 取文本分钟 (0, 真) ＋ 取文本秒 (0, 真), 字体, #墨绿)

集_内容 [1] ＝ 标识

标识 ＝ 动画框1.创建物体 (, 440, 110, 真, )

字体.字体大小 ＝ 128

字体.字体名称 ＝ “华文行楷”

动画框1.置文本 (标识, “李”, 字体, #红褐)

动画框1.趋向色变换 (标识, #深灰, 40)

局_宽度 ＝ 动画框1.取物体宽度 (标识)

局_高度 ＝ 动画框1.取物体高度 (标识)

动画框1.置物体位置 (标识, (动画框1.宽度 － 局_宽度) ÷ 2, (动画框1.高度 － 200) ÷ 2 － 局_高度 ÷ 2 ＋ 120, )

集_内容 [2] ＝ 标识

.子程序 创建时间物体

.参数 半径, 整数型

.参数 角度, 整数型

.参数 类型, 整数型

.参数 内容, 文本型, 可空

.局部变量 X, 整数型

.局部变量 Y, 整数型

.局部变量 标识, 整数型

.局部变量 字体, 字体

字体.字体名称 ＝ “宋体”

字体.字体大小 ＝ 10

字体.加粗 ＝ 真

X ＝ 四舍五入 (300 ＋ 半径 × 求余弦 (角度 × #pi ÷ 180), 0)

Y ＝ 四舍五入 (430 ＋ 半径 × 求正弦 (角度 × #pi ÷ 180), 0)

标识 ＝ 动画框1.创建物体 (, X, Y, 真, )

动画框1.置文本 (标识, 内容, 字体, #橙黄)

动画框1.趋向色变换 (标识, #红色, 30)

动画框1.置角度 (标识, 角度)

动画框1.置旋转跟随 (标识, 真)

.判断开始 (类型 ＝ 0)

加入成员 (集_小时, 标识)

.判断 (类型 ＝ 1)

加入成员 (集_分钟, 标识)

.默认

加入成员 (集_秒, 标识)

.判断结束

.子程序 取文本小时, 文本型

.参数 小时, 整数型

.参数 加当前值, 逻辑型, 可空

.局部变量 局_小时, 文本型, , "0"

局_小时 ＝ 分割文本 (#常量_小时, #换行符, )

.如果真 (加当前值)

小时 ＝ 小时 ＋ 取小时 (取现行时间 ())

.如果真结束

.如果 (小时 ％ 24 ＝ 0)

返回 (局_小时 [1])

.否则

返回 (局_小时 [小时 ％ 24 ＋ 1])

.如果结束

.子程序 取文本分钟, 文本型

.参数 分钟, 整数型

.参数 加当前值, 逻辑型, 可空

.局部变量 局_分钟, 文本型, , "0"

局_分钟 ＝ 分割文本 (#常量_分钟, #换行符, )

.如果真 (加当前值)

分钟 ＝ 分钟 ＋ 取分钟 (取现行时间 ())

.如果真结束

.如果 (分钟 ％ 60 ＝ 0)

返回 (局_分钟 [1])

.否则

返回 (局_分钟 [分钟 ％ 60 ＋ 1])

.如果结束

.子程序 取文本秒, 文本型

.参数 秒, 整数型

.参数 加当前值, 逻辑型, 可空

.局部变量 局_秒, 文本型, , "0"

局_秒 ＝ 分割文本 (#常量_秒, #换行符, )

.如果真 (加当前值)

秒 ＝ 秒 ＋ 取秒 (取现行时间 ())

.如果真结束

.如果 (秒 ％ 60 ＝ 0)

返回 (局_秒 [1])

.否则

返回 (局_秒 [秒 ％ 60 ＋ 1])

.如果结束

.子程序 置当前秒

.局部变量 n1, 整数型

.局部变量 局_秒, 整数型

局_秒 ＝ 取秒 (取现行时间 ())

.计次循环首 (60, n1)

动画框1.置文本 (集_秒 [n1], 取文本秒 (局_秒 ＋ n1 － 1), , )

.计次循环尾 ()

.子程序 置当前分钟

.局部变量 n1, 整数型

.局部变量 局_分钟, 整数型

局_分钟 ＝ 取分钟 (取现行时间 ())

.如果真 (取文本分钟 (局_分钟) ＝ 动画框1.取文本 (集_分钟 [1]))

返回 ()

.如果真结束

.计次循环首 (60, n1)

动画框1.置文本 (集_分钟 [n1], 取文本分钟 (局_分钟 ＋ n1 － 1), , )

.计次循环尾 ()

.子程序 置当前小时

.局部变量 n1, 整数型

.局部变量 局_小时, 整数型

局_小时 ＝ 取小时 (取现行时间 ())

.如果真 (取文本小时 (局_小时) ＝ 动画框1.取文本 (集_小时 [1]))

返回 ()

.如果真结束

.计次循环首 (24, n1)

动画框1.置文本 (集_小时 [n1], 取文本小时 (局_小时 ＋ n1 － 1), , )

.计次循环尾 ()

.子程序 _时钟1_周期事件

置当前秒 ()

置当前分钟 ()

置当前小时 ()

动画框1.置文本 (集_内容 [1], 动画框1.取文本 (集_小时 [1]) ＋ 动画框1.取文本 (集_分钟 [1]) ＋ 动画框1.取文本 (集_秒 [1]), , )

.子程序 _动画框1_物体左键被放开

.参数 物体标识值, 整数型

.参数 已被按下物体, 整数型

.局部变量 姓名, 文本型

.如果真 (已被按下物体 ＝ 集_内容 [2])

.如果真 (输入框 (“请输入你的姓”, “信息”, 动画框1.取文本 (集_内容 [2]), 姓名, , ))

姓名 ＝ 取文本左边 (姓名, 2)

动画框1.置文本 (集_内容 [2], 姓名, , )

.如果真结束

.如果真结束