Protection 6 ---- Page-Level Protection

最新推荐文章于 2024-06-18 06:15:00 发布
最新推荐文章于 2024-06-18 06:15:00 发布
阅读量1.2k 收藏
点赞数
分类专栏： learning cpu 文章标签： paging 分页 PF 缺页 interrupt
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/activesys/article/details/17101453
版权

页级别的保护类型

对于分页结构的保护分为两种，一种是对于访问权限的检查，一种是对于线性地址是否存在转换进行检查。

访问权限

分页结构中的一些位是用来规定页的访问权限的，例如R/W，U/S以及XD。这些位在不同的访问模式下起着不同的限制作用。对于一个线性地址的访问有两种模式：supervisor-mode以及user-mode。当CPL<3的时候是supervisor-mode，CPL==3是user-mode。下面这些规则是Intel手册中列举出来的不同的访问权限：

  • supervisor-mode
    • 读数据
      • 可以从任何线性地址读取数据
    • 写数据
      • CR0.WP==0，可以向任何线性地址写数据
      • CR0.WP==1，只能向地址转换过程中使用的分页结构中R/W==1的线性地址写数据
    • 执行
      • 32-Bit Paging或者IA32_EFER.NXE==0，访问权限依赖于CR4.SEMP
        • CR4.SEMP==0，可以执行任何线性地址中的指令
        • CR4.SEMP==1，只能执行转换过程中使用的分页结构的U/S==0的线性地址中的指令
      • PAE Paging或者IA-32e Paging并且IA32_EFER.NXE==1，访问权限也依赖于CR4.SEMP
        • CR4.SEMP==0，只能执行转换过程中使用的分页结构的XD==0的线性地址中的指令
        • CR4.SEMP==0，只能执行转换过程中使用的分页结构的U/S==0并且XD==0的现行地址中的指令
  • user-mode
    • 读数据
      • 只能读取转换过程中使用的分页结构的U/S==1的线性地址中的数据
    • 写数据
      • 只能向转换过程中使用的分页结构的U/S==1并且R/W==1的线性地址中写数据
    • 执行
      • 32-Bit Paging或者IA32_EFER.NXE==0，可以执行地址转换过程中使用的分页结构的U/S==1的线性地址中的指令
      • PAE Paging或者IA-32e Paging并且IA32_EFER.NXE==1，可以执行地址转换过程中分页结构的U/S==1并且XD==0的线性地址中的指令

没有地址转换

另一种检查是检查线性地址在现有的分页结构中有没有转换，所谓没有转换就是线性地址在转换过程中使用的分页结构的P==0或者是保留位被设置。


#PF异常

如果对于一个线性地址的转换过程中违反了上述两种检查，那么就会触发#PF异常。下图是#PF的error code，它描述了#PF的类型：


  • P：
    • 0：异常是由于不存在的页引起的
    • 1：异常是由于违反了Page-Level保护引起的
  • W/R：
    • 0：异常是由于读访问引起的
    • 1：异常是由于写访问一起的
  • U/S：
    • 0：异常是由于supervisor-mode引起的
    • 1：异常是由于user-mode引起的
  • RSVD：
    • 0：异常不是由于保留位被设置引起的
    • 1：异常是由于某些分页结构的保留位被设置引起的
  • I/D：
    • 0：异常不是由于取指引起的
    • 1：异常是由于取指引起的


例子

这里的例子主要是模拟由于没有地址转换导致#PF异常，并且在#PF异常处理程序中修改错误的情况。

首先要准备一段可执行的代码，这段代码要拷贝到能够引起#PF异常的线性地址中以便测试使用。

code_start:
    movl $puts, %ebx
    movl $dump_pae_page, %edx

    movl $msg3, %esi
    call *%ebx
    movl $println, %eax
    call *%eax
    movl $0x400000, %esi
    call *%edx
    movl $println, %eax
    call *%eax

    jmp .
code_end:
这段代码也是通过dump_pae_page来打印一个线性地址的转换过程。

接下来要将这段代码拷贝到测试的地址中，我们使用了0x400000地址为测试地址，不过拷贝的过程要在开启分页之前进行，否则拷贝的过程就会导致#PF。

    /*
     * copy code to 0x400000
     */
    movl $code_start, %esi
    movl $0x400000, %edi
    movl $code_end, %ecx
    subl %esi, %ecx
    rep movsb
