uboot-2012.04.01启动流程分析（一）

前言：这篇文章是目的是分析jz2410开发板使用的uboot-2012.04.01的启动过程，参考了很多文件，这里整理一下

注：
启动的第一到第四部分简单列出了代码，没有对代码为什么这么写进行分析，之后从第五部分内存划分开始，仔细的分析了代码。

一、启动流程图

这里的启动流程图很清晰的分析了uboot的启动过程，值得参考

二、启动步骤分析

首先在之前的编译与配置分析中，我们知道第一个执行的文件是arch/arm/cpu/arm920t/start.S这个文件，所以我们就从这个文件开始分析。

第一部分：异常向量表

.globl _start
_start:	b	start_code               //上电之后先从这里执行
	ldr	pc, _undefined_instruction
	ldr	pc, _software_interrupt
	ldr	pc, _prefetch_abort
	ldr	pc, _data_abort
	ldr	pc, _not_used
	ldr	pc, _irq
	ldr	pc, _fiq

_undefined_instruction:	.word undefined_instruction
_software_interrupt:	.word software_interrupt
_prefetch_abort:	.word prefetch_abort
_data_abort:		.word data_abort
_not_used:		.word not_used
_irq:			.word irq
_fiq:			.word fiq

第二部分：切换运行模式为管理模式

这部分代码是实现模式的切换，将模式切换为管理模式。

start_code:
	/*
	 * set the cpu to SVC32 mode
	 */
	mrs	r0, cpsr
	bic	r0, r0, #0x1f
	orr	r0, r0, #0xd3
	msr	cpsr, r0

第三部分：关闭看门狗、屏蔽中断、设置时钟

#ifdef CONFIG_S3C24X0
	/* turn off the watchdog */

#if defined(CONFIG_S3C2400)
#define pWTCON	0x15300000
#define INTMSK	0x14400008	/* Interrupt-Controller base addresses */
#define CLKDIVN	0x14800014	/* clock divisor register */
#else
#define pWTCON	0x53000000
#define INTMSK	0x4A000008	/* Interrupt-Controller base addresses */
#define INTSUBMSK	0x4A00001C
#define CLKDIVN	0x4C000014	/* clock divisor register */
#endif

	ldr	r0, =pWTCON   
	mov	r1, #0x0
	str	r1, [r0]
  
	/*
	 * mask all IRQs by setting all bits in the INTMR - default
	 */
	mov	r1, #0xffffffff
	ldr	r0, =INTMSK
	str	r1, [r0]
#if defined(CONFIG_S3C2410)
	ldr	r1, =0x3ff
	ldr	r0, =INTSUBMSK
	str	r1, [r0]
#endif
	/* FCLK:HCLK:PCLK = 1:2:4 */
	/* default FCLK is 120 MHz ! */
	ldr	r0, =CLKDIVN
	mov	r1, #3
	str	r1, [r0]
#endif	/* CONFIG_S3C24X0 */

第四部分：关闭cache，mmu及初始化内存控制器

#ifndef CONFIG_SKIP_LOWLEVEL_INIT
	bl	cpu_init_crit     //这个函数定义在该start.S文件中
#endif

#ifndef CONFIG_SKIP_LOWLEVEL_INIT
cpu_init_crit:
	/*
	 * flush v4 I/D caches
	 */
	mov	r0, #0
	mcr	p15, 0, r0, c7, c7, 0	/* flush v3/v4 cache */
	mcr	p15, 0, r0, c8, c7, 0	/* flush v4 TLB */

	/*
	 * disable MMU stuff and caches
	 */
	mrc	p15, 0, r0, c1, c0, 0
	bic	r0, r0, #0x00002300	@ clear bits 13, 9:8 (--V- --RS)
	bic	r0, r0, #0x00000087	@ clear bits 7, 2:0 (B--- -CAM)
	orr	r0, r0, #0x00000002	@ set bit 2 (A) Align
	orr	r0, r0, #0x00001000	@ set bit 12 (I) I-Cache
	mcr	p15, 0, r0, c1, c0, 0

	/*
	 * before relocating, we have to setup RAM timing
	 * because memory timing is board-dependend, you will
	 * find a lowlevel_init.S in your board directory.
	 */
	mov	ip, lr

	bl	lowlevel_init   //cpu相关的一些初始化

	mov	lr, ip
	mov	pc, lr
