delphi RTTI 反射技术

最新推荐文章于 2020-09-03 15:09:26 发布
最新推荐文章于 2020-09-03 15:09:26 发布
阅读量6k 收藏 5
点赞数 1
分类专栏： delphi
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/earbao/article/details/46729785
版权 
unit Unit_main;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls, TypInfo;

type
  TForm_main = class(TForm)
    Button1: TButton;
    Memo1: TMemo;
    Memo2: TMemo;
    Button2: TButton;
    Button3: TButton;
    Button4: TButton;
    Button5: TButton;
    Button6: TButton;
    Button7: TButton;
    Button8: TButton;
    Button9: TButton;
    Button10: TButton;
    Button11: TButton;
    Button12: TButton;
    Button13: TButton;
    procedure Button1Click(Sender: TObject);
    procedure Button2Click(Sender: TObject);
    procedure Button3Click(Sender: TObject);
    procedure Button4Click(Sender: TObject);
    procedure Button5Click(Sender: TObject);
    procedure Button6Click(Sender: TObject);
    procedure Button7Click(Sender: TObject);
    procedure Button8Click(Sender: TObject);
    procedure Button9Click(Sender: TObject);
    procedure Button10Click(Sender: TObject);
    procedure Button11Click(Sender: TObject);
    procedure Button12Click(Sender: TObject);
    procedure Button13Click(Sender: TObject);
  private
    { Private declarations }
  public
    { Public declarations }
  end;

  PTKeyDog = ^TKeyDog;

  TKeyDog = record
    id: Integer;
    projectname: string;
    city: string;
    letter: string;
    hash: string;
    code: string;
    note: string;
    filepath: string;
    userid: Integer;
  end;

  { 自定义的类 }
  TMyClass = class(TComponent)
  public
    procedure msg(const str: string);
    function Add(const a, b: Integer): Integer;
  end;


  // 编译指令 Methodinfo 是 Delphi 2009 新增的, 只有它打开了, ObjAuto 才可以获取 public 区的信息.
  // 这样, ObjAuto 可以获取 TClass3 的 public、published 和默认区域的信息.
{$M+}
{$METHODINFO ON}

  TClass3 = class
    function Fun3: string;
  private
    function Fun3Private: string;
  protected
    function Fun3Protected: string;
  public
    function Fun3Public: string;
  published
    function Fun3Published: string;
  end;
{$METHODINFO OFF}
{$M-}

var
  Form_main: TForm_main;

implementation

uses
  Rtti, ObjAuto;
{$R *.dfm}

// 获取对象的 RTTI 属性与事件的函数
function GetPropertyAndEventList(obj: TObject;
  pList, eList: TStringList): Boolean;
var
  ClassTypeInfo: PTypeInfo; { 类的信息结构指针 }
  ClassDataInfo: PTypeData; { 类的数据结构指针 }
  propertyList: PPropList; { TPropInfo 是属性的数据结构;
    PPropList 是其指针;
    TPropList 是属性结构指针的列表数组;
    PPropList 是指向这个数组的指针 }

  num: Integer; { 记录属性的总数 }
  size: Integer; { 记录属性结构的大小 }
  i: Integer;
begin
  ClassTypeInfo := obj.ClassInfo; { 先获取: 类的信息结构指针 }
  ClassDataInfo := GetTypeData(ClassTypeInfo); { 再获取: 类的数据结构指针 }
  num := ClassDataInfo.PropCount; { 属性总数 }
  size := SizeOf(TPropInfo); { 属性结构大小 }

  GetMem(propertyList, size * num); { 给属性数组分配内存 }

  GetPropInfos(ClassTypeInfo, propertyList); { 获取属性列表 }

  for i := 0 to num - 1 do
  begin
    if propertyList[i].PropType^.Kind = tkMethod then { 如果是事件; 事件也是属性吗, 给分出来 }
      eList.Add(propertyList[i].Name)
    else
      pList.Add(propertyList[i].Name);
  end;

  pList.Sort;
  eList.Sort; { 排序 }

  FreeMem(propertyList); { 释放属性数组的内存 }

  Result := True;
end;

procedure TForm_main.Button10Click(Sender: TObject);
var
  obj: TMyClass;
  t: TRttiType;
  m1, m2: TRttiMethod;
  r: TValue; // TRttiMethod.Invoke 的返回类型
