【转载】U-Boot启动过程分析(一)

目标是要将u-boot移植到mini2440开发板上，但是为了使移植能顺利进行，参考现有的开发板smk2410是一个不错的选择。

U-Boot版本：u-boot-2010.03

开发板型号：smdk2410 / mini2440

一、U-Boot启动第一阶段代码分析

U-Boot的启动是根据cpu/arm920t/u-boot.lds中指定的连接方式来运行的。U-Boot.lds文件分析：

关于.lds文件GNU语法规则，请参照http://blogold.chinaunix.net/u4/120176/showart_2382961.html

U-Boot.lds文件的作用决定一个可执行程序的各个段的存储位置以及入口地址，这也是链接定位的作用。其语法格式如下：

SECTIONS {

 ...

secname start BLOCK(align) (NOLOAD) : AT ( ldadr )

  { contents } >region :phdr =fill

...

}

secname和contents是必须的，前者用来命名这个段，后者用来确定代码中的什么部分放在这个段，以下是对这个描述中的一些关键字的解释。

【1】secname：段名。

【2】contents：决定哪些内容放在本段，可以是整个目标文件，也可以是目标文件中的某段（代码段、数据段等）。

【3】start：是段的重定位地址，本段连接（运行）的地址，如果代码中有位置无关指令，程序运行时这个段必须放在这个地址上。start可以用任意一种描述地址的符号来描述。

【4】AT（ldadr）：定义本段存储（加载）的地址，如果不使用这个选项，则加载地址等于运行地址，通过这个选项可以控制各段分别保存于输出文件中不同的位置。

ENTRY(begin)

SECTION

{

.=0x30000000;

.text:{*(.text)}

.data:{*(.data)}

.bss:{*(.bss)}

}

.text @代码段

.data @初始化数据段

.bss @未初始化数据段

需要注意的是，源程序中.bss段应该在.text之前。

其中，ENTRY(begin)指明程序的入口点为begin标号；.=0x00300000指明目标代码的起始地址为0x30000000，这一段地址为 MX1的片内RAM；.text:{*(.text)}表示从0x30000000开始放置所有目标文件的代码段，随后的.data:{* (.data)}表示数据段从代码段的末尾开始，再后是.bss段。

接着看u-boot.lds的内容：

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")

/*指定输出可执行文件是elf格式,32位ARM指令,小端*/

OUTPUT_ARCH(arm) /*指定输出可执行文件的平台为ARM*/

ENTRY(_start) /*指定输出可执行文件的起始代码段为_start*/

SECTIONS

{

/*指定可执行image文件的全局入口点，通常这个地址都放在ROM(flash)0x0位置。必须使编译器知道这个地址，通常都是修改此处来完成*/

. = 0x00000000; /*;从0x0位置开始*/

. = ALIGN(4); /*代码以4字节对齐*/

       .text :

       {

           cpu/arm920t/start.o (.text) /*代码的第一个代码部分*/

           *(.text) /*其它代码部分*/

       }

. = ALIGN(4);

.rodata : { *(.rodata) } /*指定只读数据段*/

. = ALIGN(4);

.data : { *(.data) } /*指定读/写数据段*/

. = ALIGN(4);

.got : { *(.got) } /*指定got段, got段式是uboot自定义的一个段, 非标准段*/

. = .;

__u_boot_cmd_start = .; /*把__u_boot_cmd_start赋值为当前位置, 即起始位*/

       .u_boot_cmd : { *(.u_boot_cmd) } /*指定u_boot_cmd段, uboot把所有的uboot命令放在该段.*/

__u_boot_cmd_end = .; /*把__u_boot_cmd_end赋值为当前位置,即结束位置*/

. = ALIGN(4);

__bss_start = .; /*把__bss_start赋值为当前位置,即bss段的开始位置*/

.bss : { *(.bss) } /*指定bss段*/

_end = .; /*把_end赋值为当前位置,即bss段的结束位置*/

}