#endif /* CONFIG_SKIP_LOWLEVEL_INIT */

下面分析lowlevel_init函数，这个函数位于board/samsung/smdk2410/lowlevel_init.S文件中，是关于没存控制器的初始化。

TEXT_BASE:
	.word	CONFIG_SYS_TEXT_BASE

.globl lowlevel_init
lowlevel_init:
	/* memory control configuration */
	/* make r0 relative the current location so that it */
	/* reads SMRDATA out of FLASH rather than memory ! */
	ldr     r0, =SMRDATA
	ldr	r1, _TEXT_BASE
	sub	r0, r0, r1
	ldr	r1, =BWSCON	/* Bus Width Status Controller */
	add     r2, r0, #13*4
0:
	ldr     r3, [r0], #4
	str     r3, [r1], #4
	cmp     r2, r0
	bne     0b

	/* everything is fine now */
	mov	pc, lr

	.ltorg
/* the literal pools origin */

SMRDATA:
    .word (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
    .word ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))
    .word ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))
    .word ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))
    .word ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))
    .word ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))
    .word ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))
    .word ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))
    .word ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))
    .word ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
    .word 0x32
    .word 0x30
    .word 0x30

第五部分：初始化及内存划分

call_board_init_f:
	ldr	sp, =(CONFIG_SYS_INIT_SP_ADDR)
	bic	sp, sp, #7 /* 8-byte alignment for ABI compliance */
	ldr	r0,=0x00000000    
	bl	board_init_f    

这里设置栈指针sp=CONFIG_SYS_INIT_SP_ADDR，搜索CONFIG_SYS_INIT_SP_ADDR，在smdk2410.h文件中有定义：

#define PHYS_SDRAM_1		0x30000000 /* SDRAM Bank #1 */
#define CONFIG_SYS_SDRAM_BASE	PHYS_SDRAM_1
#define CONFIG_SYS_INIT_SP_ADDR	(CONFIG_SYS_SDRAM_BASE + 0x1000 - \
				GENERATED_GBL_DATA_SIZE)

所以经过分析smdk2410.h文件，这里sp=0x30000000+0x1000-GENERATED_GBL_DATA_SIZE;
搜索GENERATED_GBL_DATA_SIZE，发现在文件/include/generic-asm-offsets.h中定义：

#define GENERATED_GBL_DATA_SIZE (128) /* (sizeof(struct global_data) + 15) & ~15 */

所以sp=0x30000000+0x1000-128
sp=0x30000F80
设置好sp后，开始调用c函数board_init_f，参数为r0;
全局查找 board_init_f 函数，找到其在arch/arm/lib/board.c中定义，这个函数足足有200行，开始研究！

5.1gd指针

gd = (gd_t *) ((CONFIG_SYS_INIT_SP_ADDR) & ~0x07);

gd指针变量是一个寄存器变量，在arch/arm/include/asm/global_data.h文件中定义：

#define DECLARE_GLOBAL_DATA_PTR     register volatile gd_t *gd asm ("r8")  

这个宏定义将gd定义为一个指向gd_t类型的寄存器变量（优势：读写效率高），并将这个寄存器指定为CPU寄存器组中的r8寄存器。这个指针指向的地址就是之前汇编中sp指向的地址即0x30000F80。

5.2 init_sequence

在上面定义好了gd指向的地址之后，我们这里先进行init_sequence部分的分析，这个数组就定义在本文件中，下面代码中我将未用到的初始化函数做了注释。

