专注于操作系统12之回到实模式

         前面我们实现了从实模式到保护模式的转换，现在来实现实模式到保护模式的转换。转换需注意：要从16位的代码段返回实模式，所以在转换代码中加了一段16位代码（即先从保护模式进入到这个16位代码段，再由这个16位代码段转换到实模式）；在转换到实模式前，需将段寄存器标准化（属性为可读写，大小为0ffffh）,这里用了一个normal描述符来实现.以下代码参照了《自己动手写操作系统》。

      

;;nasm 2.07
;;nasm backtoreal.asm -o backtoreal.img

org 07c00H

%macro Descriptor 3             ;定义Descriptor结构体宏
	dw	%2 & 0FFFFh				; 段界限 1				(2 字节)
	dw	%1 & 0FFFFh				; 段基址 1				(2 字节)
	db	(%1 >> 16) & 0FFh			; 段基址 2				(1 字节)
	dw	((%2 >> 8) & 0F00h) | (%3 & 0F0FFh)	; 属性 1 + 段界限 2 + 属性 2		(2 字节)
	db	(%1 >> 24) & 0FFh			; 段基址 3				(1 字节)
%endmacro ; 共 8 字节

DA_C		EQU	98h	; 只读代码段的属性值
DA_DRW		EQU	92h	; 允许读写的数据段的属性值
DA_32		EQU	4000h	;32位段的属性值


	jmp	LABEL_BEGIN         
	               ;现在进行第一步：建立GDT表
[SECTION .gdt]     ;用于放GDT表的段
;GDT
LABEL_GDT: Descriptor 0,0,0 ;空描述符，当一个任务没有LDT时，会把LDTR清空，这时，LDTR便指向空描述符。

LABEL_CODE32: Descriptor 0,SegCode32Len-1,DA_C + DA_32 ; 代码段的描述符

LABEL_VIDEO: Descriptor 0B8000h,0ffffh,DA_DRW    ;显存的描述符，0b8000h是显存的首地址
;GDT 结束
LABEL_NORMAL: Descriptor 0,0ffffh,DA_DRW      ;normal描述符，用于将段寄存器的属性规范化（即属性为读写，大小为0ffffh）
LABEL_CODE16: Descriptor 0,0ffffh,DA_C       ;16位代码段
GdtLenth equ $ - LABEL_GDT   ;计算GDT表的长度

GdtPtr dw GdtLenth - 1 ; 准备存入GDTR的信息
       dd 0    ;    用于存放GDT表的物理地址，后面会计算


;GDT选择子

SelectorCode32 equ LABEL_CODE32 - LABEL_GDT ;代码段的选择子
SelectorVideo  equ LABEL_VIDEO - LABEL_GDT  ;显存所在段的选择子
SelectorNormal equ LABEL_NORMAL - LABEL_GDT  ;normal描述符的选择子
SelectorCode16 equ LABEL_CODE16 - LABEL_GDT ;16位段的选择子 
;[SECTION .gdt]结束

[SECTION .s16]
[BITS 16]	;目标处理器模式
LABEL_BEGIN:
mov ax,cs
mov ds,ax
mov es,ax
mov ss,ax
mov sp,0100h

mov [LABEL_BACK_TO_REAL + 3],ax    ;保存cs的值,用于后面的jmp 0:LABEL_REAL 使它变成 jmp cs:LABEL_REAL


; 初始化 16 位代码段描述符
	mov	ax, cs
	movzx	eax, ax
	shl	eax, 4
	add	eax, LABEL_SEG_CODE16
	mov	word [LABEL_CODE16 + 2], ax
	shr	eax, 16
	mov	byte [LABEL_CODE16 + 4], al
	mov	byte [LABEL_CODE16 + 7], ah




;初始化32位段的描述符

xor eax,eax   ; 同或运算，这里是将eax清零

mov ax,cs
shl eax,4     ;左移四位，相当于乘以16，实模式下计算物理地址
add eax,LABEL_SEG_CODE32    ;eax中为32位段的物理地址

mov word [LABEL_CODE32 + 2],ax   ;将32位段的物理地址存入段的描述符中

shr eax,16
mov byte [LABEL_CODE32 + 4],al
mov byte [LABEL_CODE32 + 7],ah

;计算GDT表的物理地址,将GDT表的物理地址信息存入GdtPtr中
xor eax,eax
mov ax,cs
shl eax,4
add eax,LABEL_GDT
mov dword [GdtPtr + 2],eax

;现在进行第二步：将GDT表的信息加载到GDTR中
lgdt [GdtPtr]  ;装载GDTR

;关中断
cli

;现在进行第三步：打开地址线
in al,92h
or al,00000010b
out 92h,al

;现在进行第四步：置PE为1，表示CPU处于保护模式下
mov eax,cr0
or eax,1
mov cr0,eax
;现在进入第五步：跳到保护模式的代码

jmp dword SelectorCode32:0  ;这里将SelectorCode32存入CS中作为选择子
;[SECTION .s16] 结束

;保护模式下的代码,32位代码
[SECTION .s32]
[BITS 32]  

LABEL_SEG_CODE32:
mov ax,SelectorVideo ;视频选择子,用于找到显存段的描述符
mov gs,ax 

mov edi,(80 * 10 + 0)*2  ;屏幕的第10行，第0列
mov ah,0Ch
mov al,'p'
mov [gs:edi],ax ;将字符‘p’输出到屏幕
 
jmp SelectorCode16:0

SegCode32Len equ $ - LABEL_SEG_CODE32  ;计算32位代码段的长度

[SECTION .code16]
ALIGN 32
[BITS 16]
LABEL_SEG_CODE16:
mov ax,SelectorNormal  ;将段寄存器标准化
mov es,ax
mov ds,ax
mov ss,ax
mov fs,ax
mov gs,ax

mov eax,cr0   ;将PE置零，让CPU处于实模式
and al,11111110b
mov cr0,eax

LABEL_BACK_TO_REAL:      ;跳到实模式下，注意这里jmp指令中的段地址不为0，前面已赋值
jmp 0:LABEL_REAL

Code16Len equ $ - LABEL_SEG_CODE16  

LABEL_REAL:    ;进入实模式
            ;还原es，ss，ds的值
mov ax,cs
mov es,ax
mov ds,ax
mov ss,ax

 in	al, 92h		; 
 and	al, 11111101b	; 关闭 A20 地址线
 out	92h, al		; 

 sti ;开中断

jmp $

times 510-($-$)  db 0
dw 0aa55h