docker实践第二版pdf 网盘_vba实践+按章节拆分扫描版pdf文档-CSDN博客

vba实践+按章节拆分扫描版pdf文档

声明：在执行操作前，请注意备份文档

要把扫描版pdf文档按章节拆分，并以章节标题命名，保存成多个文档。

扫描版pdf文档没有文字信息，也没有书签，想要对这种pdf按章节拆分，就需要从图片中获得相关信息。所以在前期通过OCR软件对pdf进行文字识别，导出word文档，再从文档中提取标题文本、章节内容的起始页码和结束页码等信息，并放到一个txt文档中。从word文档中提取相关信息的操作见文章

阿德：vba实践+提取word章节标题文本及其起止页码信息zhuanlan.zhihu.com

这个txt文件的结构如下图所示。

实现代码如下所示，代码的运行环境为Win8.1，Word2010 VBA，Acrobat Pro DC，在本机测试成功。主要思路是使用do while 循环，逐行读取文本文件的信息，把这些信息放到一个数组中，然后使用PDoc.InsertPages方法提取相应的pdf页面，插入到新文档中，然后保存。

关于PDoc. InsertPages方法的详细信息可参考文章

阿德：VBA实践+批量合并pdfzhuanlan.zhihu.com

Sub 按章节拆分pdf文档()
'章节标题及页码信息已经提前记录于一个txt文件中

Dim pdfFile As String
Dim sPDdoc As New Acrobat.AcroPDDoc, tPDdoc As New Acrobat.AcroPDDoc
Dim TitInfor, TitStr As String '不能直接把TitInfor声明为数组

Open "F:userdataDesktopTitlePage.TXT" For Input As #1
pdfFile = "F:userdataDesktop三基32k五版-交付.pdf" '要拆分的pdf文档路径

'打开要拆分的pdf文档,不可见的。
If Not sPDdoc.Open(pdfFile) Then
    MsgBox "文件打开不成功，请检查文件是否存在"
    Set sPDdoc = Nothing
    Exit Sub
End If

Line Input #1, TitStr '读取第一行数据
Do While Not EOF(1) '未达到结尾时执行循环。应该在文本文件末尾再加一行内容行，确保所有行读取完
    tPDdoc.Create '创建pdf空白文档，不含页面
    TitInfor = Split(TitStr, vbTab)
    tPDdoc.InsertPages -1, sPDdoc, CInt(TitInfor(1)) - 1, CInt(TitInfor(2)) - CInt(TitInfor(1)) + 1, 0 '插入页面。因为tpddoc是空白文档，没有页面，所以第一参数为-1。
    tPDdoc.Save PDSaveFull, "F:userdataDesktop" & TitInfor(0) & ".pdf" '保存文档
    tPDdoc.Close '关闭文档
 
    Line Input #1, TitStr '读取下一行数据
Loop

sPDdoc.Close
Close #1
Set sPDdoc = Nothing
Set tPDdoc = Nothing
MsgBox "完成！"

End Sub