begin
  t := TRttiContext.Create.GetType(TMyClass);
  { 获取 TMyClass 类的两个方法 }
  m1 := t.GetMethod('msg'); { procedure }
  m2 := t.GetMethod('Add'); { function }

  obj := TMyClass.Create(Self); { 调用需要依赖一个已存在的对象 }

  { 调用 msg 过程 }
  m1.Invoke(obj, ['Delphi 2010']); { 将弹出信息框 }

  { 调用 Add 函数 }
  r := m2.Invoke(obj, [1, 2]); { 其返回值是个 TValue 类型的结构 }
  ShowMessage(IntToStr(r.AsInteger)); { 3 }

  obj.Free;
end;

procedure TForm_main.Button11Click(Sender: TObject);
var
  obj: TMyClass;
  t: TRttiType;
  p: TRttiProperty;
  r: TValue;
begin
  obj := TMyClass.Create(Self);
  t := TRttiContext.Create.GetType(TMyClass);

  p := t.GetProperty('Name'); // 继承自TComponent的name

  r := p.GetValue(obj);
  ShowMessage(r.AsString); { 原来的 }

  p.SetValue(obj, 'NewName');
  r := p.GetValue(obj);
  ShowMessage(r.AsString); { NewName }

  obj.Free;
end;

procedure TForm_main.Button12Click(Sender: TObject);
var
  t: TRttiType;
  p: TRttiProperty;
  r: TValue;
begin
  t := TRttiContext.Create.GetType(TButton);

  p := t.GetProperty('Align');
  p.SetValue(Button1, TValue.FromOrdinal(TypeInfo(TAlign), Ord(alLeft)));

  r := p.GetValue(Button1);
  ShowMessage(IntToStr(r.AsOrdinal)); { 3 }
end;

procedure TForm_main.Button13Click(Sender: TObject);
var
  MiArr: TMethodInfoArray;
  Mi: PMethodInfoHeader;
  obj: TClass3;
begin
  obj := TClass3.Create;
  MiArr := GetMethods(obj.ClassType);

  Memo1.Clear;
  for Mi in MiArr do
    Memo1.Lines.Add(string(Mi.Name));

  obj.Free;
end;

procedure TForm_main.Button1Click(Sender: TObject);
var
  propertyL, EventL: TStringList;
begin
  // 属性
  propertyL := TStringList.Create;
  // 事件
  EventL := TStringList.Create;

  Memo1.Clear;
  Memo2.Clear;

  GetPropertyAndEventList(Self, propertyL, EventL); { 调用函数, 第一个参数是对象名 }
  Memo1.Lines := propertyL;
  Memo2.Lines := EventL;

  propertyL.Free;
  EventL.Free;
end;

procedure TForm_main.Button2Click(Sender: TObject);
var
  ctx: TRttiContext;
  t: TRttiType;
begin
  Memo1.Clear;
  for t in ctx.GetTypes do
    Memo1.Lines.Add(t.Name);
end;

procedure TForm_main.Button3Click(Sender: TObject);
var
  ctx: TRttiContext;
  t: TRttiType;
  m: TRttiMethod;
begin
  Memo1.Clear;
  t := ctx.GetType(TButton);
  // for m in t.GetMethods do Memo1.Lines.Add(m.Name);
  for m in t.GetMethods do
    Memo1.Lines.Add(m.ToString);
end;

procedure TForm_main.Button4Click(Sender: TObject);
var
  ctx: TRttiContext;
  t: TRttiType;
  p: TRttiProperty;
begin
  Memo1.Clear;
  t := ctx.GetType(TButton);
  // for p in t.GetProperties do Memo1.Lines.Add(p.Name);
  for p in t.GetProperties do
    Memo1.Lines.Add(p.ToString);
end;

procedure TForm_main.Button5Click(Sender: TObject);
var
  ctx: TRttiContext;
  t: TRttiType;
  f: TRttiField;
begin
  Memo1.Clear;
  t := ctx.GetType(TButton);
  // for f in t.GetFields do Memo1.Lines.Add(f.Name);
  for f in t.GetFields do
    Memo1.Lines.Add(f.ToString);