通过以上伪操作，我们可以得到U-Boot在上电后开始执行程序的第一个入口点_start。U-Boot启动第一阶段流程如下：

 图 1.1 U-Boot第二阶段执行流程

 第一个链接的是cpu/arm920t/start.o，因此u-boot.bin的入口代码在cpu/arm920t/start.o中，其源代码在cpu/arm920t/start.S中。下面我们来分析cpu/arm920t/start.S的执行。

【1】硬件设备初始化

<1>设置异常向量

       cpu/arm920t/start.S开头有如下的代码：

.globl _start

_start:    b  start_code   /*复位 ，_start表示的是绝对地址,存放的是b start_code"这条指令的机器码*/

       ldr   pc, _undefined_instruction   /* 未定义指令向量 */

       ldr   pc, _software_interrupt          /*  软件中断向量 */

       ldr   pc, _prefetch_abort                 /*  预取指令异常向量 */

       ldr   pc, _data_abort                        /*  数据操作异常向量 */

       ldr   pc, _not_used                           /*  未使用   */

       ldr   pc, _irq                                      /*  irq中断向量  */

       ldr   pc, _fiq                                       /*  fiq中断向量  */

注意ldr伪指令对标号表示的绝对地址的直接引用 。

/*  中断向量表入口地址，.word的意义为在当前地址处放入一个16bits值*/

_undefined_instruction:    .word undefined_instruction

_software_interrupt:  .word software_interrupt

_prefetch_abort:  .word prefetch_abort

_data_abort:        .word data_abort

_not_used:          .word not_used

_irq:                     .word irq

_fiq:                     .word fiq

       .balignl 16,0xdeadbeef

以上代码设置了ARM异常向量表， 各个异常向量介绍如下：

表 1.1 ARM异常中断向量表

地址	异常	进入模式	描述
0x00000000	复位	管理模式	复位电平有效时，产生复位异常，程序跳转到复位处理程序处执行
0x00000004	未定义指令	未定义模式	遇到不能处理的指令时，产生未定义指令异常
0x00000008	软件中断	管理模式	执行SWI指令产生，用于用户模式下的程序调用特权操作指令
0x0000000c	预存指令	中止模式	处理器预取指令的地址不存在，或该地址不允许当前指令访问，产生指令预取中止异常
0x00000010	数据操作	中止模式	处理器数据访问指令的地址不存在，或该地址不允许当前指令访问时，产生数据中止异常
0x00000014	未使用	未使用	未使用
0x00000018	IRQ	IRQ	外部中断请求有效，且CPSR中的I位为0时，产生IRQ异常
0x0000001c	FIQ	FIQ	快速中断请求引脚有效，且CPSR中的F位为0时，产生FIQ异常

   

 在cpu/arm920t/start.S中还有这些异常对应的异常处理程序。当一个异常产生时，CPU根据异常号在异常向量表中找到对应的异常向量，然后执行异常向量处的跳转指令，CPU就跳转到对应的异常处理程序执行。

其中复位异常向量的指令"b start_code"决定了U-Boot启动后将自动跳转到标号"start_code"处执行。      

_TEXT_BASE: /*定义SDRAM中的uboot起始地址*/ 

    .word    TEXT_BASE 

.globl _armboot_start 

_armboot_start: 

    .word _start /* 这句话的意思应该是在_armboot_start标号处，保存了_start的值，也就是说，_armboot_start是存放_start的地址*/

/* 

 * These are defined in the board-specific linker script. 

 */ 

.globl _bss_start 

_bss_start: 

    .word __bss_start 

 

.globl _bss_end 

_bss_end: 

    .word _end /*_bss_end是存放_end的地址*/       

 

<2>CPU进入SVC模式

