洛谷 P1373 小a和uim之大逃离

题目背景

小a和uim来到雨林中探险。突然一阵北风吹来，一片乌云从北部天边急涌过来，还伴着一道道闪电，一阵阵雷声。刹那间，狂风大作，乌云布满了天空，紧接着豆大的雨点从天空中打落下来，只见前方出现了一个披头散发、青面獠牙的怪物，低沉着声音说：“呵呵，既然你们来到这，只能活下来一个！”。小a和他的小伙伴都惊呆了！

题目描述

瞬间，地面上出现了一个n*m的巨幅矩阵，矩阵的每个格子上有一坨0~k不等量的魔液。怪物各给了小a和uim一个魔瓶，说道，你们可以从矩阵的任一个格子开始，每次向右或向下走一步，从任一个格子结束。开始时小a用魔瓶吸收地面上的魔液，下一步由uim吸收，如此交替下去，并且要求最后一步必须由uim吸收。魔瓶只有k的容量，也就是说，如果装了k+1那么魔瓶会被清空成零，如果装了k+2就只剩下1，依次类推。怪物还说道，最后谁的魔瓶装的魔液多，谁就能活下来。小a和uim感情深厚，情同手足，怎能忍心让小伙伴离自己而去呢？沉默片刻，小a灵机一动，如果他俩的魔瓶中魔液一样多，不就都能活下来了吗？小a和他的小伙伴都笑呆了！

现在他想知道他们都能活下来有多少种方法。

输入输出格式

输入格式：
第一行，三个空格隔开的整数n，m，k

接下来n行，m列，表示矩阵每一个的魔液量。同一行的数字用空格隔开。

输出格式：
一个整数，表示方法数。由于可能很大，输出对1 000 000 007取余后的结果。

输入输出样例

输入样例#1：
2 2 3
1 1
1 1
输出样例#1：
4
说明

【题目来源】

lzn改编

【样例解释】

样例解释：四种方案是：(1,1)->(1,2),(1,1)->(2,1),(1,2)->(2,2),(2,1)->(2,2)。

【数据范围】

对于20%的数据，n,m<=10,k<=2

对于50%的数据，n,m<=100,k<=5

对于100%的数据，n,m<=800,1<=k<=15

分析：这道题目比较恶心，首先，只往下和右走可以想到dp（无后效性）。我们肯定要设一个f[i,j]来表示，跑到f[i,j]的方案数，显然，对于不同的魔液来到这个点，方案数是不同的，又因为最后一定要uim吸收，所以，我们设f[i,j,k,l]为走到(i,j)，两者的差为k，到l走的方案数,l为0为小a走，否则为uim走。
转移方程：

f[i,j,l,1]:=(f[i,j,l,1]+f[i-1,j,(l+a[i,j]+k) mod k,0]+f[i,j-1,(l+a[i,j]+k) mod k,0]) mod modd;
f[i,j,l,0]:=(f[i,j,l,0]+f[i-1,j,(l-a[i,j]+k) mod k,1]+f[i,j-1,(l-a[i,j]+k) mod k,1]) mod modd;

（对于小a走的话，会增大两者差，所以是从k-a[i,j]转移过来，uim走会减小两者差，所以是从k+a[i,j]转移过来）

代码：

const
 maxn=801;
 modd=1000000007;

var
 f:array [0..801,0..801,0..15,0..1] of longint;
 a:array [1..801,1..801] of longint;
 n,m,k,i,j,l,ans:longint;
begin
 readln(n,m,k);
 inc(k); 
 for i:=1 to n do
  for j:=1 to m do
   begin
    read(a[i,j]);
    f[i,j,a[i,j] mod k,0]:=1;
   end;
 for i:=1 to n do
  for j:=1 to m do
   for l:=0 to k-1 do
    begin
     f[i,j,l,1]:=(f[i,j,l,1]+f[i-1,j,(l+a[i,j]+k) mod k,0]+
                 f[i,j-1,(l+a[i,j]+k) mod k,0]) mod modd;
     f[i,j,l,0]:=(f[i,j,l,0]+f[i-1,j,(l-a[i,j]+k) mod k,1]+
                 f[i,j-1,(l-a[i,j]+k) mod k,1]) mod modd;
    end;
 for i:=1 to n do
  for j:=1 to m do
   ans:=(ans+f[i,j,0,1]) mod modd;
 writeln(ans);
end.