测试代码准备好了，调用init_pae32_paging来初始化PAE Paging结构，这个结构和 《PAE Paging》中的分页结构相同，不过就是在0x400000地址转换过程中PDE的保留位被设置了，PTE的P标志被清0，这两种情况都会导致#PF。 
###############################################################
# init_pae32_paging:
init_pae32_paging:
    movl $PDPT_BASE, %esi
    call clear_4k_page
    movl $0x201000, %esi
    call clear_4k_page
    movl $0x202000, %esi
    call clear_4k_page

    # PDPTE[0]
    movl $PDPT_BASE, %esi
    movl $0x201001, (%esi)
    movl $0x00, 4(%esi)
    # PDE[0] 0x00 ~ 0x1fffff (2M)
    # PDE[1] 0x200000 ~ 0x3fffff (2M)
    # PDE[2] 0x400000 ~ 0x400fff (4K)
    movl $0x201000, %esi
    movl $0x00, %eax
    movl $0x00000087, (%esi, %eax, 8)
    movl $0x00, 4(%esi, %eax, 8)
    inc %eax
    movl $0x00200087, (%esi, %eax, 8)
    movl $0x00, 4(%esi, %eax, 8)
    inc %eax
    movl $0x00202007, (%esi, %eax, 8)
    movl $0x70000000, 4(%esi, %eax, 8)
    # PTE[0] 0x400000 ~ 0x400fff (4K)
    movl $0x202000, %esi
    movl $0x00400000, (%esi)
    /*
    movl xd_bit, %eax
    movl %eax, 4(%esi)
    */
    ret
然后就是编写#PF处理代码了，这里能够修改线性地址转换过程中由于数据结构中保留位被设置以及P标志为0的异常。 
###############################################################
# PF_handler():
PF_handler:
    jmp do_PF_handler
pf_msg1:  .asciz  "----> Now, enter #PF handler, occur at: 0x"
pf_msg2:  .asciz  "----> Error Code: 0x"
pf_msg3:  .asciz  "----> fixup <----"
do_PF_handler:
    popl %esi
    pushl %ecx
    pushl %edx
    pushl %ebx

    movl %esi, %ebx
    # puts error address
    movl $pf_msg1, %esi
    call puts
    movl %cr2, %ecx
    movl %ecx, %esi
    call print_int_value
    call println
    # puts error code
    movl $pf_msg2, %esi
    call puts
    movl %ebx, %esi
    call print_int_value
    call println

    call get_maxphyadd
    pushl %ecx
    leal -64(%eax), %ecx
    negl %ecx
    movl $-1, %edi
    shll %cl, %edi
    shrl %cl, %edi
    popl %ecx

# fix error
get_pdpte:
    movl %ecx, %eax
    shrl $30, %eax
    andl $0x03, %eax
    movl $PDPT_BASE, %ebx

    # PDPTE
    pushl %edi
    movl 4(%ebx, %eax, 8), %edx
    notl %edi
    andl %edx, %edi
    jz get_pdpte_low
    popl %edi
    andl %edi, %edx
    movl %edx, 4(%ebx, %eax, 8)
    jmp do_PF_handler_done

get_pdpte_low:
    popl %edi
    movl (%ebx, %eax, 8), %edx
    btsl $0, %edx
    movl %edx, (%ebx, %eax, 8)
    jnc do_PF_handler_done

get_pde:
    #PDE
    movl %edx, %ebx
    andl $0xfffff000, %ebx
    movl %ecx, %eax
    shrl $21, %eax
    andl $0x01ff, %eax

    pushl %edi
    movl 4(%ebx, %eax, 8), %edx
    notl %edi
    andl $0x7fffffff, %edi
    andl %edx, %edi
    jz get_pde_low
    popl %edi
    orl $0x80000000, %edi
    andl %edi, %edx
    movl %edx, 4(%ebx, %eax, 8)
    jmp do_PF_handler_done

get_pde_low:
    popl %edi
    movl (%ebx, %eax, 8), %edx
    btsl $0, %edx
    movl %edx, (%ebx, %eax, 8)
    jnc do_PF_handler_done
    bt $7, %edx
    movl %edx, (%ebx, %eax, 8)
    jc do_PF_handler_done

get_pte:
    #PTE
    movl %edx, %ebx
    andl $0xfffff000, %ebx
    movl %ecx, %eax
    shrl $12, %eax
    andl $0x01ff, %eax

    pushl %edi
    movl 4(%ebx, %eax, 8), %edx
    notl %edi
    andl $0x7fffffff, %edi
    andl %edx, %edi
    jz get_pte_low
    popl %edi
    orl $0x80000000, %edi
    andl %edi, %edx
    movl %edx, 4(%ebx, %eax, 8)
    jmp do_PF_handler_done

get_pte_low:
    popl %edi
    movl (%ebx, %eax, 8), %edx
    btsl $0, %edx
    movl %edx, (%ebx, %eax, 8)
    jc do_PF_handler_done

do_PF_handler_done:

    movl $pf_msg3, %esi
    call puts
    call println
    call println

    popl %ebx
    popl %edx
    popl %ecx
    iret