start_code:

       /*

        * set the cpu to SVC32 mode

        */

       mrs r0, cpsr

       bic  r0, r0, #0x1f    /*工作模式位清零 */

       orr   r0, r0, #0xd3 /*工作模式位设置为"10011"（管理模式），并将中断禁止位和快中断禁止位置1 */

       msr cpsr, r0

       以上代码将CPU的工作模式位设置为管理模式，并将中断禁止位和快中断禁止位置一，从而屏蔽了IRQ和FIQ中断。

<3>设置控制寄存器地址

#ifdef CONFIG_S3C24X0

    /* turn off the watchdog */

# if defined(CONFIG_S3C2400)

#  define pWTCON 0x15300000

#  define INTMSK  0x14400008

#  define CLKDIVN      0x14800014

#else      /* s3c2410与s3c2440下面4个寄存器地址相同 */

#  define pWTCON 0x53000000               /* WATCHDOG控制寄存器地址 */

#  define INTMSK  0x4A000008                     /* INTMSK中断控制寄存器地址  */

#  define INTSUBMSK 0x4A00001C      /* INTSUBMSK寄存器地址 */

#  define CLKDIVN      0x4C000014                   /* CLKDIVN寄存器地址 */

# endif

       对与s3c2440开发板，以上代码完成了WATCHDOG，INTMSK，INTSUBMSK，CLKDIVN四个寄存器的地址的设置。各个寄存器地址参见其CPU s3c2410/2440数据手册。

<4>关闭看门狗。启动时不希望去喂狗，如果不关，就需要间隔一定时间去喂狗，否则会导致系统重启。

ldr   r0, =pWTCON

mov       r1, #0x0

str   r1, [r0]   /* 看门狗控制器的最低位为0时，看门狗不输出复位信号 */

   以上代码向看门狗控制寄存器写入0，关闭看门狗。否则在U-Boot启动过程中，CPU将不断重启。此处=表示此ldr是一条伪指令，而非ARM指令集的ldr伪指令ldr作用是大范围的地址读取功能，用来加载32位立即数或者一个地址值到指定的寄存器，其参数有"="符号,一般用在加载外围功能部件的寄存器地址，实现一些控制操作。

 

<5>屏蔽中断

       /*

        * mask all IRQs by setting all bits in the INTMR - default

        */

       mov       r1, #0xffffffff     /* 某位被置1则对应的中断被屏蔽 */

       ldr   r0, =INTMSK

       str   r1, [r0]

INTMSK是主中断屏蔽寄存器，每一位对应SRCPND（中断源引脚寄存器）中的一位，表明SRCPND相应位代表的中断请求是否被CPU所处理。INTMSK寄存器是一个32位的寄存器，每位对应一个中断，向其中写入0xffffffff就将INTMSK寄存器全部位置1，从而屏蔽对应的中断。

# if defined(CONFIG_S3C2410)

          ldr  r1, =0x3fff      

          ldr  r0, =INTSUBMSK

          str  r1, [r0]

# endif

INTSUBMSK次中断屏蔽寄存器，每一位对应SUBSRCPND中的一位，表明SUBSRCPND相应位代表的中断请求是否被CPU所处理。INTSUBMSK寄存器是一个32位的寄存器，但是这里只使用了低14位。向其中写入0x3fff就是将INTSUBMSK寄存器全部有效位（低14位）置1，从而屏蔽对应的中断。

<6>设置时钟寄存器

设置HCLK为FCLK/2，PCLK为FCLK/4， FCLK为CPU产生clock，HCLK为AHB总线上的设备产生clock，PCLK为APB总线上的设备产生clock。

/* FCLK:HCLK:PCLK = 1:2:4 */

       /* default FCLK is 120 MHz ! */

       ldr   r0, =CLKDIVN

       mov       r1, #3

       str   r1, [r0]

#endif /* CONFIG_S3C24X0 */

