Delphi中的线程类--之(2)

原创 2003年12月02日 22:00:00

Delphi中的线程类<?xml:namespace prefix = o ns = "urn:schemas-microsoft-com:office:office" />

 

猛禽[Mental Studio]

http://mental.mentsu.com

 

之二

首先就是构造函数:

constructor TThread.Create(CreateSuspended: Boolean);

begin

  inherited Create;

  AddThread;

  FSuspended := CreateSuspended;

  FCreateSuspended := CreateSuspended;

  FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), CREATE_SUSPENDED, FThreadID);

  if FHandle = 0 then

    raise EThread.CreateResFmt(@SThreadCreateError, [SysErrorMessage(GetLastError)]);

end;

虽然这个构造函数没有多少代码,但却可以算是最重要的一个成员,因为线程就是在这里被创建的。

在通过Inherited调用TObject.Create后,第一句就是调用一个过程:AddThread,其源码如下:

procedure AddThread;

begin

  InterlockedIncrement(ThreadCount);

end;

同样有一个对应的RemoveThread

procedure RemoveThread;

begin

  InterlockedDecrement(ThreadCount);

end;

它们的功能很简单,就是通过增减一个全局变量来统计进程中的线程数。只是这里用于增减变量的并不是常用的Inc/Dec过程,而是用了InterlockedIncrement/InterlockedDecrement这一对过程,它们实现的功能完全一样,都是对变量加一或减一。但它们有一个最大的区别,那就是InterlockedIncrement/InterlockedDecrement是线程安全的。即它们在多线程下能保证执行结果正确,而Inc/Dec不能。或者按操作系统理论中的术语来说,这是一对“原语”操作。

以加一为例来说明二者实现细节上的不同:

一般来说,对内存数据加一的操作分解以后有三个步骤:

1、  从内存中读出数据

2、  数据加一

3、  存入内存

现在假设在一个两个线程的应用中用Inc进行加一操作可能出现的一种情况:

