JVM从跨平台到跨专业 Ⅳ -- 字节码技术

类文件结构

我们将一个简单的HelloWorld文件通过javac命令编译之后，得到以下字节码文件：

第一列是八进制的标号，后面几列是字节码内容。

字节码内容是十六进制的。一个字节可以表示两个十六进制位。

在弄清这些字节码的内容之前，我们先看看类文件的结构(根据JVM规范)：

u4 			   magic       //魔数
u2             minor_version;   //小版本号
u2             major_version;    //主版本号
u2             constant_pool_count;    
cp_info        constant_pool[constant_pool_count-1];  //常量池信息  
u2             access_flags;    //访问修饰
u2             this_class;    //类名信息
u2             super_class;   //父类的信息
u2             interfaces_count;    
u2             interfaces[interfaces_count];  //接口相关信息   
u2             fields_count;    
field_info     fields[fields_count];   //类中成员变量的信息
u2             methods_count;    
method_info    methods[methods_count];    //类中的方法信息
u2             attributes_count;    
attribute_info attributes[attributes_count]; //类的附加属性信息

_count定义内容的长度

第一列的u代表字节

魔数

u4 magic

对应字节码文件的0~3个字节

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

魔数表示的就是这个文件的类型，例如ca fe ba be就代表【class】文件

版本

u2 minor_version

u2 major_version

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

这里的主版本号为34(十六进制)，转化为十进制为52，代表JDK8

51就代表JDK7，53就代表JDK9，以此类推

常量池

紧接着主、次版本号之后的是常量池入口，常量池可以比喻为Class文件里的资源仓库，它是Class文件结构中与其他项目关联最多的数据，通常也是占用Class文件空间最大的数据项目之一，另外，它还是在Class文件中第一个出现的表类型数据项目。

8~9 字节，表示常量池长度，00 23 （35） 表示常量池有 #1~#34项，注意 #0 项不计入，也没有值

在Class文件格式规范制定之时，设计者将第0项常量空出来是有特殊考虑的，这样做的目的在于，如果后面某些指向常量池的索引值的数据在特定情况下需要表达“不引用任何一个常量池项目”的含义，可以把索引值设置为0来表示。Class文件结构中只有常量池的容量计数是从1开始，对于其他集合类型，包括接口索引集合、字段表集合、方法表集合等的容量计数都与一般习惯相同，是从0开始

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

第#1项 0a 表示一个 Method 信息，00 06 和 00 15（21） 表示它引用了常量池中 #6 和 #21 项来获得这个方法的【所属类】和【方法名】

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09

怎么知道0a 表示一个 Method 信息的呢？
我们只需要将0a 换成十进制也就是10，然后查表，发现是methodref，是一个方法引用的信息。
我们还要知道每一项的前一个字节(也就是u1型标志位)，首先表示当前项代表什么，查表之后再根据该项的类型后面的具体属性占据几个字节，值是多少。也就是说00 06和00 15代表【所属类】和【方法名】并不是空穴来风。
我们就拿这个methodref来说：

以后的分析都可以以此类推

第#2项 09 表示一个 Field 信息，00 16（22）和 00 17（23） 表示它引用了常量池中 #22 和 # 23 项来获得这个成员变量的【所属类】和【成员变量名】

0000000 ca fe ba be 00 00 00 34 00 23 0a 00 06 00 15 09
0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

第#3项 08 表示一个字符串常量名称，00 18（24）表示它引用了常量池中 #24 项

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

第#4项 0a 表示一个 Method 信息，00 19（25） 和 00 1a（26） 表示它引用了常量池中 #25 和 #26项来获得这个方法的【所属类】和【方法名】

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

第#5项 07 表示一个 Class 信息，00 1b（27） 表示它引用了常量池中 #27 项

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07

第#6项 07 表示一个 Class 信息，00 1c（28） 表示它引用了常量池中 #28 项

0000020 00 16 00 17 08 00 18 0a 00 19 00 1a 07 00 1b 07
0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29

第#7项 01 表示一个 utf8 串，00 06 表示长度，3c 69 6e 69 74 3e 是【 <init> 】

<init>表示构造方法

0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29

第#8项 01 表示一个 utf8 串，00 03 表示长度，28 29 56 是【()V】其实就是表示无参、无返回值

0000040 00 1c 01 00 06 3c 69 6e 69 74 3e 01 00 03 28 29
0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e

第#9项 01 表示一个 utf8 串，00 04 表示长度，43 6f 64 65 是【Code】

0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e

第#10项 01 表示一个 utf8 串，00 0f（15） 表示长度，4c 69 6e 65 4e 75 6d 62 65 72 54 61 62 6c 65是【LineNumberTable】

0000060 56 01 00 04 43 6f 64 65 01 00 0f 4c 69 6e 65 4e
0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 12 4c 6f 63

第#11项 01 表示一个 utf8 串，00 12（18） 表示长度，4c 6f 63 61 6c 56 61 72 69 61 62 6c 65 54 6162 6c 65是【LocalVariableTable】