CPU上电几毫秒后，晶振输出稳定，FCLK=Fin（晶振频率），CPU开始执行指令。但实际上，FCLK可以高于Fin，为了提高系统时钟，需要用软件来启用PLL。这就需要设置CLKDIVN，MPLLCON，UPLLCON这3个寄存器。CLKDIVN寄存器用于设置FCLK，HCLK，PCLK三者间的比例，可以根据表1.2来设置。

表 1.2 S3C2440 的CLKDIVN寄存器格式

CLKDIVN	位	说明	初始值
HDIVN	[2:1]	00 : HCLK = FCLK/1. 01 : HCLK = FCLK/2. 10 : HCLK = FCLK/4 （当 CAMDIVN[9] = 0 时） HCLK= FCLK/8  （当 CAMDIVN[9] = 1 时） 11 : HCLK = FCLK/3 （当 CAMDIVN[8] = 0 时） HCLK = FCLK/6 （当 CAMDIVN[8] = 1时）	00
PDIVN	[0]	0: PCLK = HCLK/1   1: PCLK = HCLK/2	0

 设置CLKDIVN为5，就将HDIVN设置为二进制的10，由于CAMDIVN[9]没有被改变过，取默认值0，因此HCLK = FCLK/4。PDIVN被设置为1，因此PCLK= HCLK/2。因此分频比FCLK:HCLK:PCLK = 1:4:8 。

 MPLLCON寄存器用于设置FCLK与Fin的倍数。MPLLCON的位[19:12]称为MDIV，位[9:4]称为PDIV，位[1:0]称为SDIV。

 对于S3C2440，FCLK与Fin的关系如下面公式：

MPLL(FCLK) = (2×m×Fin)/(p× 2^s)

其中： m=MDIC+8，p=PDIV+2，s=SDIV

通过P 值来对输入频率（Fin）来进行分频，通过m值来对VCO的输出频率进行分频，其输出频率被输入到一个相位频率侦测器(PFD)；通过s 值来对VCO 的输出频率进行分频，其分频器S的输出是Mpll(从Mpll 模块的输出频率)。

MPLLCON与UPLLCON的值可以根据CPU数据手册中"PLL VALUE SELECTION TABLE"设置。该表部分摘录如下：

表 1.3 推荐PLL值

输入频率	输出频率	MDIV	PDIV	SDIV
12.0000MHz	48.00 MHz	56(0x38)	2	2
12.0000MHz	405.00 MHz	127(0x7f)	2	1

 

 例如，打算移植到mini2440开发板时，其系统主频设置为405MHZ，USB时钟频率设置为48MHZ时，系统可以稳定运行，因此设置MPLLCON与UPLLCON为：

 MPLLCON=(0x7f<<12) | (0x02<<4) | (0x01) = 0x7f021

 UPLLCON=(0x38<<12) | (0x02<<4) | (0x02) = 0x38022

 

【2】 执行cpu_init_crit关闭MMU和cache

    

#ifndef CONFIG_SKIP_LOWLEVEL_INIT

       bl    cpu_init_crit

#endif

cpu_init_crit这段代码在U-Boot正常启动时才需要执行，若将U-Boot从RAM中启动则应该注释掉这段代码。

下面分析一下cpu_init_crit到底做了什么：

#ifndef CONFIG_SKIP_LOWLEVEL_INIT

cpu_init_crit:

/*

 * 使数据cache与指令cache无效 */

 */ 

mov       r0, #0 /*comment 1 start*/

mcr p15, 0, r0, c7, c7, 0    /* 向c7写入0将使ICache与DCache无效*/

mcr p15, 0, r0, c8, c7, 0    /* 向c8写入0将使TLB失效 **//* comment 1 end*/

/*

* disable MMU stuff and caches

*/

mrc p15, 0, r0, c1, c0, 0    /*  读出控制寄存器到r0中  */

bic  r0, r0, #0x00002300   @ clear bits 13, 9:8 (--V- --RS)

bic  r0, r0, #0x00000087   @ clear bits 7, 2:0 (B--- -CAM)

