第2章 编写MBR主引导记录，让我们开始掌权

计算机的启动过程

在开机的一瞬间，也就是接电的一瞬间，CPU的cs:ip寄存器被强制初始化为0xF000:0xFFF0。由于开机的时候处于实模式，在实模式下的段基址要乘以16，也就是左移4位，于是0xF000:0xFFF0的等效地址将是0xFFFF0,此地址便是BIOS的入口地址。(BIOS是在实模式下运行的，实模式只能访问1MB，20位地址线，如果寄存器超过了其最大值，溢出的部分就会回卷到0)，此处只有16个字节，真正的逻辑不在这里，此处的代码只是个跳转指令：jmp far f000:e05b，跳转到BIOS代码真正开始的地方，接下来BIOS便马不停蹄地检测内存、显卡等外设信息，当检测通过后，并初始化好硬件后，开始在内存中的0x000~0x3FFF处建立数据结构，中断向量表并填写中断例程。
注：正常电脑的BIOS应该是直接写在主板上面的，可以CPU直接寻址的，也就是实模式下地址有的是访问到真正的主板上插的内存，有的是外设，还有BIOS等，都占用了地址。如下图2-1所示。
BIOS最后一项工作是校验位于0盘0道1扇区的内容，如果此扇区末尾的两个字节分别时魔数0x55和0xaa，BIOS便认为此扇区中确实存在可执行的程序（此程序便是MBR），便加载到物理地址0x7c00，随后跳转到0x7c00继续执行。
MBR的主要功能就是和显示器进行通信，之后便读取第2块扇区信息，读取完bootloader之后加载到内存后跳转过去执行。
bootloader会构建全局描述符表，获取内存的大小，进入保护模式，创建页目录及页表并初始化页内存位图，最后加载内核。
内核放在第二扇区，而且其是一个elf格式的可执行文件，加载到内存后经过解析即可运行。
内核先进行初始化：初始化中断、初始化内存管理系统、初始化线程相关结构、初始化PIT、控制台初始化、键盘初始化、tss初始化、初始化系统调用、初始化硬盘、初始化文件系统等。

软件接力的第一棒——BIOS

BIOS，Basic Input & Output System，即基本输入输出系统。

地址0~0x9FFFF处的是DRAM，Dynamic Random Access Memory，即动态随机访问内存，有640KB，对应到了插到主板上的内存条；
地址0xF0000~0xFFFFF，这64KB是ROM，这里面存的就是BIOS的代码；BIOS的主要工作是检测、初始化硬件。建立了中断向量表，这样就可以通过“int 中断号”来实现相关的硬件调用，当然BIOS建立的这些功能就是对硬件的IO操作，也就是输入输出。

BIOS是如何苏醒过来的？

BIOS 代码所做的工作也是一成不变的，而且在正常情况下，其本身是不需要修改的，平时听说的那些主板坏了要刷 BIOS 的情况属于例外。于是 BIOS 顺理成章地便被写进此 ROM.
在开机的一瞬间，也就是接电的一瞬间， CPU 的 CS: ip 寄存器被强制初始化为 00xF000: 0xFFF0。执行一条跳转指令后进入真正的BIOS初始化流程.
执行最后BIOS将MBR加载到0X7C00处，并将接力棒交给它，（MBR位于磁盘0柱面、0磁头、1扇区）。
最后，MBR初步实现代码如下：

;主引导程序 
;------------------------------------------------------------
SECTION MBR vstart=0x7c00         
mov ax,cs      
mov ds,ax
mov es,ax
mov ss,ax
mov fs,ax
mov sp,0x7c00
mov ax,0xb800
mov gs,ax

; 清屏 利用0x06号功能，上卷全部行，则可清屏。
; -----------------------------------------------------------
;INT 0x10   功能号:0x06	   功能描述:上卷窗口
;------------------------------------------------------
;输入：
;AH 功能号= 0x06
;AL = 上卷的行数(如果为0,表示全部)
;BH = 上卷行属性
;(CL,CH) = 窗口左上角的(X,Y)位置
;(DL,DH) = 窗口右下角的(X,Y)位置
;无返回值：
mov     ax, 0x600
mov     bx, 0x700
mov     cx, 0                   ; 左上角: (0, 0)
mov     dx, 0x184f		   ; 右下角: (80,25),
; 因为VGA文本模式中，一行只能容纳80个字符,共25行。
; 下标从0开始，所以0x18=24,0x4f=79
int     0x10                    ; int 0x10

;;;;;;;;;    下面这三行代码是获取光标位置    ;;;;;;;;;
;.get_cursor获取当前光标位置,在光标位置处打印字符,目的是避免打印字符混乱，覆盖别人的输出。
; 其实这是防君子不防小人的做法,万一人家不在光标处打印，自己打印的内容同样也会被别人覆盖。
; 不管别人了，咱们做好自己的就行
mov ah, 3	  ; 输入: 3号子功能是获取光标位置,需要存入ah寄存器
mov bh, 0	  ; bh寄存器存储的是待获取光标的页号

int 0x10	  ; 输出: ch=光标开始行,cl=光标结束行
; dh=光标所在行号,dl=光标所在列号

;;;;;;;;;;;;;;    获取光标位置结束    ;;;;;;;;;;;;;;;;


;;;;;;;;;     打印字符串    ;;;;;;;;;;;
;还是用10h中断,不过这次是调用13号子功能打印字符串
mov ax, message 
mov bp, ax     ; es:bp 为串首地址, es此时同cs一致，开头时已经为sreg初始化

; 光标位置要用到dx寄存器中内容,cx中的光标位置可忽略
mov cx, 5      ; cx 为串长度,不包括结束符0的字符个数
mov ax, 0x1301 ; 子功能号13是显示字符及属性,要存入ah寄存器,
; al设置写字符方式,只有低2位有意义
; ah=01,显示字符串，光标跟随移动
mov bx, 0x2	  ; bh存储要显示的页号,此处是第0页, bl中是字符属性, 属性黑底绿字(bl = 02h)
int 0x10       ; 执行BIOS 0x10 号中断
;;;;;;;;;      打字字符串结束	 ;;;;;;;;;;;;;;;

jmp $;	  ; 使程序悬停在此

message db "1 MBR"
times 510-($-$$) db 0
db 0x55,0xaa