0000100 75 6d 62 65 72 54 61 62 6c 65 01 00 12 4c 6f 63
0000120 61 6c 56 61 72 69 61 62 6c 65 54 61 62 6c 65 01

第#12项 01 表示一个 utf8 串，00 04 表示长度，74 68 69 73 是【this】

0000120 61 6c 56 61 72 69 61 62 6c 65 54 61 62 6c 65 01
0000140 00 04 74 68 69 73 01 00 1d 4c 63 6e 2f 69 74 63

第#13项 01 表示一个 utf8 串，00 1d（29） 表示长度，是【Lcn/itcast/jvm/t5/HelloWorld;】

0000140 00 04 74 68 69 73 01 00 1d 4c 63 6e 2f 69 74 63
0000160 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c 6f
0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16

第#14项 01 表示一个 utf8 串，00 04 表示长度，74 68 69 73 是【main】

0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16

第#15项 01 表示一个 utf8 串，00 16（22） 表示长度，是【([Ljava/lang/String;)V】其实就是参数为字符串数组，无返回值

0000200 57 6f 72 6c 64 3b 01 00 04 6d 61 69 6e 01 00 16
0000220 28 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72
0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13

第#16项 01 表示一个 utf8 串，00 04 表示长度，是【args】

0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13

第#17项 01 表示一个 utf8 串，00 13（19） 表示长度，是【[Ljava/lang/String;】

0000240 69 6e 67 3b 29 56 01 00 04 61 72 67 73 01 00 13
0000260 5b 4c 6a 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69
0000300 6e 67 3b 01 00 10 4d 65 74 68 6f 64 50 61 72 61

第#18项 01 表示一个 utf8 串，00 10（16） 表示长度，是【MethodParameters】

0000300 6e 67 3b 01 00 10 4d 65 74 68 6f 64 50 61 72 61
0000320 6d 65 74 65 72 73 01 00 0a 53 6f 75 72 63 65 46

第#19项 01 表示一个 utf8 串，00 0a（10） 表示长度，是【SourceFile】

0000320 6d 65 74 65 72 73 01 00 0a 53 6f 75 72 63 65 46
0000340 69 6c 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64

第#20项 01 表示一个 utf8 串，00 0f（15） 表示长度，是【HelloWorld.java】

0000340 69 6c 65 01 00 0f 48 65 6c 6c 6f 57 6f 72 6c 64
0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e

第#21项 0c 表示一个 【名+类型】，00 07 00 08 引用了常量池中 #7 #8 两项

0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e

第#22项 07 表示一个 Class 信息，00 1d（29） 引用了常量池中 #29 项

0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e

第#23项 0c 表示一个 【名+类型】，00 1e（30） 00 1f （31）引用了常量池中 #30 #31 两项

0000360 2e 6a 61 76 61 0c 00 07 00 08 07 00 1d 0c 00 1e
0000400 00 1f 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64

第#24项 01 表示一个 utf8 串，00 0f（15） 表示长度，是【hello world】

0000400 00 1f 01 00 0b 68 65 6c 6c 6f 20 77 6f 72 6c 64

第#25项 07 表示一个 Class 信息，00 20（32） 引用了常量池中 #32 项

0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74

第#26项 0c 表示一个 【名+类型】，00 21（33） 00 22（34）引用了常量池中 #33 #34 两项

0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74

第#27项 01 表示一个 utf8 串，00 1b（27） 表示长度，是【cn/itcast/jvm/t5/HelloWorld】

0000420 07 00 20 0c 00 21 00 22 01 00 1b 63 6e 2f 69 74
0000440 63 61 73 74 2f 6a 76 6d 2f 74 35 2f 48 65 6c 6c
0000460 6f 57 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61

第#28项 01 表示一个 utf8 串，00 10（16） 表示长度，是【java/lang/Object】

0000460 6f 57 6f 72 6c 64 01 00 10 6a 61 76 61 2f 6c 61
0000500 6e 67 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61

第#29项 01 表示一个 utf8 串，00 10（16） 表示长度，是【java/lang/System】

0000500 6e 67 2f 4f 62 6a 65 63 74 01 00 10 6a 61 76 61
0000520 2f 6c 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f

第#30项 01 表示一个 utf8 串，00 03 表示长度，是【out】

0000520 2f 6c 61 6e 67 2f 53 79 73 74 65 6d 01 00 03 6f
0000540 75 74 01 00 15 4c 6a 61 76 61 2f 69 6f 2f 50 72

第#31项 01 表示一个 utf8 串，00 15（21） 表示长度，是【Ljava/io/PrintStream;】

0000540 75 74 01 00 15 4c 6a 61 76 61 2f 69 6f 2f 50 72
0000560 69 6e 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76

第#32项 01 表示一个 utf8 串，00 13（19） 表示长度，是【java/io/PrintStream】

0000560 69 6e 74 53 74 72 65 61 6d 3b 01 00 13 6a 61 76
0000600 61 2f 69 6f 2f 50 72 69 6e 74 53 74 72 65 61 6d