orr   r0, r0, #0x00000002   @ set bit 2 (A) Align

orr   r0, r0, #0x00001000   @ set bit 12 (I) I-Cache

mcr p15, 0, r0, c1, c0, 0    /*  保存r0到控制寄存器  */

/*

* before relocating, we have to setup RAM timing

* because memory timing is board-dependend, you will

* find a lowlevel_init.S in your board directory.

 */

mov       ip, lr

bl    lowlevel_init

mov       lr, ip

mov       pc, lr

#endif /* CONFIG_SKIP_LOWLEVEL_INIT */

 代码中的c0，c1，c7，c8都是ARM920T的协处理器CP15的寄存器。其中c7是cache控制寄存器，c8是TLB控制寄存器。325~327行代码将0写入c7、c8，使Cache，TLB内容无效。

 第comment 1 start ~ comment 1 end行代码关闭了MMU。这是通过修改CP15的c1寄存器来实现的，先看CP15的c1寄存器的格式（仅列出代码中用到的位）：

表 1.4 CP15的c1寄存器格式(部分)

15	14	13	12	11	10	9	8	7	6	5	4	3	2	1	0
.	.	V	I	.	.	R	S	B	.	.	.	.	C	A	M

各个位的意义如下：

V :  表示异常向量表所在的位置，0：异常向量在0x00000000；1：异常向量在 0xFFFF0000
I :  0 ：关闭ICaches；1 ：开启ICaches
R、S : 用来与页表中的描述符一起确定内存的访问权限
B :  0 ：CPU为小字节序；1 ： CPU为大字节序
C :  0：关闭DCaches；1：开启DCaches
A :  0：数据访问时不进行地址对齐检查；1：数据访问时进行地址对齐检查
M :  0：关闭MMU；1：开启MMU

       332~337行代码将c1的 M位置零，关闭了MMU。

【3】初始化RAM控制寄存器

 其中的lowlevel_init就完成了内存初始化的工作，由于内存初始化是依赖于开发板的，因此lowlevel_init的代码一般放在board下面相应的目录中。对于smdk2410，lowlevel_init在board/Samsung/smdk2410/lowlevel_init.S中定义如下：

45  #define BWSCON   0x48000000        /* 13个存储控制器的开始地址 */

  … …

129  _TEXT_BASE:

130      .word     TEXT_BASE

131 

132  .globl lowlevel_init

133  lowlevel_init:

134      /* memory control configuration */

135      /* make r0 relative the current location so that it */

136      /* reads SMRDATA out of FLASH rather than memory ! */

137      ldr     r0, =SMRDATA

138      ldr   r1, _TEXT_BASE

139      sub  r0, r0, r1              /* SMRDATA减 _TEXT_BASE就是13个寄存器的偏移地址 */

140      ldr   r1, =BWSCON   /* Bus Width Status Controller */

141      add     r2, r0, #13*4

142  0:

143      ldr     r3, [r0], #4    /*将13个寄存器的值逐一赋值给对应的寄存器*/

144      str     r3, [r1], #4

145      cmp     r2, r0

146      bne     0b

147 

148      /* everything is fine now */

149      mov       pc, lr

150 

151      .ltorg

152  /* the literal pools origin */

153 

154  SMRDATA:            /*  下面是BWSCON 的13个寄存器的值  */

155  .word ((0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))

156 .word((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))

157 .word((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))

158 .word((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))

159 .word((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))

160 .word((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))

161 .word((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))

162 .word ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))

163 .word ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))

164 .word ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)

165 .word 0x32

166 .word 0x30

167 .word 0x30

这部分代码主要是设置memory的时序，位宽等参数。

 

lowlevel_init初始化了13个寄存器来实现RAM时钟的初始化。lowlevel_init函数对于U-Boot从NAND Flash或NOR Flash启动的情况都是有效的。

       U-Boot.lds链接脚本有如下代码：

       .text :

