s3c44B0的启动代码44b0init.S的中断分析

问题一：什么是向量式中断处理和非向量式中断处理

解答：向量式中断处理是有硬件判断优先级，这个硬件逻辑提供矢量表的一条跳转指令放到0x1C或0x18，这个地址提供了相应服务程序的跳转指令。

;中断向量表
VECTOR_BRANCH
    ldr pc,=HandlerEINT0    ;mGA    0x20
    ldr pc,=HandlerEINT1    ;    
    ldr pc,=HandlerEINT2    ;
    ldr pc,=HandlerEINT3    ;
    ldr pc,=HandlerEINT4567    ;
    ldr pc,=HandlerTICK        ;mGA    0x34
    b .
    b .
    ldr pc,=HandlerZDMA0    ;mGB    0x40
    ldr pc,=HandlerZDMA1    ;
    ldr pc,=HandlerBDMA0    ;
    ldr pc,=HandlerBDMA1    ;
    ldr pc,=HandlerWDT        ;
    ldr pc,=HandlerUERR01    ;mGB    0x54
    b .
    b .
    ldr pc,=HandlerTIMER0    ;mGC    0x60
    ldr pc,=HandlerTIMER1    ;
    ldr pc,=HandlerTIMER2    ;
    ldr pc,=HandlerTIMER3    ;
    ldr pc,=HandlerTIMER4    ;
    ldr pc,=HandlerTIMER5    ;mGC    0x74
    b .
    b .
    ldr pc,=HandlerURXD0    ;mGD    0x80
    ldr pc,=HandlerURXD1    ;
    ldr pc,=HandlerIIC        ;
    ldr pc,=HandlerSIO        ;
    ldr pc,=HandlerUTXD0    ;
    ldr pc,=HandlerUTXD1    ;mGD    0x94
    b .
    b .
    ldr pc,=HandlerRTC        ;mGKA    0xa0
    b .
    b .
    b .
    b .
    b .                        ;mGKA
    b .
    b .
    ldr pc,=HandlerADC        ;mGKB    0xc0
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;
    b .                        ;mGKB
    b .
    b .
    ldr pc,=EnterPWDN        ;0xe0=EnterPWDN

—————————————————————————————————————————————————————————————————————————————

HANDLER是个宏

 MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
    sub        sp,sp,#4            ;decrement sp(to store jump address)
    stmfd   sp!,{r0}            ;PUSH the work register to stack(lr does't push because it return to original address)
    ldr        r0,=$HandleLabel    ;load the address of HandleXXX to r0
    ldr        r0,[r0]                ;load the contents(service routine start address) of HandleXXX
    str        r0,[sp,#4]            ;store the contents(ISR) of HandleXXX to stack
    ldmfd   sp!,{r0,pc}            ;POP the work register and pc(jump to ISR)
    MEND

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

对于HandlerADC       展开就是(;HandlerADC    HANDLE HandleADC 解为)：

                                                            ;
;HandlerADC                        ;HandlerADC为中断向量表的入口                                                ;
;   sub        sp,sp,#4            ;将sp减少一个字节，使其在堆栈高端留出存储返回地址，因为pc在寄存器组中的            ;
;                                ;的位置大于r0，出栈时装入的是栈的高端的内容                                    ;
;   stmfd   sp!,{r0}            ;保存r0                                                                    ;
;   ldr        r0,=HandleADC        ;装载中断处理函数的指针                                                    ;
;   ldr        r0,[r0]                ;装载中断处理函数的地址                                                    ;
;   str        r0,[sp,#4]            ;将中断处理函数的地址存入刚才预留的位置，r0的上面                                ;
;   ldmfd   sp!,{r0,pc}            ;出栈后，pc指向的既是中断处理函数的地址                                         ;
;                                                                                                       ;
;    INTCON^2 == 0时,vector table使能                                                                        ;
;    发生中断->HandlerADC->HandleADC(pISR_ADC,即:_ISR_STARTADDRESS+0x20);                                    ;                          
;    若要在程序中处理此中断，只要将中断服务函数的指针赋给pISR_ADC,如：pISR_ADC = (int)ADCIsr                      ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

也就是说，在ADC有中断发生时，0x18或0x1C处就是 b HandlerADC ，其他IRQ中断类似：

  AREA    Init,CODE,READONLY
    ENTRY
  0            b ResetHandler                ;for debug                             
   4           b HandlerUndef                ;handlerUndef
   8           b HandlerSWI                ;SWI interrupt handler
  0x0C     b HandlerPabort                ;handlerPAbort
  0x10      b HandlerDabort                ;handlerDAbort
  0x14      b .                            ;handlerReserved
  0x18      b HandlerIRQ         这里会被替换
   0x1C    b HandlerFIQ
     

HandlerFIQ        HANDLER HandleFIQ
HandlerIRQ        HANDLER HandleIRQ
HandlerUndef    HANDLER HandleUndef
HandlerSWI        HANDLER HandleSWI
HandlerDabort    HANDLER HandleDabort
HandlerPabort    HANDLER HandlePabort

HandlerADC        HANDLER HandleADC            HandleADC刚好是IRQ中断处理表的首址，为了和非向量式中断处理的逻辑符合
HandlerRTC        HANDLER HandleRTC
HandlerUTXD1    HANDLER HandleUTXD1
HandlerUTXD0    HANDLER HandleUTXD0
HandlerSIO        HANDLER HandleSIO
HandlerIIC        HANDLER HandleIIC

。

。

。

——————————————————————————————————————————————————————

那什么是非向量式中断呢？

解答：非向量式中断就是不用硬件判断，而改用软件（44b0init.s里）判断，如下：

;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;非向量中断的处理                                                                                          ;
;如果I_ISPC的使用不正确，此时I_ISPR可能为零                                                                  ;
;堆栈内容的变化                                                                                              ;
;                                                                                                       ;
;H    sp    |--|        |--|        |--|        |--|     sp    |--|                                            ;
;        |  |     sp    |  |         |  |         |ad|->pc    |  |                                            ;
;        |  |        |  |        |r9|        |r9|->r9    |  |                                            ;
;L        |  |        |  |     sp |r8|     sp    |r8|->r8    |  |                                            ;
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
IsrIRQ                            ;using I_ISPR register.
    sub        sp,sp,#4            ;预留返回指针的存储位置
    stmfd   sp!,{r8-r9}   

    ldr        r9,=I_ISPR
    ldr        r9,[r9]                ;载入I_ISPR

    cmp        r9, #0x0            ;If the IDLE mode work-around is used,r9 may be 0 sometimes.
    beq        %F2                    ;无可处理中断,返回

    mov        r8,#0x0                ;r8为偏移量,清零

0
    movs    r9,r9,lsr #1        ;从右向左逐位检验
    bcs        %F1
    add        r8,r8,#4            ;偏移量累加
    b        %B0                

1
    ldr        r9,=HandleADC        ;中断处理表的首址
    add        r9,r9,r8            ;计算中断处理表的入口地址 r9+r8,即装载中断处理函数的指针
    ldr        r9,[r9]                ;装载中断处理函数的地址
    str        r9,[sp,#8]            ;将中断处理函数的地址存入刚才预留的位置,r8和r9的上面
    ldmfd   sp!,{r8-r9,pc}        ;出栈后,pc指向的既是中断处理函数的地址

2
    ldmfd    sp!,{r8-r9}            ;恢复r8,r9
    add        sp,sp,#4            ;恢复栈指针
    subs    pc,lr,#4            ;返回