1、  线程A从内存中读出数据(假设为3

2、  线程B从内存中读出数据(也是3

3、  线程A对数据加一(现在是4

4、  线程B对数据加一(现在也是4

5、  线程A将数据存入内存(现在内存中的数据是4

6、  线程B也将数据存入内存(现在内存中的数据还是4,但两个线程都对它加了一,应该是5才对,所以这里出现了错误的结果)

而用InterlockIncrement过程则没有这个问题,因为所谓“原语”是一种不可中断的操作,即操作系统能保证在一个“原语”执行完毕前不会进行线程切换。所以在上面那个例子中,只有当线程A执行完将数据存入内存后,线程B才可以开始从中取数并进行加一操作,这样就保证了即使是在多线程情况下,结果也一定会是正确的。

前面那个例子也说明一种“线程访问冲突”的情况,这也就是为什么线程之间需要“同步”(Synchronize),关于这个,在后面说到同步时还会再详细讨论。

说到同步,有一个题外话:加拿大滑铁卢大学的教授李明曾就Synchronize一词在“线程同步”中被译作“同步”提出过异议,个人认为他说的其实很有道理。在中文中“同步”的意思是“同时发生”,而“线程同步”目的就是避免这种“同时发生”的事情。而在英文中,Synchronize的意思有两个:一个是传统意义上的同步(To occur at the same time),另一个是“协调一致”(To operate in unison)。在“线程同步”中的Synchronize一词应该是指后面一种意思,即“保证多个线程在访问同一数据时,保持协调一致,避免出错”。不过像这样译得不准的词在IT业还有很多,既然已经是约定俗成了,本文也将继续沿用,只是在这里说明一下,因为软件开发是一项细致的工作,该弄清楚的,绝不能含糊。

 

扯远了,回到TThread的构造函数上,接下来最重要就是这句了:

FHandle := BeginThread(nil, 0, @ThreadProc, Pointer(Self), CREATE_SUSPENDED, FThreadID);

这里就用到了前面说到的Delphi RTL函数BeginThread,它有很多参数,关键的是第三、四两个参数。第三个参数就是前面说到的线程函数,即在线程中执行的代码部分。第四个参数则是传递给线程函数的参数,在这里就是创建的线程对象(即Self)。其它的参数中,第五个是用于设置线程在创建后即挂起,不立即执行(启动线程的工作是在AfterConstruction中根据CreateSuspended标志来决定的),第六个是返回线程ID

现在来看TThread的核心:线程函数ThreadProc。有意思的是这个线程类的核心却不是线程的成员,而是一个全局函数(因为BeginThread过程的参数约定只能用全局函数)。下面是它的代码:

function ThreadProc(Thread: TThread): Integer;

var

  FreeThread: Boolean;

begin

  try

    if not Thread.Terminated then

    try

      Thread.Execute;

    except

      Thread.FFatalException := AcquireExceptionObject;

    end;

  finally

    FreeThread := Thread.FFreeOnTerminate;

    Result := Thread.FReturnValue;

    Thread.DoTerminate;

    Thread.FFinished := True;

    SignalSyncEvent;

    if FreeThread then Thread.Free;

    EndThread(Result);

  end;

end;

虽然也没有多少代码,但却是整个TThread中最重要的部分,因为这段代码是真正在线程中执行的代码。下面对代码作逐行说明:

首先判断线程类的Terminated标志,如果未被标志为终止,则调用线程类的Execute方法执行线程代码,因为TThread是抽象类,Execute方法是抽象方法,所以本质上是执行派生类中的Execute代码。

所以说,Execute就是线程类中的线程函数,所有在Execute中的代码都需要当作线程代码来考虑,如防止访问冲突等。

如果Execute发生异常,则通过AcquireExceptionObject取得异常对象,并存入线程类的FFatalException成员中。

最后是线程结束前做的一些收尾工作。局部变量FreeThread记录了线程类的FreeOnTerminated属性的设置,然后将线程返回值设置为线程类的返回值属性的值。然后执行线程类的DoTerminate方法。

DoTerminate方法的代码如下:

procedure TThread.DoTerminate;

begin

  if Assigned(FOnTerminate) then Synchronize(CallOnTerminate);

end;

很简单,就是通过Synchronize来调用CallOnTerminate方法,而CallOnTerminate方法的代码如下,就是简单地调用OnTerminate事件:

procedure TThread.CallOnTerminate;

begin

  if Assigned(FOnTerminate) then FOnTerminate(Self);

end;

因为OnTerminate事件是在Synchronize中执行的,所以本质上它并不是线程代码,而是主线程代码(具体见后面对Synchronize的分析)。

执行完OnTerminate后,将线程类的FFinished标志设置为True

接下来执行SignalSyncEvent过程,其代码如下:

procedure SignalSyncEvent;

begin

  SetEvent(SyncEvent);

end;

也很简单,就是设置一下一个全局EventSyncEvent,关于Event的使用,本文将在后文详述,而SyncEvent的用途将在WaitFor过程中说明。

然后根据FreeThread中保存的FreeOnTerminate设置决定是否释放线程类,在线程类释放时,还有一些些操作,详见接下来的析构函数实现。

最后调用EndThread结束线程,返回线程返回值。

至此,线程完全结束。

 (待续)

Delphi的线程类

本文是没有写过delphi的多线程,对delphi的线程类TThread不熟悉的人而写的,主要从 TThread的源代码入手.  Delphi为多线程的实现专门封装了一个TThread类来实现,我们从...
  • wozengcong
  • wozengcong
  • 2015年05月03日 12:26
  • 1427

Delphi中的线程类--之(2)

 Delphi中的线程类 猛禽[Mental Studio]http://mental.mentsu.com 之二首先就是构造函数:constructor TThread.Create(CreateS...
  • walkingboy
  • walkingboy
  • 2004年12月25日 14:57
  • 670

DELPHI基于线程的定时器和一个泛型对象池

笔记 unit ThreadTimer; //次编译指令仅在测试时使用,请勿在Release版本中打开 {$DEFINE RunInMainThread} interface uses Sy...
  • huixch
  • huixch
  • 2016年05月12日 01:13
  • 363

独立线程实现消息循环的Delphi定时器类

Delphi的定时器类TTimer内部是创建不可见的窗口,调用SetTimer这个Win32 API 来实现的。TTimer要求使用它的线程实现了消息循环。所以,除非控制台程序中实现消息循环,否则TT...
  • zhouzuoji
  • zhouzuoji
  • 2008年04月24日 22:31
  • 4454

访问类的私有变量的两种方式

在用image加载bmp图片时,要使用某点的像素值,传统的做法是scanline、canvas.pixel、或者用api函数来获取。 既然image能画出bmp图片来,bmp中应该包含这个位图的像素值...
  • dbyoung
  • dbyoung
  • 2015年04月09日 14:00
  • 2142

Delphi中的线程类(学习ing)

Delphi中的线程类    Delphi中有一个线程类TThread是用来实现多线程编程的,这个绝大多数Delphi书藉都有说到,但基本上都是对TThread类的几个成员作一简单介绍,再说明一下Ex...
  • formiss
  • formiss
  • 2007年04月11日 14:51
  • 1847

delphi2010多线程编程教程

delphi笔记12010-09-14 10:45:47阅读657评论0  字号:大中小 订阅FROM:http://hi.baidu.com/ytlvy2008/blog/item/e5a03ad1...
  • gzcszzx
  • gzcszzx
  • 2011年05月28日 10:21
  • 1761

Delphi中的线程类(2)

 首先就是构造函数:constructor TThread.Create(CreateSuspended: Boolean);begin  inherited Create;  AddThread; ...
  • yepemig
  • yepemig
  • 2009年01月14日 20:06
  • 925

Delphi Thread 进程和线程函数(1)

线程和进程函数: 1.WinExec - 运行外部程序 //声明 WinExec(   lpCmdLine: LPCSTR; {文件名和参数; 如没指定路径会按以下顺序查找: 程序目录/当前目...
  • lailai186
  • lailai186
  • 2013年04月08日 15:52
  • 2087

Delphi中使用TThread类实现多线程

之前写的多线程程序都是用api直接做的,没有用过delphi自带Tthread类,刚才看了下,写了个demo,希望对新手有帮助。。。 窗体单元: unit main; interfa...
  • wozengcong
  • wozengcong
  • 2015年05月03日 12:42
  • 5677
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:Delphi中的线程类--之(2)
举报原因:
原因补充:

(最多只允许输入30个字)