第#33项 01 表示一个 utf8 串，00 07 表示长度，是【println】

0000620 01 00 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a

第#34项 01 表示一个 utf8 串，00 15（21） 表示长度，是【(Ljava/lang/String;)V】

0000620 01 00 07 70 72 69 6e 74 6c 6e 01 00 15 28 4c 6a
0000640 61 76 61 2f 6c 61 6e 67 2f 53 74 72 69 6e 67 3b
0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

其实翻译过后类似于下图：


可以通过javap命令反编译得到，我们在jvm的第一篇提到过。

访问标识与继承信息

21 表示该 class 是一个类，公共的

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

05 表示根据常量池中 #5 找到本类全限定名

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

06 表示根据常量池中 #6 找到父类全限定名

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

表示接口的数量，本类为 0

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

Field 信息

表示成员变量数量，本类为 0

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

Method 信息

表示方法数量，本类为 2

0000660 29 56 00 21 00 05 00 06 00 00 00 00 00 02 00 01

然后我们要明确一个方法由以下几个部分组成：

• 访问修饰符，
• 名称，
• 参数描述，
• 方法属性数量，
• 方法属性组成
  • 方法属性我们可以理解为方法体中具体要执行的代码

然后我们接着看字节码

• 红色代表访问修饰符（本类中是 public）
• 蓝色代表引用了常量池 #07 项作为方法名称
• 绿色代表引用了常量池 #08 项作为方法参数描述
• 黄色代表方法属性数量，本方法是 1
• 红色代表方法属性
  • 00 09 表示引用了常量池 #09 项，发现是【Code】属性
  • 00 00 00 2f 表示此属性的长度是 47
  • 00 01 表示【操作数栈】最大深度
  • 00 01 表示【局部变量表】最大槽（slot）数
  • 00 00 00 05 表示字节码长度，本例是 5
  • 2a b7 00 01 b1 是字节码指令
  • 00 00 00 02 表示方法细节属性数量，本例是 2
  • 00 0a 表示引用了常量池 #10 项，发现是【LineNumberTable】属性
    • 00 00 00 06 表示此属性的总长度，本例是 6
    • 00 01 表示【LineNumberTable】长度
    • 00 00 表示【字节码】行号 00 04 表示【java 源码】行号
  • 00 0b 表示引用了常量池 #11 项，发现是【LocalVariableTable】属性
    • 00 00 00 0c 表示此属性的总长度，本例是 12
    • 00 01 表示【LocalVariableTable】长度
    • 00 00 表示局部变量生命周期开始，相对于字节码的偏移量
    • 00 05 表示局部变量覆盖的范围长度
    • 00 0c 表示局部变量名称，本例引用了常量池 #12 项，是【this】
    • 00 0d 表示局部变量的类型，本例引用了常量池 #13 项，是【Lcn/itcast/jvm/t5/HelloWorld;】
    • 00 00 表示局部变量占有的槽位（slot）编号，本例是 0

• 红色代表访问修饰符（本类中是 public static）
• 蓝色代表引用了常量池 #14 项作为方法名称
• 绿色代表引用了常量池 #15 项作为方法参数描述
• 黄色代表方法属性数量，本方法是 2
• 红色代表方法属性（属性1）
  • 00 09 表示引用了常量池 #09 项，发现是【Code】属性
  • 00 00 00 37 表示此属性的长度是 55
  • 00 02 表示【操作数栈】最大深度
  • 00 01 表示【局部变量表】最大槽（slot）数
  • 00 00 00 05 表示字节码长度，本例是 9
  • b2 00 02 12 03 b6 00 04 b1 是字节码指令
  • 00 00 00 02 表示方法细节属性数量，本例是 2
  • 00 0a 表示引用了常量池 #10 项，发现是【LineNumberTable】属性
    • 00 00 00 0a 表示此属性的总长度，本例是 10
    • 00 02 表示【LineNumberTable】长度
    • 00 00 表示【字节码】行号 00 06 表示【java 源码】行号
    • 00 08 表示【字节码】行号 00 07 表示【java 源码】行号
  • 00 0b 表示引用了常量池 #11 项，发现是【LocalVariableTable】属性
    • 00 00 00 0c 表示此属性的总长度，本例是 12
    • 00 01 表示【LocalVariableTable】长度
    • 00 00 表示局部变量生命周期开始，相对于字节码的偏移量
    • 00 09 表示局部变量覆盖的范围长度
    • 00 10 表示局部变量名称，本例引用了常量池 #16 项，是【args】
    • 00 11 表示局部变量的类型，本例引用了常量池 #17 项，是【[Ljava/lang/String;】
    • 00 00 表示局部变量占有的槽位（slot）编号，本例是 0

红色代表方法属性（属性2）

• 00 12 表示引用了常量池 #18 项，发现是【MethodParameters】属性
  • 00 00 00 05 表示此属性的总长度，本例是 5
  • 01 参数数量
  • 00 10 表示引用了常量池 #16 项，是【args】
  • 00 00 访问修饰符

