一个导出Excel非常快的类

最新推荐文章于 2020-03-18 10:36:12 发布
最新推荐文章于 2020-03-18 10:36:12 发布
阅读量428 收藏 1
点赞数
分类专栏： Delphi 文章标签： excel integer string destructor constructor function

一个导出Excel非常快的类

unit DBGridEhToExcel;

interface
uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, DB, ComCtrls, ExtCtrls, StdCtrls, Gauges, DBGridEh, ShellApi;

type
  TTitleCell = array of array of String;

  //分解DBGridEh的标题
  TDBGridEhTitle = class
  private
    FDBGridEh: TDBGridEh;  //对应DBGridEh
    FColumnCount: integer; //DBGridEh列数(指visible为True的列数)
    FRowCount: integer;    //DBGridEh多表头层数(没有多表头则层数为1)
    procedure SetDBGridEh(const Value: TDBGridEh);
    function GetTitleRow: integer;    //获取DBGridEh多表头层数
    function GetTitleColumn: integer; //获取DBGridEh列数
  public
    //分解DBGridEh标题，由TitleCell二维动态数组返回
    procedure GetTitleData(var TitleCell: TTitleCell);
  published
    property DBGridEh: TDBGridEh read FDBGridEh write SetDBGridEh;
    property ColumnCount: integer read FColumnCount;
    property RowCount: integer read FRowCount;
  end;

  TDBGridEhToExcel = class(TComponent)
  private
    FCol: integer;
    FRow: integer;
    FProgressForm: TForm;                                  {进度窗体}
    FGauge: TGauge;                                        {进度条}
    Stream: TStream;                                       {输出文件流}
    FBookMark: TBookmark;                                 
    FShowProgress: Boolean;                                {是否显示进度窗体}
    FDBGridEh: TDBGridEh;
    FBeginDate: TCaption;                                  {开始日期}
    FTitleName: TCaption;                                  {Excel文件标题}
    FEndDate: TCaption;                                    {结束日期}
    FUserName: TCaption;                                   {制表人}
    FFileName: String;                                     {保存文件名}
    procedure SetShowProgress(const Value: Boolean);
    procedure SetDBGridEh(const Value: TDBGridEh);
    procedure SetBeginDate(const Value: TCaption);
    procedure SetEndDate(const Value: TCaption);
    procedure SetTitleName(const Value: TCaption);
    procedure SetUserName(const Value: TCaption);
    procedure SetFileName(const Value: String);   

    procedure IncColRow;
    procedure WriteBlankCell;                              {写空单元格}
    {写数字单元格}
    procedure WriteFloatCell(const AValue: Double; const IncStatus: Boolean=True);
    {写整型单元格}
    procedure WriteIntegerCell(const AValue: Integer; const IncStatus: Boolean=True);
    {写字符单元格}
    procedure WriteStringCell(const AValue: string; const IncStatus: Boolean=True);
    procedure WritePrefix;
    procedure WriteSuffix;
    procedure WriteHeader;                                 {输出Excel标题}
    procedure WriteTitle;                                  {输出Excel列标题}
    procedure WriteDataCell;                               {输出数据集内容}
    procedure WriteFooter;                                 {输出DBGridEh表脚}
    procedure SaveStream(aStream: TStream);
    procedure CreateProcessForm(AOwner: TComponent);       {生成进度窗体}
    {根据表格修改数据集字段顺序及字段中文标题}
    procedure SetDataSetCrossIndexDBGridEh;
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
    procedure ExportToExcel; {输出Excel文件}
  published
    property DBGridEh: TDBGridEh read FDBGridEh write SetDBGridEh;
    property ShowProgress: Boolean read FShowProgress write SetShowProgress;
    property TitleName: TCaption read FTitleName write SetTitleName;
    property BeginDate: TCaption read FBeginDate write SetBeginDate;
    property EndDate: TCaption read FEndDate write SetEndDate;
    property UserName: TCaption read FUserName write SetUserName;
    property FileName: String read FFileName write SetFileName;
  end;