init_fnc_t *init_sequence[] = {
#if defined(CONFIG_ARCH_CPU_INIT)
	arch_cpu_init,		/* basic arch cpu dependent setup */    //未用到
#endif
#if defined(CONFIG_BOARD_EARLY_INIT_F)
	board_early_init_f,
#endif
#ifdef CONFIG_OF_CONTROL
	fdtdec_check_fdt,                  //未用到
#endif
	timer_init,		/* initialize timer */
#ifdef CONFIG_FSL_ESDHC
	get_clocks,                       //未用到
#endif
	env_init,		/* initialize environment */
	init_baudrate,		/* initialze baudrate settings */
	serial_init,		/* serial communications setup */
	console_init_f,		/* stage 1 init of console */
	display_banner,		/* say that we are here */
#if defined(CONFIG_DISPLAY_CPUINFO)
	print_cpuinfo,		/* display cpu info (and speed) */
#endif
#if defined(CONFIG_DISPLAY_BOARDINFO)
	checkboard,		/* display board info */        //未用到
#endif
#if defined(CONFIG_HARD_I2C) || defined(CONFIG_SOFT_I2C)
	init_func_i2c,              //未用到
#endif
	dram_init,		/* configure available RAM banks */
	NULL,
};

接下来挨个查看这些函数的源码。

5.2.1 board_early_init_f

这个函数在board/samsung/smdk2410/smdk2410.c文件中定义，是一些与硬件平台相关的初始化，包括时钟初始化、GPIO初始化：

int board_early_init_f(void)
{
	struct s3c24x0_clock_power * const clk_power =
					s3c24x0_get_base_clock_power();
	struct s3c24x0_gpio * const gpio = s3c24x0_get_base_gpio();

	/* to reduce PLL lock time, adjust the LOCKTIME register */
	writel(0xFFFFFF, &clk_power->locktime);

	/* configure MPLL */
	writel((M_MDIV << 12) + (M_PDIV << 4) + M_SDIV,
	       &clk_power->mpllcon);

	/* some delay between MPLL and UPLL */
	pll_delay(4000);

	/* configure UPLL */
	writel((U_M_MDIV << 12) + (U_M_PDIV << 4) + U_M_SDIV,
	       &clk_power->upllcon);

	/* some delay between MPLL and UPLL */
	pll_delay(8000);

	/* set up the I/O ports */
	writel(0x007FFFFF, &gpio->gpacon);
	writel(0x00044555, &gpio->gpbcon);
	writel(0x000007FF, &gpio->gpbup);
	writel(0xAAAAAAAA, &gpio->gpccon);
	writel(0x0000FFFF, &gpio->gpcup);
	writel(0xAAAAAAAA, &gpio->gpdcon);
	writel(0x0000FFFF, &gpio->gpdup);
	writel(0xAAAAAAAA, &gpio->gpecon);
	writel(0x0000FFFF, &gpio->gpeup);
	writel(0x000055AA, &gpio->gpfcon);
	writel(0x000000FF, &gpio->gpfup);
	writel(0xFF95FFBA, &gpio->gpgcon);
	writel(0x0000FFFF, &gpio->gpgup);
	writel(0x002AFAAA, &gpio->gphcon);
	writel(0x000007FF, &gpio->gphup);

	return 0;
}

5.2.2. timer_init初始化

这个函数在arch/arm/cpu/arm920t/s3c24x0/timer.c中定义，用来初始化系统定时器：

int timer_init(void)
{
	struct s3c24x0_timers *timers = s3c24x0_get_base_timers();
	ulong tmr;

	/* use PWM Timer 4 because it has no output */
	/* prescaler for Timer 4 is 16 */
	writel(0x0f00, &timers->tcfg0);
	if (gd->tbu == 0) {
		/*
		 * for 10 ms clock period @ PCLK with 4 bit divider = 1/2
		 * (default) and prescaler = 16. Should be 10390
		 * @33.25MHz and 15625 @ 50 MHz
		 */
		gd->tbu = get_PCLK() / (2 * 16 * 100);
		gd->timer_rate_hz = get_PCLK() / (2 * 16);
	}
	/* load value for 10 ms timeout */
	writel(gd->tbu, &timers->tcntb4);
	/* auto load, manual update of timer 4 */
	tmr = (readl(&timers->tcon) & ~0x0700000) | 0x0600000;
	writel(tmr, &timers->tcon);
	/* auto load, start timer 4 */
	tmr = (tmr & ~0x0700000) | 0x0500000;
	writel(tmr, &timers->tcon);
	gd->lastinc = 0;
	gd->tbl = 0;

	return 0;
}