附加属性

• 00 01 表示附加属性数量
• 00 13 表示引用了常量池 #19 项，即【SourceFile】
• 00 00 00 02 表示此属性的长度
• 00 14 表示引用了常量池 #20 项，即【HelloWorld.java】

参考文献：https://docs.oracle.com/javase/specs/jvms/se8/html/jvms-4.html

字节码指令

初识

接着上一节，研究一下两组字节码指令，一个是public cn.itcast.jvm.t5.HelloWorld()构造方法的字节码指令；

2a b7 00 01 b1

• 2a => aload_0 加载 slot 0(也就是局部变量表中0号槽位) 的局部变量，即 this，作为下面的 invokespecial 构造方法调用的参数

• b7 => invokespecial 预备调用构造方法，哪个方法呢？

• 00 01 引用常量池中 #1 项，即【 Method java/lang/Object."<init>":()V 】

• b1 表示返回

另一个是 public static void main(java.lang.String[]);主方法的字节码指令:

b2 00 02 12 03 b6 00 04 b1

• b2 => getstatic 用来加载静态变量，哪个静态变量呢？
• 00 02 引用常量池中 #2 项，即【Field java/lang/System.out:Ljava/io/PrintStream;】
  • 在Field 中，这个：后面是这个变量的类型
• 12 => ldc 加载参数，哪个参数呢？
• 03 引用常量池中 #3 项，即 【String hello world】
• b6 => invokevirtual 预备调用成员方法，哪个方法呢？
• 00 04 引用常量池中 #4 项，即【Method java/io/PrintStream.println:(Ljava/lang/String;)V】
  • 在Method 中：后面跟的是参数列表和返回值
  • V代表void，也就是无返回值
• b1 表示返回

我们可以发现：

• 在java源代码中是准备好对象，再使用方法，然后加参数
• 在jvm的解释器中是先准备好对象和参数，再使用方法。
  • 也就是说在调用方法之前先把所有依赖准备好

参考文档：
https://docs.oracle.com/javase/specs/jvms/se8/html/jvms-6.html#jvms-6.5
字节对应的的字节码指令在里面可以一一查到：

javap工具

Oracle 提供了 javap 工具来反编译 class 文件：

javap -v -p Main.class

-v 显示附加信息

Classfile /Users/maweiqing/Documents/GitHub/TechSisterLearnJava/codes/TechSister/target/classes/com/itwanger/jvm/Main.class
  SHA-256 checksum 6688843e4f70ae8d83040dc7c8e2dd3694bf10ba7c518a6ea9b88b318a8967c6
  Compiled from "Main.java"
public class com.itwanger.jvm.Main
  minor version: 0
  major version: 55
  flags: (0x0021) ACC_PUBLIC, ACC_SUPER
  this_class: #3                          // com/itwanger/jvm/Main
  super_class: #4                         // java/lang/Object
  interfaces: 0, fields: 1, methods: 2, attributes: 1
Constant pool:
   #1 = Methodref          #4.#18         // java/lang/Object."<init>":()V
   #2 = Fieldref           #3.#19         // com/itwanger/jvm/Main.age:I
   #3 = Class              #20            // com/itwanger/jvm/Main
   #4 = Class              #21            // java/lang/Object
   #5 = Utf8               age
   #6 = Utf8               I
   #7 = Utf8               <init>
   #8 = Utf8               ()V
   #9 = Utf8               Code
  #10 = Utf8               LineNumberTable
  #11 = Utf8               LocalVariableTable
  #12 = Utf8               this
  #13 = Utf8               Lcom/itwanger/jvm/Main;
  #14 = Utf8               getAge
  #15 = Utf8               ()I
  #16 = Utf8               SourceFile
  #17 = Utf8               Main.java
  #18 = NameAndType        #7:#8          // "<init>":()V
  #19 = NameAndType        #5:#6          // age:I
  #20 = Utf8               com/itwanger/jvm/Main
  #21 = Utf8               java/lang/Object
{
  private int age;
    descriptor: I
    flags: (0x0002) ACC_PRIVATE

  public com.itwanger.jvm.Main();
    descriptor: ()V
    flags: (0x0001) ACC_PUBLIC
    Code:
      stack=2, locals=1, args_size=1
         0: aload_0
         1: invokespecial #1                  // Method java/lang/Object."<init>":()V
         4: aload_0
         5: bipush        18
         7: putfield      #2                  // Field age:I
        10: return
      LineNumberTable:
        line 6: 0
        line 7: 4
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0      11     0  this   Lcom/itwanger/jvm/Main;

  public int getAge();
    descriptor: ()I
    flags: (0x0001) ACC_PUBLIC
    Code:
      stack=1, locals=1, args_size=1
         0: aload_0
         1: getfield      #2                  // Field age:I
         4: ireturn
      LineNumberTable:
        line 9: 0
      LocalVariableTable:
        Start  Length  Slot  Name   Signature
            0       5     0  this   Lcom/itwanger/jvm/Main;
}
SourceFile: "Main.java"