{

cpu/arm920t/start.o    (.text)

//因为smdk2410没有提供对nand flash的支持，下面这两行是将U-Boot移植到mini2440时要//添加的

board/samsung/mini2440/lowlevel_init.o (.text)

board/samsung/mini2440/nand_read.o (.text)

… …

}

 board/samsung/mini2440/lowlevel_init.o将被链接到cpu/arm920t/start.o后面，因此board/samsung/mini2440/lowlevel_init.o也在U-Boot的前4KB的代码中。

 U-Boot在NAND Flash启动时，lowlevel_init.o将自动被读取到CPU内部4KB的内部RAM中。因此第137~146行的代码将从CPU内部RAM中复制寄存器的值到相应的寄存器中。

 对于U-Boot在NOR Flash启动的情况，由于U-Boot连接时确定的地址是U-Boot在内存中的地址，而此时U-Boot还在NOR Flash中，因此还需要在NOR Flash中读取数据到RAM中。

 由于NOR Flash的开始地址是0，而U-Boot的加载到内存的起始地址是TEXT_BASE，SMRDATA标号在Flash的地址就是SMRDATA－TEXT_BASE。

 综上所述，lowlevel_init的作用就是将SMRDATA开始的13个值复制给开始地址[BWSCON]的13个寄存器，从而完成了存储控制器的设置。

【4】加载U-Boot第二阶段代码到RAM，此部分针对mini2440开发板

  原来针对smdk2410开发板的cpu/arm920t/start.S的代码是只支持从NOR Flash启动的，经过修改现在U-Boot在NOR Flash和NAND Flash上都能在mini2440开发板上启动了，实现的思路是这样的：

       bl    bBootFrmNORFlash /*  判断U-Boot是在NAND Flash还是NOR Flash启动  */

       cmp       r0, #0          /*  r0存放bBootFrmNORFlash函数返回值，若返回0表示NAND Flash启动，否则表示在NOR Flash启动  */

       beq nand_boot         /*  跳转到NAND Flash启动代码  */

   

/*  NOR Flash启动的代码  */

       b     stack_setup         /* 跳过NAND Flash启动的代码 */

   

nand_boot:

/*  NAND Flash启动的代码  */

   

stack_setup:       

       /* 其他代码 */

   

其中bBootFrmNORFlash函数作用是判断U-Boot是在NAND Flash启动还是NOR Flash启动，若在NOR Flash启动则返回1，否则返回0。根据ATPCS规则，函数返回值会被存放在r0寄存器中，因此调用bBootFrmNORFlash函数后根据r0的值就可以判断U-Boot在NAND Flash启动还是NOR Flash启动。bBootFrmNORFlash函数在board/samsung/mini2440/nand_read.c中定义如下：

int bBootFrmNORFlash(void)

{

    volatile unsigned int *pdw = (volatile unsigned int *)0;

    unsigned int dwVal;

    

    dwVal = *pdw;         /* 先记录下原来的数据 */

    *pdw = 0x12345678;

    if (*pdw != 0x12345678)       /* 写入失败，说明是在NOR Flash启动 */

    {

        return 1;     

    }

    else                                   /* 写入成功，说明是在NAND Flash启动 */

    {

        *pdw = dwVal;        /* 恢复原来的数据 */

        return 0;

    }

}

无论是从NOR Flash还是从NAND Flash启动，地址0处为U-Boot的第一条指令" b    start_code"。

对于从NAND Flash启动的情况，其开始4KB的代码会被自动复制到CPU内部4K内存中，因此可以通过直接赋值的方法来修改。

 对于从NOR Flash启动的情况，NOR Flash的开始地址即为0，必须通过一定的命令序列才能向NOR Flash中写数据，所以可以根据这点差别来分辨是从NAND Flash还是NOR Flash启动：向地址0写入一个数据，然后读出来，如果发现写入失败的就是NOR Flash，否则就是NAND Flash。