end;

// http://my.oschina.net/hermer/blog/320075
procedure TForm_main.Button6Click(Sender: TObject);
var
  ctx: TRttiContext;
  t: TRttiType;
  ms: TArray<TRttiMethod>;
  ps: TArray<TRttiProperty>;
  fs: TArray<TRttiField>;
begin
  Memo1.Clear;
  t := ctx.GetType(TButton);

  ms := t.GetMethods;
  ps := t.GetProperties;
  fs := t.GetFields;

  Memo1.Lines.Add(Format('%s 类共有 %d 个方法', [t.Name, Length(ms)]));
  Memo1.Lines.Add(Format('%s 类共有 %d 个属性', [t.Name, Length(ps)]));
  Memo1.Lines.Add(Format('%s 类共有 %d 个字段', [t.Name, Length(fs)]));
end;

procedure TForm_main.Button7Click(Sender: TObject);
var
  t: TRttiRecordType;
  f: TRttiField;
begin
  Memo1.Clear;
  t := TRttiContext.Create.GetType(TypeInfo(TPoint)).AsRecord;
  Memo1.Lines.Add(t.QualifiedName);
  Memo1.Lines.Add(Format('Size: %d', [t.TypeSize]));
  Memo1.Lines.Add(EmptyStr);

  Memo1.Lines.Add(Format('字段数: %d', [Length(t.GetFields)]));
  Memo1.Lines.Add(Format('方法数: %d', [Length(t.GetMethods)]));
  Memo1.Lines.Add(Format('属性数: %d', [Length(t.GetProperties)]));
  Memo1.Lines.Add(EmptyStr);

  Memo1.Lines.Add('全部字段:');
  for f in t.GetFields do
    Memo1.Lines.Add(f.ToString);
end;

procedure TForm_main.Button8Click(Sender: TObject);
var
  t: TRttiRecordType;
  f: TRttiField;
begin
  Memo1.Clear;
  t := TRttiContext.Create.GetType(TypeInfo(TKeyDog)).AsRecord;
  Memo1.Lines.Add(t.QualifiedName);
  Memo1.Lines.Add(Format('Size: %d', [t.TypeSize]));
  Memo1.Lines.Add(EmptyStr);

  Memo1.Lines.Add(Format('字段数: %d', [Length(t.GetFields)]));
  Memo1.Lines.Add(Format('方法数: %d', [Length(t.GetMethods)]));
  Memo1.Lines.Add(Format('属性数: %d', [Length(t.GetProperties)]));
  Memo1.Lines.Add(EmptyStr);

  Memo1.Lines.Add('全部字段:');
  for f in t.GetFields do
    Memo1.Lines.Add(f.ToString);
end;

procedure TForm_main.Button9Click(Sender: TObject);
var
  t: TRttiOrdinalType;
begin
  Memo1.Clear;

  // 先从类型名获取类型信息对象
  t := TRttiContext.Create.GetType(TypeInfo(Byte)) as TRttiOrdinalType;
  Memo1.Lines.Add(Format('%s - %s', [t.Name, t.QualifiedName]));
  Memo1.Lines.Add(Format('Size: %d', [t.TypeSize]));
  Memo1.Lines.Add('QualifiedName: ' + t.QualifiedName);
  Memo1.Lines.Add(Format('Min,Max: %d , %d', [t.MinValue, t.MaxValue]));
  Memo1.Lines.Add(EmptyStr); // 空字串

  // 可以用 AsOrdinal 方法代替前面的 as TRttiOrdinalType
  t := TRttiContext.Create.GetType(TypeInfo(Word)).AsOrdinal;
  Memo1.Lines.Add(Format('%s: %s', [t.Name, t.QualifiedName]));
  Memo1.Lines.Add(Format('Size: %d', [t.TypeSize]));
  Memo1.Lines.Add(Format('Min,Max: %d , %d', [t.MinValue, t.MaxValue]));
  Memo1.Lines.Add(EmptyStr);

  // 也可以直接强制转换
  t := TRttiOrdinalType(TRttiContext.Create.GetType(TypeInfo(Integer)));
  Memo1.Lines.Add(Format('%s: %s', [t.Name, t.QualifiedName]));
  Memo1.Lines.Add(Format('Size: %d', [t.TypeSize]));
  Memo1.Lines.Add(Format('Min,Max: %d , %d', [t.MinValue, t.MaxValue]));
  Memo1.Lines.Add(EmptyStr);