我们可以看到它把我们前面枯燥的字节码文件表现的更加清晰易读，然后我们再看看方法表中的几个常见的选项：

• descriptor：表示方法的参数和返回值

• flags：方法的权限

• Code.stack：操作数栈的最大深度

• Code.locals：局部变量表所需的存储空间，单位是Slot(变量槽)。方法的参数变量和方法内的局部变量都会存储在局部变量表中。

  • 变量槽是虚拟机为局部变量分配内存所使用的最小单位。对于byte、char、float、int、short、boolean和returnAddress等长度不超过32位的数据类型，每个局部变量占用一个变量槽，而double和long这两种64位的数据类型则需要两个变量槽来存放。
  • 注意，并不是在方法中用了多少个局部变量，就把这些局部变量所占变量槽数量之和作为max locals的值，操作数栈和局部变量表直接决定一个该方法的栈帧所耗费的内存，不必要的操作数栈深度和变量槽数量会造成内存的浪费。Java虚拟机的做法是将局部变量表中的变量槽进行重用，当代码执行超出一个局部变量的作用域时，这个局部变量所占的变量槽可以被其他局部变量所使用，Javac编译器会根据变量的作用域来分配变量槽给各个变量使用，根据同时生存的最大局部变量数量和类型计算出max locals的大小。

• Code.args_size：方法参数列表的长度，也就是方法的参数个数

• LineNumberTable，该属性的作用是描述源码行号与字节码行号(字节码偏移量)之间的对应关系。

  • 它并不是运行时必需的属性，但默认会生成到Class文件之中，可以在Javac中使用-g: none或-g: lines选项来取消或要求生成这项信息。如果选择不生成LineNumberTable属性，对程序运行产生的最主要影响就是当抛出异常时，堆栈中将不会显示出错的行号，并且在调试程序的时候，也无法按照源码行来设置断点。

• LocalVariableTable，该属性的作用是描述帧栈中的局部变量表与源码中定义的变量之间的关系。

  • 它也不是运行时必需的属性，但默认会生成到Class文件之中，可以在Javac中使用-g: none或-g: vars选项来取消或要求生成这项信息。如果没有生成这项属性，最大的影响就是当其他人引用这个方法时，所有的参数名称都将会丢失，警如IDE将会使用诸如arg0、arg1之类的占位符代替原有的参数名，这对程序运行没有影响，但是会对代码编写带来较大不便，而且在调试期间无法根据参数名称从上下文中获得参数值。
  • Start：表示这个局部变量的生命周期开始的字节码偏移量
  • Length：表示这个局部变量作用范围覆盖的长度，与Start结合起来就是这个局部变量在字节码之中的作用域范围
  • Slot：插槽的索引
  • Name：局部变量的名字
  • Signature：局部变量的类型

为什么 stack 的值为 2，locals 的值为 1，args_size 的值为 1 呢？ 默认的构造方法不是没有参数和局部变量吗？
这是因为有一个隐藏的 this 变量，只要不是静态方法，都会有一个当前类的对象 this 悄悄的存在着。当执行该方法时，栈帧压入虚拟机栈，在此栈帧的局部变量表中，this就存在第一个变量槽中索引为0.

字段表；

  private int age;
    descriptor: I
    flags: (0x0002) ACC_PRIVATE

表明字段的访问权限修饰符为 private，类型为 int，名称为 age。

不清楚descriptor后面的类型可以查表；

图解方法执行流程

代码：

public class Demo3_1 {    
	public static void main(String[] args) {        
		int a = 10;        
		int b = Short.MAX_VALUE + 1;        
		int c = a + b;        
		System.out.println(c);   
    } 
}

1. 常量池载入运行时常量池
   

   常量池也属于方法区，只不过这里单独提出来了

2. 方法字节码载入方法区
   

   • （stack=2，locals=4） 对应操作数栈有2个空间（每个空间4个字节），局部变量表中有4个槽位

3. 执行引擎开始执行字节码

   • bipush 10
     

     • 将一个 byte 压入操作数栈（其长度会补齐 4 个字节），类似的指令还有
       • sipush 将一个 short 压入操作数栈（其长度会补齐 4 个字节）
       • ldc 将一个 int 压入操作数栈
       • ldc2_w 将一个 long 压入操作数栈（分两次压入,占两个空间的位置，因为 long 是 8 个字节）
       • 这里小的数字都是和字节码指令存在一起，超过 short 范围的数字存入了常量池

   • istore 1
     将操作数栈栈顶元素弹出，放入局部变量表的slot 1中
     对应代码中的：

     a = 10

     
     

   • ldc #3

     • 读取运行时常量池中#3，即32768(超过short最大值范围的数会被放到运行时常量池中)，将其加载到操作数栈中
     • 注意 Short.MAX_VALUE 是 32767，所以 32768 = Short.MAX_VALUE + 1 实际是在编译期间计算好的

     

   • istore 2
     将操作数栈中的元素弹出，放到局部变量表的2号位置
     
     

   • iload1 iload2
     将局部变量表中1号位置和2号位置的元素放入操作数栈中

     • 因为只能在操作数栈中执行运算操作

     

   • iadd
     将操作数栈中的两个元素弹出栈并相加，结果在压入操作数栈中
     
     

   • istore 3
     将操作数栈中的元素弹出，放入局部变量表的3号位置
     
     

   • getstatic #4
     在运行时常量池中找到#4，发现是一个对象
     在堆内存中找到该对象，并将其引用放入操作数栈中

     
     

   • iload 3
     将局部变量表中3号位置的元素压入操作数栈中
     

   • invokevirtual 5

     • 找到常量池 #5 项，定位到方法区 java/io/PrintStream.println:(I)V 方法
       生成新的栈帧（分配 locals、stack等）
       传递参数，执行新栈帧中的字节码
       
     • 执行完毕，弹出栈帧
       清除 main 操作数栈内容
       

   • return
     完成 main 方法调用，弹出 main 栈帧，程序结束