下面来分析NOR Flash启动部分代码：

208      adr  r0, _start              /* r0 <- current position of code   */

209      ldr   r1, _TEXT_BASE            /* test if we run from flash or RAM */

   

/* 判断U-Boot是否是下载到RAM中运行，若是，则不用 再复制到RAM中了，这种情况通常在调试U-Boot时才发生 */

210      cmp      r0, r1      /*_start等于_TEXT_BASE说明是下载到RAM中运行 */

211      beq stack_setup

212  /* 以下直到nand_boot标号前都是NOR Flash启动的代码 */

213      ldr   r2, _armboot_start

214      ldr   r3, _bss_start

215      sub  r2, r3, r2              /* r2 <- size of armboot            */

216      add r2, r0, r2              /* r2 <- source end address         */

217  /* 搬运U-Boot自身到RAM中*/

218  copy_loop:

219      ldmia     r0!, {r3-r10} /* 从基地址为[r0]的NOR Flash中读入8个字的数据 */

220      stmia      r1!, {r3-r10} /* 将r3至r10寄存器的数据复制给基地址为[r1]的内存 */

221      cmp       r0, r2                    /* until source end addreee [r2]    */

222      ble  copy_loop

223      b     stack_setup         /* 跳过NAND Flash启动的代码 */

       下面再来分析NAND Flash启动部分代码：