end;

{ TMyClass }

function TMyClass.Add(const a, b: Integer): Integer;
begin
  Result := a + b;
end;

procedure TMyClass.msg(const str: string);
begin
  MessageDlg(str, mtInformation, [mbYes], 0);
end;

{ TClass3 }

function TClass3.Fun3: string;
begin
  Result := 'Fun3';
end;

function TClass3.Fun3Private: string;
begin
  Result := 'Fun3Private';
end;

function TClass3.Fun3Protected: string;
begin
  Result := 'Fun3Protected';
end;

function TClass3.Fun3Public: string;
begin
  Result := 'Fun3Public';
end;

function TClass3.Fun3Published: string;
begin
  Result := 'Fun3Published';
end;

end.
object Form_main: TForm_main
  Left = 0
  Top = 0
  Caption = 'delphi RTTI  '#21453#23556#25216#26415
  ClientHeight = 523
  ClientWidth = 804
  Color = clBtnFace
  Font.Charset = DEFAULT_CHARSET
  Font.Color = clWindowText
  Font.Height = -11
  Font.Name = 'Tahoma'
  Font.Style = []
  OldCreateOrder = False
  PixelsPerInch = 96
  TextHeight = 13
  object Button1: TButton
    Left = 8
    Top = 8
    Width = 97
    Height = 25
    Caption = 'rtti '#21453#23556
    TabOrder = 0
    OnClick = Button1Click
  end
  object Memo1: TMemo
    Left = 8
    Top = 175
    Width = 537
    Height = 287
    ScrollBars = ssBoth
    TabOrder = 1
  end
  object Memo2: TMemo
    Left = 595
    Top = 175
    Width = 201
    Height = 287
    ScrollBars = ssBoth
    TabOrder = 2
  end
  object Button2: TButton
    Left = 136
    Top = 8
    Width = 75
    Height = 25
    Caption = 'gettype'
    TabOrder = 3
    OnClick = Button2Click
  end
  object Button3: TButton
    Left = 248
    Top = 8
    Width = 121
    Height = 25
    Caption = #33719#21462'TButton '#31867#30340#26041#27861
    TabOrder = 4
    OnClick = Button3Click
  end
  object Button4: TButton
    Left = 400
    Top = 8
    Width = 121
    Height = 25
    Caption = #33719#21462'TButton '#31867#30340#23646#24615
    TabOrder = 5
    OnClick = Button4Click
  end
  object Button5: TButton
    Left = 544
    Top = 8
    Width = 145
    Height = 25
    Caption = #33719#21462' TButton '#31867#30340#23383#27573
    TabOrder = 6
    OnClick = Button5Click
  end
  object Button6: TButton
    Left = 8
    Top = 48
    Width = 305
    Height = 25
    Caption = #33719#21462#33719#21462' TButton '#31867#30340#26041#27861#38598#21512#12289#23646#24615#38598#21512#12289#23383#27573#38598#21512
    TabOrder = 7
    OnClick = Button6Click
  end
  object Button7: TButton
    Left = 344
    Top = 48
    Width = 233
    Height = 25
    Caption = 'TRttiRecordType '#35835#21462#20102#32467#26500#30340#20449#24687'.'
    TabOrder = 8
    OnClick = Button7Click
  end
  object Button8: TButton
    Left = 595
    Top = 48
    Width = 190
    Height = 25
    Caption = #35835#21462#33258#23450#20041#32467#26500#20307'TKeyDog'#20449#24687
    TabOrder = 9
    OnClick = Button8Click
  end
  object Button9: TButton
    Left = 8
    Top = 96
    Width = 185
    Height = 25
    Caption = #26377#24207#31867#22411'TRttiOrdinalType'
    TabOrder = 10
    OnClick = Button9Click
  end
  object Button10: TButton
    Left = 224
    Top = 96
    Width = 161
    Height = 25
    Caption = 'Rtti '#21453#23556#35843#29992'TMyClass '#30340#26041#27861
    TabOrder = 11
    OnClick = Button10Click
  end
  object Button11: TButton
    Left = 408
    Top = 96
    Width = 185
    Height = 25
    Caption = 'Rtti '#21453#23556#20462#25913'TMyClass '#31867#30340#23646#24615#22495
    TabOrder = 12
    OnClick = Button11Click
  end
  object Button12: TButton
    Left = 614
    Top = 96
    Width = 155
    Height = 25
    Caption = 'rtti '#21453#23556#20462#25913#26522#20030#20540
    TabOrder = 13
    OnClick = Button12Click
  end
  object Button13: TButton
    Left = 8
    Top = 127
    Width = 169
    Height = 25
    Caption = 'ObjAuto'#33719#21462'TClass3 '#30340#20449#24687
    TabOrder = 14
    OnClick = Button13Click
  end