var
  CXlsBof: array[0..5] of Word = ($809, 8, 0, $10, 0, 0);
  CXlsEof: array[0..1] of Word = ($0A, 00);
  CXlsLabel: array[0..5] of Word = ($204, 0, 0, 0, 0, 0);
  CXlsNumber: array[0..4] of Word = ($203, 14, 0, 0, 0);
  CXlsRk: array[0..4] of Word = ($27E, 10, 0, 0, 0);
  CXlsBlank: array[0..4] of Word = ($201, 6, 0, 0, $17);

implementation
{ TDBGridEhTitle }


function TDBGridEhTitle.GetTitleColumn: integer;
var
  i, ColumnCount: integer;
begin
  ColumnCount := 0;
  for i := 0 to DBGridEh.Columns.Count - 1 do
  begin
    if DBGridEh.Columns[i].Visible then
      Inc(ColumnCount);
  end;

  Result := ColumnCount;
end;

procedure TDBGridEhTitle.GetTitleData(var TitleCell: TTitleCell);
var
  i, Row, Col: integer;
  Caption: String;
begin
  FColumnCount := GetTitleColumn;
  FRowCount := GetTitleRow;
  SetLength(TitleCell,FColumnCount,FRowCount);
  Row := 0;
  for i := 0 to DBGridEh.Columns.Count - 1 do
  begin
    if DBGridEh.Columns[i].Visible then
    begin
      Col := 0;
      Caption := DBGridEh.Columns[i].Title.Caption;
      while POS('|', Caption) > 0 do
      begin
        TitleCell[Row,Col] := Copy(Caption, 1, Pos('|',Caption)-1);
        Caption := Copy(Caption,Pos('|', Caption)+1, Length(Caption));
        Inc(Col);
      end;
      TitleCell[Row, Col] := Caption;
      Inc(Row);
    end;
  end;
end;

function TDBGridEhTitle.GetTitleRow: integer;
var
  i, j: integer;
  MaxRow, Row: integer;
begin
  MaxRow := 1;
  for i := 0 to DBGridEh.Columns.Count - 1 do
  begin
    Row := 1;
    for j := 0 to Length(DBGridEh.Columns[i].Title.Caption) do
    begin
      if DBGridEh.Columns[i].Title.Caption[j] = '|' then
        Inc(Row);
    end;

    if MaxRow < Row then
      MaxRow :=  Row;
  end;

  Result := MaxRow;
end;

procedure TDBGridEhTitle.SetDBGridEh(const Value: TDBGridEh);
begin
  FDBGridEh := Value;
end;

{ TDBGridEhToExcel }

constructor TDBGridEhToExcel.Create(AOwner: TComponent);
begin
  inherited Create(AOwner);
  FShowProgress := True;
end;

procedure TDBGridEhToExcel.SetShowProgress(const Value: Boolean);
begin
  FShowProgress := Value;
end;

procedure TDBGridEhToExcel.SetDBGridEh(const Value: TDBGridEh);
begin
  FDBGridEh := Value;
end;

procedure TDBGridEhToExcel.SetBeginDate(const Value: TCaption);
begin
  FBeginDate := Value;
end;

procedure TDBGridEhToExcel.SetEndDate(const Value: TCaption);
begin
  FEndDate := Value;
end;

procedure TDBGridEhToExcel.SetTitleName(const Value: TCaption);
begin
  FTitleName := Value;
end;

procedure TDBGridEhToExcel.SetUserName(const Value: TCaption);
begin
  FUserName := Value;
end;

procedure TDBGridEhToExcel.SetFileName(const Value: String);
begin
  FFileName := Value;
end;

procedure TDBGridEhToExcel.IncColRow;
begin
  if FCol = DBGridEh.DataSource.DataSet.FieldCount - 1 then
  begin
    Inc(FRow);
    FCol := 0;
  end
  else
    Inc(FCol);