最后在开启分页之后，首先对线性地址0x400000的转换过程进行打印，然后逃转到0x400000地址去执行其中的指令，由于0x400000地址中的指令也是打印对于线性地址0x400000的转换过程，所以执行结构应该看到两次对于0x400000线性地址的转换过程的打印结构。

    movl $msg3, %esi
    call puts
    call println
    movl $0x400000, %esi
    call dump_pae_page
    call println

    ljmp $KERNEL_CODE32_SELECTOR, $0x400000

最后的执行结构：


从执行结果可以看出，从第一次打印的结构来看，对线性地址0x400000的转换中使用的PDE的保留位被设置了，PTE的P标志被清0，所以没有对线性地址0x400000的转换。接下来的两次#PF正是由于跳转到0x400000地址去执行指令导致的。

第一次#PF是由PDE的保留位被设置导致的，从错误代码中可以看到，0x19表示P==1，RSVD==1，I/D==1，这说明异常是由于违反了页级别的保护引起的，具体是由于一些分页结构的保留位被设置引起的，同时是在取指令时引起的。接下来#PF处理过程修复了这个错误。

第一次#PF异常处理结束后，会重现执行跳转代码，但是这是线性地址0x400000仍然没有转换，所以导致了第二次#PF异常。

第二次#PF是由PTE的P标记被清0导致的，从错误代码中可以看出，0x10表示P==0，I/D==1，这说明异常是由于页不存在导致的，同时是在取指令时引起的。接下来#PF处理过程也修改了这个错误。

两种错误都被修正之后，代码可以正确的跳转到0x400000地址去执行了，执行的结构就是打印出线性地址0x400000被转换的过程，从结果上看之前的错误都被#PF处理过程修复了。


参考

《Intel® 64 and IA-32 Architectures Software Developer’s Manual Volume 3 (3A, 3B & 3C): System Programming Guide》

《x86/x64体系探索及编程》