end


yunshouhu
关注
  • 1
    点赞
  • 踩
  • 5
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
Delphi开发B/S数据库应用系统：详细教程及最佳实践
m0_57781768的博客
06-17 1014
通过本文的详细介绍，您应该已经了解了如何使用Delphi开发一个功能完备的B/S数据库应用系统。从环境准备、项目规划、数据库设计、Delphi编程到最终部署，我们涵盖了整个开发过程的各个方面。用户管理：支持用户注册、登录和权限管理。图书管理：支持图书信息的录入、修改、删除和查询。借阅管理：支持图书借阅和归还，并记录借阅信息。界面设计：使用Delphi的VCL组件设计直观易用的用户界面。系统部署：配置Web服务器和数据库服务器，发布Web应用程序。
反射 数据类型_Delphi反射机制初探
weixin_36209848的博客
01-12 437
在Java中存在着一种强大的功能就是反射，所以我在考虑Delphi出来这么多年了，难道没有支持反射机制吗？经过翻山越岭的一顿搜索终于找到了反射的身影在Delphi中反射称为RTTI(Run-Time Type Information) 翻译过来的名称是"运行期类型信息"，也就是说可以在运行期获得数据类型或类(class)的信息反射在我们普通程序开发中基本使用不到，但是在我们底层的程序设计中使用特别...
Delphi2010强化的反射
敦格
01-09 2693
Delphi2010强化的反射
ObjAuto.pas单元补完 delphi7反射
quasiceo
12-26 1440
ObjAuto.pas单元补完 大家都知道D2009提供的ObjAuto.pas是一个半成品，只能取方法，不能取参数。但是其实这些功能都是可以实现的我在此做个补完，供Delphi6~Delphi2009使用，同时添加了编译预处理，供各个不同版本的Delphi兼容编译特地做了个D7下的Demo，老版本的Delphi一样可以使用。也可以去CodeGear官方网站下载，链接在此http://cc.co
Delphi反射
diligentcat的专栏
10-26 2348
最近在写一个框架，需要用到反射，与C# java这些原生支持反射的语言不同，delphi对反射的支持相对要弱一些，但也够用了，其实C#的大部分的思想还是从 delphi而来，毕竟都是安德鲁斯的杰作。 这是只谈想法，不谈实现。Delphi7里其实就有对反射的支持了，typInfo,objAuto。基本上可以实现大部分的功能。但对静态方法的支持目前还没有好的解决办法。调用objectInvoke时
运用delphiXE RTTI在运行时动态获取信息及获取某个TComponent类或TObject类的RttiType信息的案例
pulledup的博客
09-03 1097
运用delphiXE RTTI在运行时动态获取信息及获取某个TComponent类或TObject类的RttiType信息的案例 一、理解RTTI 先看看官方文档：http://docwiki.embarcadero.com/RADStudio/Rio/en/Working_with_RTTI 译文如下： 运行时类型信息（RTTI）是一种编程模式，其中可以在运行时获...
RTTI.rar_DELPHI RTTI
最新发布
09-21
本示例源码是针对Delphi RTTI的学习资源，非常适合初学者了解和掌握这一技术。 RTTI在Delphi中主要通过`System.Rtti`单元提供，它包含了处理运行时类型信息的一系列类和接口。其中，`TRttiContext`是核心类，用于...
RTTI.zip_DELPHI RTTI_delphi_rtti
09-14
通过“RTTI.zip”中的示例，你可以更深入地理解Delphi的RTTI机制，并在实际项目中灵活应用这些概念和技术。这个压缩包提供了一个很好的学习平台，帮助开发者掌握如何在Delphi中有效地利用RTTI。
rtti-inspector-combo.zip_DELPHI RTTI_RTTIInspector_inspector
09-20
在Delphi编程环境中，RTTI（Run-Time Type Information）是一种强大的特性，允许程序在运行时获取类型信息。这个“rtti-inspector-combo.zip”压缩包包含了一个利用Delphi RTTI机制创建的“RTTIInspector”工具，它...
Delphi_RTTI.rar_Delphi控件源码_Delphi_
08-11
这不仅加深了我们对RTTI的理解，也为我们提供了实践RTTI技术的参考。 总的来说，Delphi的RTTI系统为开发者提供了一种强大的工具，它使得我们可以更深入地理解和控制程序的行为。结合Delphi的控件源码，我们可以更...
DELPHI RTTI 探索
09-12
RTTI的主要作用在于能够动态地了解对象所属的类及其属性和方法，这对于实现诸如类型检查、反射等功能至关重要。 #### 类（Class）和 VMT 的关系 在Delphi中，类本质上可以被看作是一个指向虚拟方法表（Virtual ...
delphi RTTI 反射技术
aldsot0997的博客
06-11 292
unit Unit_main; interface uses Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls, TypInfo; type TForm_main = class(TForm) Button1...
Delphi 创建建具有“反射调用”功能的类
LocustWei的专栏
06-30 3378
有的时候你会希望自己定义的一个Class在运行期能增加一个property、function，或者一个方法能完全改变他的行为，又或者你希望通过方法名来调用方法（类似JAVA）。这样的效果可以利用AutoObject的后绑定特性来实现。第一步、模拟实现一个AutoObject。其实关键部分是要实现IDispatch的GetIDsOfNames（通过函数（属性）名称获取函数ID），和Inv
delphi 类 线程 反射 泛型 简单理解
aldsot0997的博客
03-15 207
1 unit Unit3; 2 3 interface 4 5 uses 6 Winapi.Windows, Winapi.Messages, System.SysUtils, System.Variants, System.Classes, 7 Vcl.Graphics, Vcl.Controls, Vcl.Forms, Vcl....
Delphi 的RTTI机制浅探(续)
Qi_jianzhou的资料室
04-05 747
Delphi 的RTTI机制浅探(续)savetime2k@yahoo.com  2004.1.22http://savetime.delphibbs.com本文是《Delphi 的RTTI机制浅探》的续篇，上篇地址在：  http://www.delphibbs.com/delphibbs/dispq.asp?lid=2420610本文上篇基本上是 RTTI 入门介绍，续篇介绍了所有 TypIn
Delphi 遍历类中的属性
easyboot的专栏
09-21 5493
unit Unit1; interface uses Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms, Dialogs, StdCtrls,TypInfo; type TForm1 = class(TForm) Button2: TButton; procedure
用DELPHI的RTTI实现数据集的简单对象化
猛禽的编程艺术
01-31 9126
用DELPHI的RTTI实现数据集的简单对象化 [Mental Studio]猛禽[Blog]在《强大的DELPHI RTTI--兼谈需要了解多种开发语言》一文中，我说了一下我用DELPHI的RTTI实现了数据集的简单对象化。本文将详细介绍一下我的实现方法。 首先从一个简单的例子说起：假设有一个ADODataSet控件，连接罗斯文数据库，SQL为： select * from
Delphi6/7/2007获取类型信息
henreash的专栏
12-16 3589
2010年2月10日 Delphi2010强化的反射 第一篇 http://hi.baidu.com/rarnu/blog/item/880c68810337f3d1bc3e1e9e.html 第二篇 http://hi.baidu.com/rarnu/blog/item/29914b4a32faac2a08f7ef7f.html posted @ 2010-02-10
深入理解DELPHI RTTI机制
"DELPHI RTTI 探索" 在Delphi编程环境中，RTTI（运行时类型信息）是一项强大的特性，它允许程序在运行时获取关于对象类型、类信息、属性和方法等元数据。这使得动态编程和反射成为可能，从而增强了代码的灵活性和可...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值