5.2.3. 设备初始化

这些函数用来初始化需要用到的设备，在通用设备驱动文件中定义：

env_init, /* initialize environment /
init_baudrate, / initialze baudrate settings /
serial_init, / serial communications setup /
console_init_f, / stage 1 init of console /
display_banner, / say that we are here */

5.2.4. print_cpuinfo

这个函数用来打印CPU信息，在arch/arm/cpu/arm920t/s3c24x0/cpu_info.c文件中：

int print_cpuinfo(void)
{
	int i;
	char buf[32];
/* the S3C2400 seems to be lacking a CHIP ID register */
#ifndef CONFIG_S3C2400
	ulong cpuid;
	struct s3c24x0_gpio * const gpio = s3c24x0_get_base_gpio();

	cpuid = readl(&gpio->gstatus1);
	printf("CPUID: %8lX\n", cpuid);
#endif
	for (i = 0; i < ARRAY_SIZE(freq_f); i++)
		printf("%cCLK: %8s MHz\n", freq_c[i], strmhz(buf, freq_f[i]()));

	return 0;
}

5.2.5. dram_init

这个用来初始化SDRAM，在board/samsung/smdk2410/smdk2410.c文件中：

int dram_init(void)
{
	/* dram_init must store complete ramsize in gd->ram_size */
	gd->ram_size = PHYS_SDRAM_1_SIZE;
	return 0;
}

PHYS_SDRAM_1_SIZE宏定义在上文中已经分析过了，为64MB

总结一下，初始化序列 init_sequence 主要是设备初始化工作：
① 硬件平台初始化：时钟系统初始化，GPIO初始化；
② 定时器初始化；
③ 外围设备初始化：串口、Flash等；
④ 打印CPU信息；
⑤ 初始化DRAM（SDRAM）；

5.3. 准备内存空间

在 board_init_f 函数中，接下来的内容都是在准备内存空间，详细的代码和SDRAM中uboot准备的内存分布图如下：

5.4. 重定位代码

在准备完内存空间之后，就进入了这个函数的最末端，重定位代码，代码如下：

	gd->relocaddr = addr;             //uboot代码存储起始位置
	gd->start_addr_sp = addr_sp;      //用户栈顶位置
	gd->reloc_off = addr - _TEXT_BASE;   //偏移大小等于uboot起始代码存储位置-_TEXT_BASE，这里_TEXT_BASE等于0
	debug("relocation Offset is: %08lx\n", gd->reloc_off);
	memcpy(id, (void *)gd, sizeof(gd_t));

	relocate_code(addr_sp, id, addr);

关于重定位代码的函数 relocate_code 是用汇编语言编写的，下一小节重点讲述，至此，board_init_f 函数研读完毕。

6. 重定位代码（relocate_code）

根据ARM子程序调用规则，C语言调用relocate_code函数时，传入的三个参数分别存放在R0、R1、R2寄存器中，所以在汇编代码被调用时，首先将这三个重要参数保存：

	.globl	relocate_code
relocate_code:
	mov	r4, r0	/* save addr_sp 保存栈顶指针的值到r4寄存器中 */ 
	mov	r5, r1	/* save addr of gd 保存gd指针的值到r5寄存器中*/ 
	mov	r6, r2	/* save addr of destination 保存addr的值到r6寄存器中 */ 

然后设置栈顶指针sp：

	/* Set up the stack						    */
stack_setup:
	mov	sp, r4

重定位：

	adr	r0, _start		//_start是程序起始地址
	cmp	r0, r6			//和要拷贝的目的地址比较一下
	beq	clear_bss		//如果相同，跳过拷贝，直接跳到clear_bss处
	mov	r1, r6			//把目的地址加载到r1中
	ldr	r3, _bss_start_ofs	//加载
	add	r2, r0, r3		/* r2 <- source end address	 copy的结束地址    */