activesys
关注
专栏目录
关闭内存页保护开启内存页保护cr0
09-04 630
void PageProtectOn() { __asm{//恢复内存保护 mov eax, cr0 or eax, 10000h mov cr0, eax sti } } void PageProtectOff() { __asm{//去掉内存保护 cli mov eax, cr0 and eax, not 10000h mov
kernel bypass smep
qq_46441427的博客
11-09 438
和之前的babydriver一样，用这个来解 semp开启以后，ret2usr就不能用了，因为semp让在ring0权的时候执行用户空间的代码直接crash掉 而系统开启semp的方法是设置cr4寄存器的第20位为1，第20位为0时关闭 gdb 如果不能看 cr4 寄存器的值，可以通过 报错查看。为了关闭 smep 保护，常用一个固定值 0x6f0，即 mov cr4, 0x6f0 #include <stdio.h> #include <stdlib.h> #include &l
使用Rust开发操作系统(4级分页内存)
VenmoSnake的博客
02-27 1994
基础控制位 基础控制位是用于控制内存分页行为，主要为以下寄存器 CR0寄存器： CR0寄存器的WP（第16位）和PG位(第31位) CR4寄存器： CR0寄存器的PSE(第4位),PAE(第5位),PGE(第7位),PCIDE(第17位),SMEP(第20位),SMAP(第21位),PKE(第22位),CET(第23位)标志位 MSR寄存器：MSR寄存器LME(第8位)和NXE(第11位)标志位...
深入理解计算机系统 第三章大略和第五章大略
weixin_30443813的博客
05-29 146
这2章总结的很少，主要是觉得没那么重要。 1. 　　1）2个操作数的指令，第二个操作数通常是目的操作数:movb a b，move a to b,而add a b,b+=a，指令分为指令类，如mov类：movb,movw,movl，b指一个字节，w表示2个字节，l表示4个字节；movs类（扩展填符号）,movz类（扩展填0） 　　2）寄存器：这里只说ia32体系的那8个32位寄存器，...
Linux mem 1.3 分页寻址(Paging)机制详解
pwl999的博客
11-02 4079
文章目录1. X86手册定义1.1 paging modes1.2 `4-LEVEL PAGING`和`5-LEVEL PAGING`模式1.2.1 `4-LEVEL PAGING`1.2.2 CR3 format1.2.3 PML5/PGD entry format1.2.4 PML4/P4D entry format1.2.5 PDPT/PUD entry format (1-GByte Page)1.2.6 PDPT/PUD entry format (Page Directory)1.2.7 PD/
CentOS使用docker-compose安装redis
Peter Cheung的博客
08-15 1533
讲述如何在Linux环境下使用docker-compose安装redis。
理解Computer中memory-mapped file
漫步量化
06-30 917
内存映射 内存映射：将内核空间的一段内存区域映射到用户空间。可以将内核空间的一段内存区域同时映射到多个进程，实现进程间的共享内存通信。 《理解内核空间、内存区域、用户空间》 《Memory-mapped I/O》 《理解Computer中slack space, page cache, thrash》 memory map in computer science Wikipedia A memory map is a structure of data(which usually resides..
LAB3_User-Level Environments_PartB Page Faults, Breakpoints Exceptions, and System Calls
Small_Pond的博客
06-19 605
1. PartB: Page Faults, Breakpoints Exceptions, and System Calls 1.1. 处理页错误 1.1.1. Exercise 5. 修改 trap_dispatch() 将 page fault exceptions 分配到 page_fault_handler(). 记住你可以用make run-xor make run-x-nox是启动...
8-07-14_MegaCLI for linux_windows
03-15
LSIP200233314 (DFCT) Pcilinkspeedset and adpdowngrade cmds are not working and Need to update Help page LSIP200232870 (DFCT) Add a Gen2 to Gen3 toggle function and a check for the PCI speed to ...
CA-100CUSB充电线改装为移动电源
09-23
• Remove references to 5-6 data bits and 1.5 stop bits. • Fix blue screen in checked build serial driver. • Power management fast resume for Vista. • Fixed LocID problem with usb2.0 hubs on Win2K....
第 10 章 Prometheus 监控 | 实战案例 - Nginx 监控
最新发布
甘蓝的专栏
06-18 299
为 Nginx 安装 nginx-prometheus-exporter，实现对 Nginx 的监控。
10.4 自制操作系统: risc-v 虚拟内存系统
Do one thing at a time, and do well.
04-12 3156
Sv32 全称： Page-Based 32-bit Virtual-Memory Systems 当Sv32是被写入到satp.MODE时，s-mode是在一个32-bit的虚拟内存系统。在这种模式下，supervisor和user虚拟地址通过遍历基树页表转换为supervisor物理地址。 当 SXLEN=32 时支持 Sv32，并且旨在包含足以支持现代基于 Unix 的操作系统的机制。 Addressing and Memory Protection （寻址和内存保护） Sv32 实现支持
整理文件夹
guocaigao的专栏
10-09 1234
目前我们所有的文件都在一个文件夹下，目录结构如下 以后代码越来越多，管理起来很不方便，下面我们就仿照linux的目录结构来整理一下：新建一个boot文件夹，将bootsect.S、head.S、setup.S此文件夹下；新建include文件夹，在此文件夹下新建asm和linux文件夹，asm文件夹下添加io.h和system.h，linux文件夹下添加head.h；新建init文件夹并将mai
8259A
activesys的专栏
12-23 7610
8259A 中断响应 命令字 例子 参考
PAE Paging
activesys的专栏
11-20 2311
PAE Paging与32-Bit Paging的区别 PAE Paging与32-Bit Paging的不同点在于PAE Paging可将32-Bit的线性地址转换成最高52位的物理地址，不过受到线性地址宽度的限制，最高可访问的线性地址空间还是4G。还有就是PAE Paging使用4个PDPTE寄存器进行地址转换，CR3寄存器保存这4个PDPTE寄存器的物理地址。这样在地址转换时可以使用更多的
32-Bit Paging
activesys的专栏
11-11 1465
分页 分页是将线性地址转换成物理地址的机制，当关闭分页的时候线性地址直接映射成物理地址，开启分页之后线性地址要经过一系列的转换才能获得物理地址。分页的好处很多，有了分页，OS可以对页面进行调度，这样OS可以实现虚拟内存以及多任务。 将线性地址转换成物理地址的过程中主要关心下面这些方面： 线性地址宽度。物理地址宽度。页大小。访问权限。被缓存的能力。 Intel CPU支持很多种分
Real-Address Mode
activesys的专栏
08-08 1198
当Intel CPU启动或者RESET#引脚有效的时候就进入了实地址模式或者叫实模式(Real-Address Mode)。实模式是Intel 8086/8088的运行模式，所以这种模式下的使用的资源是受限的，例如使用20位的地址总线寻址1M的地址空间等等。 实模式下的执行环境 实模式下CPU提供的执行环境包括： 支持1M的物理地址空间。8位或者16位的操作数。8个16位的通
Switching to Protected-Mode
activesys的专栏
08-13 1085
保护模式的作用 实模式下CPU只提供了部分资源和功能供我们使用，但是在保护模式下CPU的全部资源和功能都可以供我们使用，同时CPU还提供了对于不同内存段的基于权限级别的保护方式，这样代码运行起来更安全，寻址方面，保护模式下可以寻址4G的地址空间。 保护模式下的分段管理 保护模式下也采用分段管理的方式将逻辑地址转换成线性地址，但是分段管理的基址是不同的，保护模式的分段管理更复杂，下面一
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值