end;

procedure TDBGridEhToExcel.WriteBlankCell;
begin
  CXlsBlank[2] := FRow;
  CXlsBlank[3] := FCol;
  Stream.WriteBuffer(CXlsBlank, SizeOf(CXlsBlank));
  IncColRow;
end;

procedure TDBGridEhToExcel.WriteFloatCell(const AValue: Double; const IncStatus: Boolean=True);
begin
  CXlsNumber[2] := FRow;
  CXlsNumber[3] := FCol;
  Stream.WriteBuffer(CXlsNumber, SizeOf(CXlsNumber));
  Stream.WriteBuffer(AValue, 8);

  if IncStatus then
    IncColRow;
end;

procedure TDBGridEhToExcel.WriteIntegerCell(const AValue: Integer; const IncStatus: Boolean=True);
var
  V: Integer;
begin
  CXlsRk[2] := FRow;
  CXlsRk[3] := FCol;
  Stream.WriteBuffer(CXlsRk, SizeOf(CXlsRk));
  V := (AValue Shl 2) Or 2;
  Stream.WriteBuffer(V, 4);

  if IncStatus then
    IncColRow;
end;

procedure TDBGridEhToExcel.WriteStringCell(const AValue: string; const IncStatus: Boolean=True);
var
  L: integer;
begin
  L := Length(AValue);
  CXlsLabel[1] := 8 + L;
  CXlsLabel[2] := FRow;
  CXlsLabel[3] := FCol;
  CXlsLabel[5] := L;
  Stream.WriteBuffer(CXlsLabel, SizeOf(CXlsLabel));
  Stream.WriteBuffer(Pointer(AValue)^, L);

  if IncStatus then
    IncColRow;
end;

procedure TDBGridEhToExcel.WritePrefix;
begin
  Stream.WriteBuffer(CXlsBof, SizeOf(CXlsBof));
end;

procedure TDBGridEhToExcel.WriteSuffix;
begin
  Stream.WriteBuffer(CXlsEof, SizeOf(CXlsEof));
end;

procedure TDBGridEhToExcel.WriteHeader;
var
  OpName, OpDate: String;
begin
  //标题
  FCol := 3;
  WriteStringCell(TitleName,False);
  FCol := 0;

  Inc(FRow);

  if Trim(BeginDate) <> '' then
  begin
    //开始日期
    FCol := 0;
    WriteStringCell(BeginDate,False);
    FCol := 0
  end;

  if Trim(EndDate) <> '' then
  begin
    //结束日期
    FCol := 5;
    WriteStringCell(EndDate,False);
    FCol := 0;
  end;

  if (Trim(BeginDate) <> '') or (Trim(EndDate) <> '') then
    Inc(FRow);

  //制表人
  OpName := '制表人：' + UserName;
  FCol := 0;
  WriteStringCell(OpName,False);
  FCol := 0;

  //制表时间
  OpDate := '制表时间：' + DateTimeToStr(Now);
  FCol := 5;
  WriteStringCell(OpDate,False);
  FCol := 0;

  Inc(FRow); 
end;

procedure TDBGridEhToExcel.WriteTitle;
var
  i, j: integer;
  DBGridEhTitle: TDBGridEhTitle;
  TitleCell: TTitleCell;
begin
  DBGridEhTitle := TDBGridEhTitle.Create;
  try
    DBGridEhTitle.DBGridEh := FDBGridEh;
    DBGridEhTitle.GetTitleData(TitleCell);

    try
      for i := 0 to DBGridEhTitle.RowCount - 1 do
      begin
        for j := 0 to DBGridEhTitle.ColumnCount - 1 do
        begin
          FCol := j;
          WriteStringCell(TitleCell[j,i],False);
        end;
        Inc(FRow);
      end;
      FCol := 0;
    except

    end;
  finally
    DBGridEhTitle.Free;
  end;
end;


procedure TDBGridEhToExcel.WriteDataCell;
var
  i: integer;