copy_loop:
	ldmia	r0!, {r9-r10}		/* copy from source address [r0]    */
	stmia	r1!, {r9-r10}		/* copy to   target address [r1]    */
	cmp	r0, r2					/* until source end address [r2]    */
	blo	copy_loop

6.2. 修改变量和函数的链接地址

存放在Flash中的程序中，函数和变量的调用地址是基于0地址，现在拷贝到了SDRAM中，而SDRAM的基地址是0x3000_0000，所以需要对拷贝程序中所有的调用链接地址进行修改。

修改程序如下：

#ifndef CONFIG_SPL_BUILD
	/*
	 * fix .rel.dyn relocations
	 */
	ldr	r0, _TEXT_BASE		/* r0 <- Text base */
	sub	r9, r6, r0		/* r9 <- relocation offset */
	ldr	r10, _dynsym_start_ofs	/* r10 <- sym table ofs */
	add	r10, r10, r0		/* r10 <- sym table in FLASH */
	ldr	r2, _rel_dyn_start_ofs	/* r2 <- rel dyn start ofs */
	add	r2, r2, r0		/* r2 <- rel dyn start in FLASH */
	ldr	r3, _rel_dyn_end_ofs	/* r3 <- rel dyn end ofs */
	add	r3, r3, r0		/* r3 <- rel dyn end in FLASH */
fixloop:
	ldr	r0, [r2]		/* r0 <- location to fix up, IN FLASH! */
	add	r0, r0, r9		/* r0 <- location to fix up in RAM */
	ldr	r1, [r2, #4]
	and	r7, r1, #0xff
	cmp	r7, #23			/* relative fixup? */
	beq	fixrel
	cmp	r7, #2			/* absolute fixup? */
	beq	fixabs
	/* ignore unknown type of fixup */
	b	fixnext
fixabs:
	/* absolute fix: set location to (offset) symbol value */
	mov	r1, r1, LSR #4		/* r1 <- symbol index in .dynsym */
	add	r1, r10, r1		/* r1 <- address of symbol in table */
	ldr	r1, [r1, #4]		/* r1 <- symbol value */
	add	r1, r1, r9		/* r1 <- relocated sym addr */
	b	fixnext
fixrel:
	/* relative fix: increase location by offset */
	ldr	r1, [r0]
	add	r1, r1, r9
fixnext:
	str	r1, [r0]
	add	r2, r2, #8		/* each rel.dyn entry is 8 bytes */
	cmp	r2, r3
	blo	fixloop
#endif`

6.3. 清除BSS

clear_bss:
#ifndef CONFIG_SPL_BUILD
	ldr	r0, _bss_start_ofs
	ldr	r1, _bss_end_ofs
	mov	r4, r6			/* reloc addr */
	add	r0, r0, r4
	add	r1, r1, r4
	mov	r2, #0x00000000		/* clear			    */

clbss_l:str	r2, [r0]		/* clear loop...		    */
	add	r0, r0, #4
	cmp	r0, r1
	bne	clbss_l

	bl coloured_LED_init
	bl red_led_on
#endif

7. 调用C函数board_init_r—进入stage2阶段

首先计算调用地址，存放到lr寄存器中，然后设置向该函数传入的参数（gd_t地址和dest_addr地址），最后加载lr寄存器的值到pc中，成功调用board_init_r函数：

	ldr	r0, _board_init_r_ofs
	adr	r1, _start
	add	lr, r0, r1
	add	lr, lr, r9
	/* setup parameters for board_init_r */
	mov	r0, r5		/* gd_t */
	mov	r1, r6		/* dest_addr */
	/* jump to it ... */
	mov	pc, lr

_board_init_r_ofs:
	.word board_init_r - _start

这个函数在arch\arm\lib\board.c文件中，这个函数放在启动的第二阶段分析

参考：本文大部分内容参考该文档