通过字节码指令来分析分析 i++问题

代码：

/**
* 从字节码角度分析 a++ 相关题目
*/
public class Demo3_2 {
	public static void main(String[] args) {
		int a = 10;
		int b = a++ + ++a + a--;
		System.out.println(a);
		System.out.println(b);
	}
}

字节码如下：

public static void main(java.lang.String[]);
	descriptor: ([Ljava/lang/String;)V
	flags: (0x0009) ACC_PUBLIC, ACC_STATIC
	Code:
		stack=2, locals=3, args_size=1
			0: bipush 10
			2: istore_1
			3: iload_1
			4: iinc 1, 1
			7: iinc 1, 1
			10: iload_1
			11: iadd
			12: iload_1
			13: iinc 1, -1
			16: iadd
			17: istore_2
			18: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
			21: iload_1
			22: invokevirtual #3 // Method java/io/PrintStream.println:(I)V
			25: getstatic #2 // Field java/lang/System.out:Ljava/io/PrintStream;
			28: iload_2
			29: invokevirtual #3 // Method java/io/PrintStream.println:(I)V
			32: return
		LineNumberTable:
			line 8: 0
			line 9: 3
			line 10: 18
			line 11: 25
			line 12: 32
		LocalVariableTable:
		  Start Length Slot Name Signature
			0    33 	0 	args [Ljava/lang/String;
			3    30 	1 	a 	 I
			18   15 	2 	b 	 I

分析：

• 注意 iinc 指令是直接在局部变量 slot 上进行运算
• a++ 和 ++a 的区别是先执行 iload 还是 先执行 iinc

过程图解如下：

条件判断指令

注意：

• byte，short，char 都会按 int 比较，因为操作数栈都是 4 字节
• goto 用来进行跳转到指定行号的字节码

我们来看一个例子：

源码：

public class Demo3_3 {
	public static void main(String[] args) {
		int a = 0;
		if(a == 0) {
			a = 10;
		} else {
			a = 20;
		}
	}
}

字节码：

0: iconst_0
1: istore_1
2: iload_1
3: ifne 12
6: bipush 10
8: istore_1
9: goto 15
12: bipush 20
14: istore_1
15: return

long，float，double 的比较请参考官方文档：
https://docs.oracle.com/javase/specs/jvms/se7/html/jvms-6.html#jvms-6.5.lcmp

循环控制指令

其实循环控制还是前面介绍的那些指令，例如 while 循环：

public class Demo3_4 {
	public static void main(String[] args) {
		int a = 0;
		while (a < 10) {
			a++;
		}
	}
}

字节码是：

0: iconst_0
1: istore_1
2: iload_1
3: bipush 		10
5: if_icmpge 	14
8: iinc 		1,1
11: goto 		2
14: return

再比如 do while 循环：

public class Demo3_5 {
	public static void main(String[] args) {
		int a = 0;
		do {
			a++;
		} while (a < 10);
	}
}

字节码：

 0: iconst_0
 1: istore_1
 2: iinc 		1, 1
 5: iload_1
 6: bipush 		10
 8: if_icmplt 	2
11: return

最后再看看 for 循环：

public class Demo3_6 {
	public static void main(String[] args) {
		for (int i = 0; i < 10; i++) {
		}
	}
}

字节码是：

0: iconst_0
1: istore_1
2: iload_1
3: bipush 		10
5: if_icmpge 	14
8: iinc 		1, 1
11: goto 		2
14: return

比较 while 和 for 的字节码，会发现它们是一模一样的。

构造方法

cinit()V

public class Demo3 {
	static int i = 10;

	static {
		i = 20;
	}

	static {
		i = 30;
	}

	public static void main(String[] args) {
		System.out.println(i); //结果为30
	}
}

编译器会按从上至下的顺序，收集所有 static 静态代码块和静态成员赋值的代码，合并为一个特殊的方法 cinit()V ：

stack=1, locals=0, args_size=0
         0: bipush        10
         2: putstatic     #3                  // Field i:I
         5: bipush        20
         7: putstatic     #3                  // Field i:I
        10: bipush        30
        12: putstatic     #3                  // Field i:I
        15: return

cinit()V方法会在类加载的初始化阶段被调用，它是整个类的构造方法

init()V

public class Demo4 {
	private String a = "s1";

	{
		b = 20;
	}

	private int b = 10;

	{
		a = "s2";
	}

	public Demo4(String a, int b) {
		this.a = a;
		this.b = b;
	}

	public static void main(String[] args) {
		Demo4 d = new Demo4("s3", 30);
		System.out.println(d.a);
		System.out.println(d.b);
	}
}

编译器会按从上至下的顺序，收集所有 {} 代码块和成员变量赋值的代码，形成新的构造方法，但原始构造方法内的代码总是在后；

方法调用

看一下几种不同的方法调用对应的字节码指令：

所得字节码如下：

我们可以很容易看出来：

• 静态方法在调用时使用invokestatic指令
• 最终方法（final），私有方法（private），构造方法都是由 invokespecial 指令来调用，属于静态绑定(也就是编译的时候就已经可以确定，invokestatic也是一样)
• 普通成员方法是由 invokevirtual 调用，属于动态绑定(也就是说编译的时候是不能确定的，可能是子类也可能是父类的，只能在运行时确定)，即支持多态

然后还有一些细节：

• new 是创建【对象】，给对象分配堆内存，执行成功会将【对象引用】压入操作数栈

• dup 是复制操作数栈栈顶的内容，本例即为【对象引用】，为什么需要两份引用呢，一个是要配合 invokespecial 调用该对象的构造方法 "<init>":()V （会消耗掉栈顶一个引用），另一个要配合 astore_1 存到局部变量表中

• 成员方法与静态方法调用的另一个区别是，执行方法前是否需要【对象引用】

• 比较有意思的是 d.test4(); 是通过【对象引用】调用一个静态方法，可以看到在调用invokestatic 之前执行了 pop 指令，把【对象引用】从操作数栈弹掉了(所以说我们调用静态方法的时候是不需要使用对象引用来完成的，否则会产生两条不必要的虚拟机指令)

• 还有一个执行 invokespecial 的情况是通过 super 调用父类方法

多态原理

因为普通成员方法需要在运行时才能确定具体的内容，所以虚拟机需要调用invokevirtual指令

在执行invokevirtual指令时，经历了以下几个步骤：

• 先通过栈帧中对象的引用找到对象
• 分析对象头，找到对象实际的Class
• Class结构中有vtable
• 查询vtable找到方法的具体地址
• 执行方法的字节码

异常处理

try-catch

public class Demo1 {
	public static void main(String[] args) {
		int i = 0;
		try {
			i = 10;
		}catch (Exception e) {
			i = 20;
		}
	}
}

对应字节码指令

Code:
     stack=1, locals=3, args_size=1
        0: iconst_0
        1: istore_1
        2: bipush        10
        4: istore_1
        5: goto          12
        8: astore_2
        9: bipush        20
       11: istore_1
       12: return
     //多出来一个异常表
     Exception table:
        from    to  target type
            2     5     8   Class java/lang/Exception

• 可以看到多出来一个 Exception table 的结构，[from, to) 是前闭后开（也就是检测2~4行）的检测范围，一旦这个范围内的字节码执行出现异常，则通过 type 匹配异常类型，如果一致，进入 target 所指示行号
• 8行的字节码指令 astore_2 是将异常对象引用存入局部变量表的2号位置（为e）

多个single-catch

public class Demo1 {
	public static void main(String[] args) {
		int i = 0;
		try {
			i = 10;
		}catch (ArithmeticException e) {
			i = 20;
		}catch (Exception e) {
			i = 30;
		}
	}
}

对应的字节码：

Code:
     stack=1, locals=3, args_size=1
        0: iconst_0
        1: istore_1
        2: bipush        10
        4: istore_1
        5: goto          19
        8: astore_2
        9: bipush        20
       11: istore_1
       12: goto          19
       15: astore_2
       16: bipush        30
       18: istore_1
       19: return
     Exception table:
        from    to  target type
            2     5     8   Class java/lang/ArithmeticException
            2     5    15   Class java/lang/Exception

• 因为异常出现时，只能进入 Exception table 中一个分支，所以局部变量表 slot 2 位置被共用

finally

public class Demo2 {
	public static void main(String[] args) {
		int i = 0;
		try {
			i = 10;
		} catch (Exception e) {
			i = 20;
		} finally {
			i = 30;
		}
	}
}

对应字节码：

Code:
     stack=1, locals=4, args_size=1
        0: iconst_0
        1: istore_1
        //try块
        2: bipush        10
        4: istore_1
        //try块执行完后，会执行finally    
        5: bipush        30
        7: istore_1
        8: goto          27
       //catch块     
       11: astore_2 //异常信息放入局部变量表的2号槽位
       12: bipush        20
       14: istore_1
       //catch块执行完后，会执行finally        
       15: bipush        30
       17: istore_1
       18: goto          27
       //出现异常，但未被Exception捕获，会抛出其他异常，这时也需要执行finally块中的代码   
       21: astore_3
       22: bipush        30
       24: istore_1
       25: aload_3
       26: athrow  //抛出异常
       27: return
     Exception table:
        from    to  target type
            2     5    11   Class java/lang/Exception
            2     5    21   any
           11    15    21   any

可以看到 finally 中的代码被复制了 3 份，分别放入 try 流程，catch 流程以及 catch剩余的异常类型流程

注意：虽然从字节码指令看来，每个块中都有finally块，但是finally块中的代码只会被执行一次

finally中的return

public class Demo3 {
	public static void main(String[] args) {
		int i = Demo3.test();
        //结果为20
		System.out.println(i);
	}

	public static int test() {
		int i;
		try {
			i = 10;
			return i;
		} finally {
			i = 20;
			return i;
		}
	}
}

对应字节码：

Code:
     stack=1, locals=3, args_size=0
        0: bipush        10
        2: istore_0
        3: iload_0
        4: istore_1  //暂存返回值
        5: bipush        20
        7: istore_0
        8: iload_0
        9: ireturn	//ireturn会返回操作数栈顶的整型值20
       //如果出现异常，还是会执行finally块中的内容，没有抛出异常
       10: astore_2
       11: bipush        20
       13: istore_0
       14: iload_0
       15: ireturn	//这里没有athrow了，也就是如果在finally块中如果有返回操作的话，且try块中出现异常，会吞掉异常！
     Exception table:
        from    to  target type
            0     5    10   any

• 由于 finally 中的 ireturn 被插入了所有可能的流程，因此返回结果肯定以finally的为准
• 至于字节码中第 2 行，似乎没啥用，且留个伏笔，看下个例子
• 跟上例中的 finally 相比，发现没有 athrow 了，这告诉我们：如果在 finally 中出现了 return，会吞掉异常
• 所以不要在finally中进行返回操作

被吞掉的异常

public class Demo3 {
   public static void main(String[] args) {
      int i = Demo3.test();
      //最终结果为20
      System.out.println(i);
   }

   public static int test() {
      int i;
      try {
         i = 10;
         //这里应该会抛出异常
         i = i/0;
         return i;
      } finally {
         i = 20;
         return i;
      }
   }
}

会发现打印结果为20，并未抛出异常

finally不带return

public class Demo4 {
	public static void main(String[] args) {
		int i = Demo4.test();
		System.out.println(i);
	}

	public static int test() {
		int i = 10;
		try {
			return i;
		} finally {
			i = 20;
		}
	}
}

对应字节码；

Code:
     stack=1, locals=3, args_size=0
        0: bipush        10
        2: istore_0 //赋值给i 10
        3: iload_0	//加载到操作数栈顶
        4: istore_1 //加载到局部变量表的1号位置
        5: bipush        20
        7: istore_0 //赋值给i 20
        8: iload_1 //加载局部变量表1号位置的数10到操作数栈
        9: ireturn //返回操作数栈顶元素 10
       10: astore_2
       11: bipush        20
       13: istore_0
       14: aload_2 //加载异常
       15: athrow //抛出异常
     Exception table:
        from    to  target type
            3     5    10   any

Synchronized

public class Demo5 {
	public static void main(String[] args) {
		int i = 10;
		Lock lock = new Lock();
		synchronized (lock) {
			System.out.println(i);
		}
	}
}

class Lock{}

对应字节码：

Code:
     stack=2, locals=5, args_size=1
        0: bipush        10
        2: istore_1
        3: new           #2                  // class com/nyima/JVM/day06/Lock
        6: dup //复制一份，放到操作数栈顶，用于构造函数消耗
        7: invokespecial #3                  // Method com/nyima/JVM/day06/Lock."<init>":()V
       10: astore_2 //剩下的一份放到局部变量表的2号位置
       11: aload_2 //加载到操作数栈
       12: dup //复制一份，放到操作数栈，用于加锁时消耗
       13: astore_3 //将操作数栈顶元素弹出，暂存到局部变量表的三号槽位。这时操作数栈中有一份对象的引用
       14: monitorenter //加锁
       //锁住后代码块中的操作    
       15: getstatic     #4                  // Field java/lang/System.out:Ljava/io/PrintStream;
       18: iload_1
       19: invokevirtual #5                  // Method java/io/PrintStream.println:(I)V
       //加载局部变量表中三号槽位对象的引用，用于解锁    
       22: aload_3    
       23: monitorexit //解锁
       24: goto          34
       //异常操作    
       27: astore        4
       29: aload_3
       30: monitorexit //解锁
       31: aload         4
       33: athrow
       34: return
     //可以看出，无论何时出现异常，都会跳转到27行，将异常放入局部变量中，并进行解锁操作，然后加载异常并抛出异常。      
     Exception table:
        from    to  target type
           15    24    27   any
           27    31    27   any