begin
  DBGridEh.DataSource.DataSet.DisableControls;
  FBookMark := DBGridEh.DataSource.DataSet.GetBookmark;
  try
    DBGridEh.DataSource.DataSet.First;
    while not DBGridEh.DataSource.DataSet.Eof do
    begin
      for i := 0 to DBGridEh.DataSource.DataSet.FieldCount - 1 do
      begin
        if DBGridEh.DataSource.DataSet.Fields[i].IsNull or (not DBGridEh.DataSource.DataSet.Fields[i].Visible) then
          WriteBlankCell
        else
        begin
          case DBGridEh.DataSource.DataSet.Fields[i].DataType of
            ftSmallint, ftInteger, ftWord, ftAutoInc, ftBytes:
              WriteIntegerCell(DBGridEh.DataSource.DataSet.Fields[i].AsInteger);
            ftFloat, ftCurrency, ftBCD:
              WriteFloatCell(DBGridEh.DataSource.DataSet.Fields[i].AsFloat);
          else
            if DBGridEh.DataSource.DataSet.Fields[i] Is TBlobfield then  // 此类型的字段(图像等)暂无法读取显示
              WriteStringCell('')
            else
              WriteStringCell(DBGridEh.DataSource.DataSet.Fields[i].AsString);
          end;
        end;
      end;

      //显示进度条进度过程
      if ShowProgress then
      begin
        FGauge.Progress := DBGridEh.DataSource.DataSet.RecNo;
        FGauge.Refresh;
      end;

      DBGridEh.DataSource.DataSet.Next;
    end;

  finally
    if DBGridEh.DataSource.DataSet.BookmarkValid(FBookMark) then
    DBGridEh.DataSource.DataSet.GotoBookmark(FBookMark);

    DBGridEh.DataSource.DataSet.EnableControls;
  end;
end;

procedure TDBGridEhToExcel.WriteFooter;
var
  i, j: integer;
begin
  if DBGridEh.FooterRowCount = 0 then exit;

  FCol := 0;
  if DBGridEh.FooterRowCount = 1 then
  begin
    for i := 0 to DBGridEh.Columns.Count - 1 do
    begin
      if DBGridEh.Columns[i].Visible then
      begin
        WriteStringCell(DBGridEh.Columns[i].Footer.Value,False);
        Inc(FCol);
      end;
    end;
  end
  else if DBGridEh.FooterRowCount > 1 then
  begin
    for i := 0 to DBGridEh.Columns.Count - 1 do
    begin
      if DBGridEh.Columns[i].Visible then
      begin
        for j := 0 to DBGridEh.Columns[i].Footers.Count - 1 do
        begin
          WriteStringCell(DBGridEh.Columns[i].Footers[j].Value ,False);
          Inc(FRow);
        end;
        Inc(FCol);
        FRow := FRow - DBGridEh.Columns[i].Footers.Count;
      end;
    end;
  end;
  FCol := 0;
end;

procedure TDBGridEhToExcel.SaveStream(aStream: TStream);
begin
  FCol := 0;
  FRow := 0;
  Stream := aStream;

  //输出前缀
  WritePrefix;

  //输出表格标题
  WriteHeader;

  //输出列标题
  WriteTitle;

  //输出数据集内容
  WriteDataCell;

  //输出DBGridEh表脚
  WriteFooter;

  //输出后缀
  WriteSuffix;
end;

procedure TDBGridEhToExcel.ExportToExcel;
var
  FileStream: TFileStream;
  Msg: String;