nand_boot:

    mov r1, #NAND_CTL_BASE 

    ldr r2, =( (7<<12)|(7<<8)|(7<<4)|(0<<0) )

    str r2, [r1, #oNFCONF]   /* 设置NFCONF寄存器 */

       

       /* 设置NFCONT，初始化ECC编/解码器，禁止NAND Flash片选 */

    ldr r2, =( (1<<4)|(0<<1)|(1<<0) )

    str r2, [r1, #oNFCONT] 

   

    ldr r2, =(0x6)           /* 设置NFSTAT */

str r2, [r1, #oNFSTAT]

   

/* 复位命令，第一次使用NAND Flash前复位 */

    mov r2, #0xff           

    strb r2, [r1, #oNFCMD]

    mov r3, #0              

   

    /* 为调用C函数nand_read_ll准备堆栈 */

    ldr sp, DW_STACK_START  

    mov fp, #0              

    /* 下面先设置r0至r2，然后调用nand_read_ll函数将U-Boot读入RAM */

    ldr r0, =TEXT_BASE      /* 目的地址：U-Boot在RAM的开始地址 */

    mov r1, #0x0               /* 源地址：U-Boot在NAND Flash中的开始地址 */

    mov r2, #0x30000          /* 复制的大小，必须比u-boot.bin文件大，并且必须是NAND Flash块大小的整数倍，这里设置为0x30000（192KB） */

    bl  nand_read_ll                 /* 跳转到nand_read_ll函数，开始复制U-Boot到RAM */

tst  r0, #0x0                     /* 检查返回值是否正确 */

beq stack_setup

bad_nand_read:

loop2: b loop2    //infinite loop

   

.align 2

DW_STACK_START: .word STACK_BASE+STACK_SIZE-4

       其中NAND_CTL_BASE，oNFCONF等在include/configs/mini2440.h中定义如下：

#define NAND_CTL_BASE  0x4E000000  // NAND Flash控制寄存器基址

   

#define STACK_BASE  0x33F00000     //base address of stack

#define STACK_SIZE  0x8000         //size of stack

   

#define oNFCONF  0x00      /* NFCONF相对于NAND_CTL_BASE偏移地址 */

#define oNFCONT  0x04      /* NFCONT相对于NAND_CTL_BASE偏移地址*/

#define oNFADDR  0x0c     /* NFADDR相对于NAND_CTL_BASE偏移地址*/

#define oNFDATA  0x10      /* NFDATA相对于NAND_CTL_BASE偏移地址*/

#define oNFCMD   0x08     /* NFCMD相对于NAND_CTL_BASE偏移地址*/

#define oNFSTAT  0x20        /* NFSTAT相对于NAND_CTL_BASE偏移地址*/

#define oNFECC   0x2c              /* NFECC相对于NAND_CTL_BASE偏移地址*/

NAND Flash各个控制寄存器的设置在S3C2440的数据手册有详细说明，这里就不介绍了。

代码中nand_read_ll函数的作用是在NAND Flash中搬运U-Boot到RAM，该函数在board/samsung/mini2440/nand_read.c中定义。

NAND Flash根据page大小可分为2种： 512B/page和2048B/page的。这两种NAND Flash的读操作是不同的。因此就需要U-Boot识别到NAND Flash的类型，然后采用相应的读操作，也就是说nand_read_ll函数要能自动适应两种NAND Flash。

参考S3C2440的数据手册可以知道：根据NFCONF寄存器的Bit3（AdvFlash (Read only)）和Bit2 （PageSize (Read only)）可以判断NAND Flash的类型。Bit2、Bit3与NAND Flash的block类型的关系如下表所示：

表 1.5 NFCONF的Bit3、Bit2与NAND Flash的关系

Bit2    Bit3	0	1
0	256 B/page	512 B/page
1	1024 B/page	2048 B/page

由于的NAND Flash只有512B/page和2048 B/page这两种，因此根据NFCONF寄存器的Bit3即可区分这两种NAND Flash了。

完整代码见board/samsung/mini2440/nand_read.c中的nand_read_ll函数，这里给出伪代码：

int nand_read_ll(unsigned char *buf, unsigned long start_addr, int size)

{

//根据NFCONF寄存器的Bit3来区分2种NAND Flash

       if( NFCONF & 0x8 )        /* Bit是1，表示是2KB/page的NAND Flash */

       {

             

              读取2K block 的NAND Flash

             

   

       }

       else                      /* Bit是0，表示是512B/page的NAND Flash */

       {

              /

              读取512B block 的NAND Flash

              /

   

       }

    return 0;

}

【5】设置堆栈

 /* Set up the stack */

stack_setup:

       ldr   r0, _TEXT_BASE            /* upper 128 KiB: relocated uboot   */

       sub  r0, r0, #CONFIG_SYS_MALLOC_LEN   /* malloc area              */

       sub  r0, r0, #CONFIG_SYS_GBL_DATA_SIZE /*  跳过全局数据区    */

#ifdef CONFIG_USE_IRQ

       sub  r0, r0, #(CONFIG_STACKSIZE_IRQ+CONFIG_STACKSIZE_FIQ)

#endif

       sub  sp, r0, #12           /* leave 3 words for abort-stack    */

 只要将sp指针指向一段没有被使用的内存就完成栈的设置了。根据上面的代码可以知道U-Boot内存使用情况了，如下图所示：

图1.2 U-Boot内存使用情况

   

【6】清除BSS段

clear_bss:

       ldr   r0, _bss_start              /* BSS段开始地址，在u-boot.lds中指定*/

       ldr   r1, _bss_end               /* BSS段结束地址，在u-boot.lds中指定*/

       mov       r2, #0x00000000

clbss_l:str     r2, [r0]          /* 将bss段清零*/

       add r0, r0, #4

       cmp      r0, r1

       ble  clbss_l

初始值为0，无初始值的全局变量，静态变量将自动被放在BSS段。应该将这些变量的初始值赋为0，否则这些变量的初始值将是一个随机的值，若有些程序直接使用这些没有初始化的变量将引起未知的后果。

【7】跳转到第二阶段代码入口

ldr   pc, _start_armboot

_start_armboot:   .word  start_armboot

跳转到第二阶段代码入口start_armboot处。

 

参考文章

http://www.cnblogs.com/heaad/archive/2010/07/17/1779829.html

http://blogold.chinaunix.net/u1/50916/showart_1161087.html