原文: http://www.cnblogs.com/zhangzt/archive/2010/07/29/1787825.html
MSDN文档:https://msdn.microsoft.com/zh-cn/library/ms177410.aspx
根据原文,稍有改动,代码规范了一下。
-- 一、行转列
-- 1、建立表格
if object_id('tb') is not null
drop table tb
go
create table tb(姓名 varchar(10),课程 varchar(10),分数 int)
SET NOCOUNT ON
insert into tb values('张三','语文',74)
insert into tb values('张三','数学',83)
insert into tb values('张三','物理',93)
insert into tb values('李四','语文',74)
insert into tb values('李四','数学',84)
insert into tb values('李四','物理',94)
go
SELECT * from tb
/*
姓名 课程 分数
张三 语文 74
张三 数学 83
张三 物理 93
李四 语文 74
李四 数学 84
李四 物理 94
*/
--2、使用SQL Server 2000静态SQL (必须知道有几门课程)
select 姓名,
max(case 课程 when'语文' then 分数 else 0 end)语文,
max(case 课程 when'数学' then 分数 else 0 end)数学,
max(case 课程 when'物理' then 分数 else 0 end)物理
from tb
group by 姓名
/*
姓名 语文 数学 物理
李四 74 84 94
张三 74 83 93
*/
--3、使用SQL Server 2000动态SQL (不必知道有几门课程)
--方法1
declare @sql1 varchar(500)
set @sql1='select 姓名'
select @sql1=@sql1+',max(case 课程 when '''+课程+''' then 分数 else 0 end)['+课程+']'
FROM (select distinct 课程 from tb)a --同from tb group by课程,默认按课程名排序
set @sql1=@sql1+' from tb group by 姓名'
--PRINT @sql1
exec(@sql1)
/*
姓名 数学 物理 语文
李四 84 94 74
张三 83 93 74
*/
--方法2 (NULL+string=NULL)
declare @sql2 varchar(8000)
select @sql2=isnull(@sql2+',','')+' max(case 课程 when '''+课程+''' then 分数 else 0 end) ['+课程+']'
FROM (select distinct 课程 from tb) as a
set @sql2='select 姓名,'+@sql2+' from tb group by 姓名'
EXEC (@sql2)
/*
姓名 数学 物理 语文
李四 84 94 74
张三 83 93 74
*/
--4、使用SQL Server 2005静态SQL
SELECT * from tb pivot(max(分数) for 课程 in (语文,数学,物理)) a
/*
姓名 语文 数学 物理
李四 74 84 94
张三 74 83 93
*/
--5、使用 SQL Server 2005 动态SQL
--使用stuff()
declare @sql51 varchar(8000)
set @sql51='' --初始化变量@sql51
select @sql51=@sql51+','+课程 from tb group by 课程--变量多值赋值
set @sql51 = stuff(@sql51,1,1,'')--去掉首个','
set @sql51='select * from tb pivot (max(分数) for 课程 in ('+@sql51+')) a'
EXEC (@sql51)
/*
姓名 数学 物理 语文
李四 84 94 74
张三 83 93 74
*/
--或使用isnull()
declare @sql52 varchar(8000)
--获得课程集合
select @sql52=isnull(@sql52+',','')+课程 from tb group by 课程
set @sql52='select * from tb pivot (max(分数) for 课程 in ('+@sql52+')) a'
EXEC (@sql52)
/*
姓名 数学 物理 语文
李四 84 94 74
张三 83 93 74
*/
-- 二、行转列结果加上总分、平均分
--1、使用SQL Server 2000静态SQL
--SQL SERVER 2000静态SQL
select 姓名,
max(case 课程 when'语文' then 分数 else 0 end) 语文,
max(case 课程 when'数学' then 分数 else 0 end) 数学,
max(case 课程 when'物理' then 分数 else 0 end) 物理,
sum(分数)总分,
cast(avg(分数*1.0) as decimal(18,2)) AS 平均分
from tb
group by 姓名
/*
姓名 语文 数学 物理 总分 平均分
李四 74 84 94 252 84.00
张三 74 83 93 250 83.33
*/
--2、使用SQL Server 2000动态SQL
--SQL SERVER 2000动态SQL
declare @sql varchar(500)
set @sql='select 姓名'
select @sql=@sql+',max(case 课程 when '''+课程+''' then 分数 else 0 end)['+课程+']'
from(select distinct 课程 from tb) a
set @sql=@sql+',sum(分数) as 总分,cast(avg(分数*1.0) as decimal(18,2)) AS 平均分 from tb group by 姓名'
exec(@sql)
/*
姓名 数学 物理 语文 总分 平均分
李四 84 94 74 252 84.00
张三 83 93 74 250 83.33
*/
--3、使用SQL Server 2005静态SQL
select m.*,n.总分,n.平均分
from
(SELECT * from tb pivot( max(分数) for 课程 in (语文,数学,物理) ) a) AS m
,(
select 姓名
,sum(分数) AS 总分
,cast(avg(分数*1.0) as decimal(18,2)) AS 平均分
from tb group by 姓名
)n
where m.姓名=n.姓名
/*
姓名 语文 数学 物理 总分 平均分
李四 74 84 94 252 84.00
张三 74 83 93 250 83.33
*/
--4、使用SQL Server 2005动态SQL
--使用stuff()
--
declare @sql_m2_41 varchar(8000)
set @sql_m2_41='' --初始化变量@sql_m2_41
select @sql_m2_41=@sql_m2_41+','+课程 from tb group by 课程--变量多值赋值
--同select @sql_m2_41 = @sql_m2_41 + ','+ 课程 from (select distinct 课程 from tb) AS a
set @sql_m2_41=stuff(@sql_m2_41,1,1,'')--去掉首个','
set @sql_m2_41='select m.*, n.总分, n.平均分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in ('+@sql_m2_41+')) b) m ,
(select 姓名,sum(分数) AS 总分, cast(avg(分数*1.0) as decimal(18,2)) AS 平均分 from tb group by 姓名) n
where m.姓名= n.姓名'
exec(@sql_m2_41)
/*
姓名 数学 物理 语文 总分 平均分
李四 84 94 74 252 84.00
张三 83 93 74 250 83.33
*/
--或使用isnull()
declare @sql_m2_42 varchar(8000)
select @sql_m2_42=isnull(@sql_m2_42+',','')+课程 from tb group by 课程
set @sql_m2_42='select m.*, n.总分,n.平均分 from
(select * from (select * from tb) a pivot (max(分数) for 课程 in (' + @sql_m2_42 + ')) b) m ,
(select 姓名,sum(分数) AS 总分, cast(avg(分数*1.0) as decimal(18,2)) AS 平均分 from tb group by 姓名) n
where m.姓名= n.姓名'
exec(@sql_m2_42)
/*
姓名 数学 物理 语文 总分 平均分
李四 84 94 74 252 84.00
张三 83 93 74 250 83.33
*/
-- 三、列转行
--1、建立表格
if object_id('tb') is not null
drop table tb
go
create table tb(姓名 varchar(10),语文 int,数学 int,物理 int)
insert into tb values('张三',74,83,93)
insert into tb values('李四',74,84,94)
go
SELECT * from tb
GO
/*
姓名 语文 数学 物理
张三 74 83 93
李四 74 84 94
*/
--2、使用SQL Server 2000静态SQL
--SQL SERVER 2000静态SQL。
SELECT * from
(
select 姓名,课程='语文',分数=语文 from tb
union all
select 姓名,课程='数学',分数=数学 from tb
union all
select 姓名,课程='物理',分数=物理 from tb
) t
order by 姓名,case 课程 when '语文' then 1 when '数学' then 2 when '物理' then 3 end
/*
姓名 课程 分数
李四 语文 74
李四 数学 84
李四 物理 94
张三 语文 74
张三 数学 83
张三 物理 93
*/
--2、使用SQL Server 2000动态SQL
--SQL SERVER 2000动态SQL。
--调用系统表动态生态。
declare @sql_cTor_21 varchar(8000)
select @sql_cTor_21=isnull(@sql_cTor_21+' union all ','')+' select 姓名, [课程]='
+quotename(Name,'''')+' , [分数] = '+quotename(Name)+' from tb'
from syscolumns
where Name!='姓名' and ID=object_id('tb')--表名tb,不包含列名为姓名的其他列
order by colid
exec(@sql_cTor_21+' order by 姓名')
GO
/*
姓名 课程 分数
李四 语文 74
李四 数学 84
李四 物理 94
张三 语文 74
张三 物理 93
张三 数学 83
*/
--3、使用SQL Server 2005静态SQL
--SQL SERVER 2005动态SQL
select 姓名,课程,分数 from tb unpivot (分数 for 课程 in([语文],[数学],[物理])) t
/*
姓名 课程 分数
张三 语文 74
张三 数学 83
张三 物理 93
李四 语文 74
李四 数学 84
李四 物理 94
*/
--4、使用SQL Server 2005动态SQL
--SQL SERVER 2005动态SQL
declare @sql_cTor_4 nvarchar(4000)
select @sql_cTor_4=isnull(@sql_cTor_4+',','')+quotename(Name)
from syscolumns
where ID=object_id('tb') and Name not in('姓名')
order by Colid
set @sql_cTor_4='select 姓名,[课程],[分数] from tb unpivot ([分数] for [课程] in('+@sql_cTor_4+')) b'
exec(@sql_cTor_4)
/*
姓名 课程 分数
张三 语文 74
张三 数学 83
张三 物理 93
李四 语文 74
李四 数学 84
李四 物理 94
*/