begin
  //如果数据集为空或没有打开则退出
  if (DBGridEh.DataSource.DataSet.IsEmpty) or (not DBGridEh.DataSource.DataSet.Active) then
    exit;

  //如果保存的文件名为空则退出
  if Trim(FileName) = '' then
    exit;
   
  //根据表格修改数据集字段顺序及字段中文标题
  SetDataSetCrossIndexDBGridEh;

  Screen.Cursor := crHourGlass;
  try
    try
      if FileExists(FileName) then
      begin
        Msg := '已存在文件（' + FileName + '），是否覆盖？';
        if Application.MessageBox(PChar(Msg),'提示',MB_YESNO+MB_ICONQUESTION+MB_DEFBUTTON2) = IDYES then
        begin
          //删除文件
          DeleteFile(FileName)
        end
        else
          exit;
      end;

      //显示进度窗体
      if ShowProgress then
        CreateProcessForm(nil);
       
      FileStream := TFileStream.Create(FileName, fmCreate);
      try
        //输出文件
        SaveStream(FileStream);
      finally
        FileStream.Free;
      end;
     
      //打开Excel文件
      ShellExecute(0, 'Open', PChar(FileName), nil, nil, SW_SHOW);
    except

    end;
  finally
    if ShowProgress then
      FreeAndNil(FProgressForm);
    Screen.Cursor := crDefault;
  end;
end;

destructor TDBGridEhToExcel.Destroy;
begin
  inherited Destroy;
end;

procedure TDBGridEhToExcel.CreateProcessForm(AOwner: TComponent);
var
  Panel: TPanel;
  Prompt: TLabel;                                           {提示的标签}
begin
  if Assigned(FProgressForm) then
    exit;

  FProgressForm := TForm.Create(AOwner);
  with FProgressForm do
  begin
    try
      Font.Name := '宋体';                                  {设置字体}
      Font.Size := 9;
      BorderStyle := bsNone;
      Width := 300;
      Height := 100;
      BorderWidth := 1;
      Color := clBlack;
      Position := poScreenCenter;

      Panel := TPanel.Create(FProgressForm);
      with Panel do
      begin
        Parent := FProgressForm;
        Align := alClient;
        BevelInner := bvNone;
        BevelOuter := bvRaised;
        Caption := '';
      end;

      Prompt := TLabel.Create(Panel);
      with Prompt do
      begin
        Parent := Panel;
        AutoSize := True;
        Left := 25;
        Top := 25;
        Caption := '正在导出数据，请稍候......';
        Font.Style := [fsBold];
      end;

      FGauge := TGauge.Create(Panel);
      with FGauge do
      begin
        Parent := Panel;
        ForeColor := clBlue;
        Left := 20;
        Top := 50;
        Height := 13;
        Width := 260;
        MinValue := 0;
        MaxValue := DBGridEh.DataSource.DataSet.RecordCount;
      end;
    except

    end;
  end;

  FProgressForm.Show;
  FProgressForm.Update;
end;

procedure TDBGridEhToExcel.SetDataSetCrossIndexDBGridEh;
var
  i: integer;
begin
  for i := 0 to DBGridEh.Columns.Count - 1 do
  begin
    DBGridEh.DataSource.DataSet.FieldByName(DBGridEh.Columns.Items[i].FieldName).Index := i;
    DBGridEh.DataSource.DataSet.FieldByName(DBGridEh.Columns.Items[i].FieldName).DisplayLabel
      := DBGridEh.Columns.Items[i].Title.Caption;
    DBGridEh.DataSource.DataSet.FieldByName(DBGridEh.Columns.Items[i].FieldName).Visible :=
      DBGridEh.Columns.Items[i].Visible;
  end;

  for i := 0 to DBGridEh.DataSource.DataSet.FieldCount - 1 do
  begin
    if POS('*****',DBGridEh.DataSource.DataSet.Fields[i].DisplayLabel) > 0 then
      DBGridEh.DataSource.DataSet.Fields[i].Visible := False;
  end; 
end;

end.


/*****************************************************************/

调用的例子

var
  DBGridEhToExcel: TDBGridEhToExcel;
begin
  DBGridEhToExcel := TDBGridEhToExcel.Create(nil);
  try
    DBGridEhToExcel.TitleName := '测试测试测试测试测试测试测试';
    DBGridEhToExcel.BeginDate := '开始日期：2005-07-01';
    DBGridEhToExcel.EndDate := '结束日期：2005-07-18';
    DBGridEhToExcel.UserName := '系统管理员';
    DBGridEhToExcel.DBGridEh := DBGridEh1;
    DBGridEhToExcel.ShowProgress := True;
    DBGridEhToExcel.FileName := 'c:/123.xls';
    DBGridEhToExcel.ExportToExcel;
  finally
    DBGridEhToExcel.Free;
  end;


xxz1314
关注
专栏目录
比较快速的将DBGridEh中的数据导出到Excel中
01-07
特点：一、不需安装Excel即可导出。二、有进度条。三、最多可以导出多少条，我没试，我试了5万条没有问题，时间也就是只需1-5分钟（我电脑较慢）。四、需安装ehlib组件。使用方法(注：别忘了uses DBGridToExcel;)：procedure TForm1.btn2Click(Sender: TObject);var DBGridEhToExcel: TDBGridEhToExcel; ExcelFileName: string;begin DBGridEhToExcel := TDBGridEhToExcel.Create(nil); try DBGridEhToExcel.TitleName := '导出测试'; DBGridEhToExcel.BeginDate := '开始日期：2005-07-01'; DBGridEhToExcel.EndDate := '结束日期：2005-07-18'; DBGridEhToExcel.UserName := '系统管理员'; DBGridEhToExcel.DBGridEh := DBGridEh1; DBGridEhToExcel.ShowProgress := True; if ExcelFileName = '' then begin ExcelFileName := 'c:\1.xls'; with TSaveDialog.Create(nil) do begin Filter := 'Microsoft Excel xls文件|*.xls'; DefaultExt := 'xls'; if not Execute then Exit else ExcelFileName := FileName; end; end; DBGridToExcel.FileName := ExcelFileName; DBGridEhToExcel.ExportToExcel; finally DBGridEhToExcel.Free; end;end;
在delphi中，从dbgrid导出数据保存成excel文件
继网开来的专栏
07-19 6490
实验了，很好用function TForm1.ExportDBGrid(DBGrid: TDBGrid; SheetName: string): boolean;//直接保存，不显示EXCEL<br />var<br />c, r, i, j: integer;<br />app: Olevariant;<br />TempFileName, ResultFileName: string;<br />begin<br />try<br />    result := True;<br />      app
DBGrid 导出到 Excel
ruoleng的专栏
08-20 1064
if ( SaveDialog->Execute() /*SelectDirectory("请选择存储目录","",Dir)*/ ) { ExportToExcel( DBGrid,/*Dir*/ SaveDialog->FileName); } /***************************************************** 函数说明: 讲DBGrid的数据导出到Excel中 参
DBGrid数据导出到Excel表格
走向辉煌
10-25 4648
注意:要在头文件中加上 #include //DBGrid数据导出到Excel表格void __stdcall GridToExcel(TDBGrid *DBGridB,AnsiString titleB,AnsiString fileNameB)     { //要导出数据的DBGrid/导出到Excel中的标题/保存Excel的路径  //判断文件是否存在,并决定是否删除  if (FileE
Delphi DbGrid导出到Excel
12-12
Delphi DbGrid导出到Excel
java使用POI导出 Excel工具类
08-14
java使用POI导出 Excel+图片工具类 ，里面含有poi jar包，只调用接口即可直接保存Excel。使用的时候需先把数据封装，具体包装需根据实际导出数据进行处理。文件demo中只提供包装格式。
java导出excel源码下载-excel-utils:一个优雅的excel导出工具类
06-05
java导出excel 源码下载 前言 公司项目最近有一个需要：报表导出。整个系统下来，起码超过一百张报表需要导出。这个时候如何优雅的实现报表导出，释放生产力就显得很重要了。下面主要给大家分享一下该工具类的使用...
java poi导出excel含工具类以及示例
08-02
String outputFile = "D:\\excel\\excel.xlsx"; OutputStream outputStream = new FileOutputStream(outputFile); UtilExcel utilExcel = new UtilExcel(); String titles = "所属区域,所属车间,当前处理人,描述...
将DBGrid中的数据快速导出到Excel的控件
01-07
发布原因：在网上找了很久也没找到个好用的，不是慢，就是要依赖Excel(必须按装),又找呀找，才找到一个http://blog.csdn.net/xiangding/archive/2003/10/27/16918.aspx,但试了一下，不能用，不知是我用法不对还是本身有问题（由于没有给出使用示例），后来找到http://developer.51cto.com/art/200510/7494.htm这个不错，但他又让我装ehlid,不爽，所以对其做了修改，其它也就是去了个加页脚的地方，很爽，有进度条，导完后如果按安装了Excel则直接打开，如果没有的话就不管了，自已想办法打开吧！特点：一、不需安装Excel即可导出。二、有进度条。三、最多可以导出多少条，我没试，我试了5万条没有问题，时间也就是只需1-5分钟（我电脑较慢）。四、不需安装组件。使用方法(注：别忘了uses DBGridToExcel;)：procedure TForm1.btn1Click(Sender: TObject);var DBGridToExcel: TDBGridToExcel; ExcelFileName: string;begin DBGridToExcel := TDBGridToExcel.Create(nil); try DBGridToExcel.TitleName := '入网车辆统计报表'; DBGridToExcel.BeginDate := '开始日期：2005-07-01'; DBGridToExcel.EndDate := '结束日期：2005-07-18'; DBGridToExcel.UserName := '系统管理员'; DBGridToExcel.DBGrid := dbgrd1; DBGridToExcel.ShowProgress := True; if ExcelFileName = '' then begin ExcelFileName := 'c:\1.xls'; with TSaveDialog.Create(nil) do begin Filter := 'Microsoft Excel xls文件|*.xls'; DefaultExt := 'xls'; if not Execute then Exit else ExcelFileName := FileName; end; end; DBGridToExcel.FileName := ExcelFileName; DBGridToExcel.Open := False; DBGridToExcel.ExportToExcel; finally DBGridToExcel.Free; end;end;
怎样把DBGrid的内容导出到Excel
10-15
void __fastcall TPhoneForm::SelectButtonClick(TObject *Sender) { 　　AnsiString StrDate, ExName;//存放日期用于sheet 　　AnsiString Datatem,phone1="拨号";//临时存放数据库的字段值 　　int i,j; 　　//查询所需的数据 　　PhoneADOQuery->Close(); 　　PhoneADOQuery->Parameters->ParamByName("date1")->Value=PhoneMaskEdit1->Text; 　　PhoneADOQuery->Parameters->ParamByName("date2")->Value=PhoneMaskEdit2->Text; 　　PhoneADOQuery->Active=true; 　　//新建一个EXCEL 　　Ex = Variant::CreateObject("Excel.Application"); 　　Ex.OlePropertyGet("workbooks").OleFunction("Add", 6); 　　Wb = Ex.OlePropertyGet("ActiveWorkBook"); 　　Sh = Wb.OlePropertyGet("ActiveSheet"); 　　Ex.OlePropertySet("Visible", true); 　　//给sheet以日期重命名, 　　StrDate=DateToStr(Date()); 　　Sh.OlePropertySet("Name", StrDate.c_str()); 　　//给EXCEL输入数据 　　for (j=0;jFieldCount;j++) 　 { 　 　　 Datatem=PhoneADOQuery->Fields->Fields[j]->FieldName; 　 　　 Sh.OlePropertyGet("Cells", 1, j+1).OlePropertySet("Value", Datatem.c_str()); 　 } 　　PhoneADOQuery->First(); 　　for (i=0; iRecordCount; i++) 　　{ 　 for (j=0;jFieldCount;j++) 　 { 　 　　 Datatem=PhoneADOQuery->Fields->Fields[j]->AsString; 　 　　 Sh.OlePropertyGet("Cells", i+2, j+1).OlePropertySet("Value", Datatem.c_str()); 　 　　 if (phone1==PhoneADOQuery->Fields->Fields[j]->FieldName) 　 　 {Sh.OlePropertyGet("Cells", i+2, j+1).OlePropertySet("NumberFormatLocal", "0_ ");//设置单元格格式为数值格式 } 　 } 　 PhoneADOQuery->Next(); 　　} 　　//保存EXCEL并退出 　　ExName=GetCurrentDir()+"\\"+DateToStr(Date())+".xls"; 　　Wb.OleFunction("SaveAs", ExName.c_str()); 　　Wb.OleFunction("Close"); 　　Ex.OleFunction ("Quit"); 　　Ex = Unassigned; }
Delphi中导出到Excel的程序例子： DBGridToExcel
10-03
Delphi中导出到Excel的程序例子： DBGridToExcel， 速度很快，试过 2 万条的数据导出， 没试过更多的数据导出，速度应该也会很快， 学习它绝对有用 ！！！
从DBGrid导出到Excel表格 4种方法
09-04
从DBGrid导出到Excel表格 4种方法
delphi dbgrid导出excel单元文件绝对好用
03-25
delphi dbgrid导出excel单元文件绝对好用 调用方式 var GridtoExcel: TDBGridEhToExcel; begin GridtoExcel := TDBGridEhToExcel.Create(nil); try GridtoExcel.DBGridEh := DBGridEh1; GridtoExcel.FileName := FormatDateTime('yyyy-mm-dd',DateTimePicker1.DateTime)+ '--------'+FormatDateTime('yyyy-mm-dd',DateTimePicker2.DateTime) +'退款订单导出'; GridtoExcel.ShowProgress := True; GridtoExcel.ExportToExcel; finally GridtoExcel.Free; end; end;
php导出excel类.zip
07-11
这个"php导出excel类.zip"文件提供了一个专为这个目的设计的PHP类库，可以帮助开发者轻松地生成和下载Excel文件。下面我们将详细探讨这个类库的关键知识点。 1. **编码设置**：在处理数据时，编码是非常重要的，它...
将DBGrid的数据导出到Excel文件保存
不得闲.闲忆居
05-21 5964
近来一段时间忙的慌，接了个帮人升级系统的小单子。其中涉及到将DbGrid的数据转到Excel文件并保存的功能，其实本身倒也不难。只是有些麻烦。想想这种功能，肯定有先人已经写好的现成东西直接拿过来用就应该OK了。于是Google一番，果然有很多类似的例子代码，俺在盒子上找到了和俺的需求相近的一个代码DbGrid2Excel这个代码。他那个写的确实不错，但是有些地方也还是不能尽如人意的哈，于是就在他的
正确的DBGrid导出到EXCEL
chaselife的博客
03-18 544
网上有很多DBGridToExcel代码都是数据表转EXCEL，连DBGrid的标题栏都没保存进去 这段代码是摘自CSDN大神(zpc198600)代码的修改版，增加了序号（字段不在数据表里）显示 procedure DBGridToExcel(dbGrid: TDBGrid); // 这才是正确的DBGrid转EXCEL方式，而不是数据表转Excel var excel...
将DBGrid里的数据导入EXCEL的
Victor's Blog
01-09 1546
将DBGrid里的数据导入EXCEL的，分享一下：void __fastcall Tsearch::DBGridToExcel(TDBGrid *AGrid, AnsiString Title)   //从DBGrid导出到Excel{  if (AGrid->DataSource->DataSet->IsEmpty())  {    ShowMessage("没有数据需要导出");  }  el
Java导出Excel工具类实例与操作技巧
Java实现Excel工具类是开发中常见的需求，本文提供了一个名为ExcelExportUtil的工具类实例，用于在Java环境中方便地导出数据到Excel文件。这个工具类的主要功能包括创建Excel工作簿、设置单元格格式、处理数据写入...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值