SE78图片批量管理

最新推荐文章于 2024-11-06 11:31:34 发布
转载 最新推荐文章于 2024-11-06 11:31:34 发布 · 1.5k 阅读 · 4 ·
CC 4.0 BY-SA版权
原文链接：https://mp.weixin.qq.com/s?__biz=MzU1MDAzMDY3MQ==&mid=2247493539&idx=2&sn=d90ffe135d8359944390443120ae73dd&chksm=fba47b83ccd3f295da4778571057e104c5fcefabffd25e129cf3552a1abb279e9e3febd1f543&scene=126&sessionid=0
文章标签：

#数学建模 #java #开发语言

众所周知，Smartforms打印的图片需要用事务码SE78上传到系统，而SE78不论是上传图片还是查看/下载/传输都是一个一个图进行的，不能批量处理。做一个打印的功能，如果仅仅是一两个图片需要上传也就罢了，如果有几百个图片需要管理，那就是一个头疼的事情了。

本程序的作用就是SE78批量上传/下载/删除/传输/查看。
f9a771ca5771454c0a681fc2c86a3c99.png

652b092bcef635e4083b3822b74de766.png

查看效果：
ec34c5e70f0853858074a46cd764f074.png

传输功能的写到请求：
c202b3cff6c294e16e5190e406f12d5c.png

其他功能请自行摸索。

代码如下：

*&---------------------------------------------------------------------*
*& Report ZSE78
*&---------------------------------------------------------------------*
*& Baitianzhen
*& SE78批量上传/下载/删除/传输/查看
*&---------------------------------------------------------------------*
REPORT zse78 NO STANDARD PAGE HEADING.


TABLES: stxbitmaps,bdsphio3.
DATA: gv_line TYPE i,
      gv_text TYPE char50.
DATA: BEGIN OF gt_upld OCCURS 0,
        name TYPE stxbitmaps-tdname,
        file TYPE rlgrap-filename,
        desc TYPE bapisignat-prop_value,
      END OF gt_upld.
DATA: gt_maps TYPE TABLE OF stxbitmaps WITH HEADER LINE.


SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE btxt1.
PARAMETERS: p_upld RADIOBUTTON GROUP typ USER-COMMAND sele DEFAULT 'X',
            p_down RADIOBUTTON GROUP typ,
            p_dele RADIOBUTTON GROUP typ,
            p_tran RADIOBUTTON GROUP typ,
            p_view RADIOBUTTON GROUP typ.
SELECTION-SCREEN END OF BLOCK b1.


SELECTION-SCREEN BEGIN OF BLOCK b2 WITH FRAME TITLE btxt2.
PARAMETERS: p_type TYPE stxbitmaps-tdbtype MODIF ID a DEFAULT 'BCOL',
            p_rsdt AS CHECKBOX MODIF ID a,
            p_auto AS CHECKBOX MODIF ID a DEFAULT 'X',
            p_comp AS CHECKBOX MODIF ID a DEFAULT 'X'.
SELECT-OPTIONS: s_name FOR gt_maps-tdname MODIF ID b,
                s_type FOR gt_maps-tdbtype MODIF ID b.
SELECTION-SCREEN END OF BLOCK b2.


AT SELECTION-SCREEN OUTPUT.
  btxt1 = '功能选择'.
  btxt2 = '数据'.
  %_p_upld_%_app_%-text = '上传'.
  %_p_down_%_app_%-text = '下载'.
  %_p_dele_%_app_%-text = '删除'.
  %_p_tran_%_app_%-text = '传输'.
  %_p_view_%_app_%-text = '查看'.
  %_p_type_%_app_%-text = '彩色/黑白'.
  %_p_rsdt_%_app_%-text = '驻留在打印机内存中'.
  %_p_auto_%_app_%-text = '自动保留高度'.
  %_p_comp_%_app_%-text = '压缩'.
  %_s_name_%_app_%-text = '名称'.
  %_s_type_%_app_%-text = '彩色/黑白'.


  LOOP AT SCREEN.
    IF p_upld = 'X'.
      IF screen-group1 CA 'B'.
        screen-active = '0'.
      ENDIF.
    ELSE.
      IF screen-group1 CA 'A'.
        screen-active = '0'.
      ENDIF.
    ENDIF.
    MODIFY SCREEN.
  ENDLOOP.


START-OF-SELECTION.
  CASE 'X'.
    WHEN p_upld.
      PERFORM upld.
    WHEN OTHERS.
      SELECT * INTO TABLE gt_maps
        FROM stxbitmaps
        WHERE tdname  IN s_name  AND
              tdid    EQ 'BMAP'  AND
              tdbtype IN s_type.
      IF sy-subrc NE 0.
        MESSAGE s000(oo) WITH '未找到数据'.
      ELSE.
        CASE 'X'.
          WHEN p_down.
            PERFORM down.
          WHEN p_dele.
            PERFORM dele.
          WHEN p_tran.
            PERFORM tran.
          WHEN p_view.
            PERFORM view.
        ENDCASE.
      ENDIF.
  ENDCASE.


*&---------------------------------------------------------------------*
*& 上传 如果已经存在,则覆盖
*&---------------------------------------------------------------------*
FORM upld.
  DATA: lv_docid TYPE stxbitmaps-docid.
  DATA: lv_exnam TYPE char255.
  DATA: lv_resol TYPE stxbitmaps-resolution.
  DATA: lt_files TYPE TABLE OF file_table.
  DATA: lv_rcode TYPE i.
  DATA: lv_file  TYPE string.


  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    EXPORTING
      window_title            = '请选择导入文件'
      default_filename        = '*.txt'
      multiselection          = ''
    CHANGING
      file_table              = lt_files
      rc                      = lv_rcode
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      not_supported_by_gui    = 4
      OTHERS                  = 5.
  IF sy-subrc = 0 AND lt_files IS NOT INITIAL.
    READ TABLE lt_files INTO lv_file INDEX 1.
    CALL FUNCTION 'GUI_UPLOAD'
      EXPORTING
        filename            = lv_file
        filetype            = 'ASC'
        has_field_separator = 'X'
      TABLES
        data_tab            = gt_upld
      EXCEPTIONS
        OTHERS              = 1.
    IF sy-subrc = 1.
      MESSAGE e000(oo) WITH '文件打开错误'.
    ENDIF.
  ENDIF.


  gv_line = lines( gt_upld ).
  LOOP AT gt_upld.
    TRANSLATE gt_upld-name TO UPPER CASE.
    MESSAGE s000(oo) WITH sy-tabix '/' gv_line gt_upld-name INTO gv_text.
    CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
      EXPORTING
        percentage = 0
        text       = gv_text.


    lv_exnam = gt_upld-file.
    WHILE lv_exnam CA '.'.
      SHIFT lv_exnam.
    ENDWHILE.
    TRANSLATE lv_exnam TO UPPER CASE.


    WRITE / gt_upld-name.
    CLEAR: lv_docid.
    PERFORM import_bitmap_bds IN PROGRAM saplstxbitmaps
                              USING gt_upld-file
                                    gt_upld-name
                                    'GRAPHICS'
                                    'BMAP'
                                    p_type
                                    lv_exnam
                                    gt_upld-desc "描述
                                    p_rsdt "驻留打印机内存
                                    p_auto "自动保留高度
                                    p_comp "压缩
                              CHANGING lv_docid
                                       lv_resol.
    WRITE lv_docid.
  ENDLOOP.
ENDFORM.                    "upld


*&---------------------------------------------------------------------*
*& 下载 弹出保存路径对话框
*&---------------------------------------------------------------------*
FORM down.
  DATA: lv_blen TYPE i,
        gv_line TYPE i,
        lv_path TYPE string,
        lv_file TYPE string,
        lv_xstr TYPE xstring,
        lt_btab TYPE TABLE OF x255.


  CALL METHOD cl_gui_frontend_services=>directory_browse
    EXPORTING
      window_title         = '下载到目录:'
    CHANGING
      selected_folder      = lv_path
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      not_supported_by_gui = 3
      OTHERS               = 4.
  CHECK sy-subrc = 0.


  gv_line = lines( gt_maps ).
  LOOP AT gt_maps.
    MESSAGE s000(oo) WITH sy-tabix '/' gv_line gt_maps-tdname INTO gv_text.
    CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
      EXPORTING
        percentage = 0
        text       = gv_text.


    WRITE / gt_maps-tdname.
    CALL METHOD cl_ssf_xsf_utilities=>get_bds_graphic_as_bmp
      EXPORTING
        p_object       = 'GRAPHICS'
        p_name         = gt_maps-tdname
        p_id           = gt_maps-tdid
        p_btype        = gt_maps-tdbtype
      RECEIVING
        p_bmp          = lv_xstr
      EXCEPTIONS
        not_found      = 1
        internal_error = 2
        OTHERS         = 3.
    IF sy-subrc = 0.
      CALL FUNCTION 'SCMS_XSTRING_TO_BINARY'
        EXPORTING
          buffer        = lv_xstr
        IMPORTING
          output_length = lv_blen
        TABLES
          binary_tab    = lt_btab.


      IF lv_xstr(2) = '424D'."BMP
        CONCATENATE lv_path '\'  gt_maps-tdname '_'
                    gt_maps-tdbtype '.bmp' INTO lv_file.
      ELSE.
        CONCATENATE lv_path '\'  gt_maps-tdname '_'
                    gt_maps-tdbtype '.tif' INTO lv_file.
      ENDIF.


      CALL FUNCTION 'GUI_DOWNLOAD'
        EXPORTING
          filename     = lv_file
          filetype     = 'BIN'
          bin_filesize = lv_blen
        TABLES
          data_tab     = lt_btab
        EXCEPTIONS
          OTHERS       = 1.
      IF sy-subrc = 0.
        WRITE lv_file.
      ELSE.
        WRITE '下载失败'.
      ENDIF.
    ELSE.
      WRITE '获取文件失败'.
    ENDIF.
  ENDLOOP.
ENDFORM.                    "down


*&---------------------------------------------------------------------*
*& 删除
*&---------------------------------------------------------------------*
FORM dele.
  DATA lv_mess TYPE char100.


  LOOP AT gt_maps.
    WRITE: / gt_maps-tdname,gt_maps-tdbtype.
    CALL FUNCTION 'SAPSCRIPT_DELETE_GRAPHIC_BDS'
      EXPORTING
        i_object      = 'GRAPHICS'
        i_name        = gt_maps-tdname
        i_id          = gt_maps-tdid
        i_btype       = gt_maps-tdbtype
        dialog        = ''
      EXCEPTIONS
        delete_failed = 1
        not_found     = 2
        canceled      = 3
        OTHERS        = 4.
    CASE sy-subrc.
      WHEN 0.
        WRITE '成功删除'.
      WHEN OTHERS.
        MESSAGE ID sy-msgid TYPE 'S' NUMBER sy-msgno
                WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4 INTO lv_mess.
        WRITE lv_mess.
    ENDCASE.
  ENDLOOP.
ENDFORM.                    "dele


*&---------------------------------------------------------------------*
*& 传输 弹出选择请求号的对话框 工作台请求
*&---------------------------------------------------------------------*
FORM tran.
  DATA: lv_task TYPE e070-trkorr,
        lt_071k TYPE TABLE OF e071k WITH HEADER LINE,
        lt_e071 TYPE TABLE OF e071  WITH HEADER LINE.


  lt_e071-objfunc  = 'K'.
  lt_e071-pgmid    = 'R3TR'.
  lt_e071-object   = 'TABU'.
  lt_e071-obj_name = 'STXBITMAPS'.
  APPEND lt_e071.


  LOOP AT gt_maps.
    lt_071k-pgmid      = 'R3TR'.
    lt_071k-mastertype = 'TABU'.
    lt_071k-object     = 'TABU'.
    lt_071k-mastername = 'STXBITMAPS'.
    lt_071k-objname    = 'STXBITMAPS'.
    CONCATENATE gt_maps-tdobject
                gt_maps-tdname
                gt_maps-tdid
                gt_maps-tdbtype
                INTO lt_071k-tabkey RESPECTING BLANKS.
    APPEND lt_071k.
  ENDLOOP.


  CALL FUNCTION 'TR_ORDER_CHOICE_CORRECTION'
    EXPORTING
      iv_category = 'SYST'
    IMPORTING
      ev_task     = lv_task
    EXCEPTIONS
      OTHERS      = 3.
  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.


  CALL FUNCTION 'TR_APPEND_TO_COMM_OBJS_KEYS'
    EXPORTING
      wi_simulation         = ''
      wi_suppress_key_check = ''
      wi_trkorr             = lv_task
    TABLES
      wt_e071               = lt_e071
      wt_e071k              = lt_071k
    EXCEPTIONS
      OTHERS                = 68.
  IF sy-subrc NE 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ELSE.
    MESSAGE s000(oo) WITH '成功'.
  ENDIF.
ENDFORM.                    "tran


*&---------------------------------------------------------------------*
*& 使用HTML查看多个图片
*&---------------------------------------------------------------------*
FORM view.
  DATA: lv_pkey  TYPE char80,
        lv_xstr TYPE xstring,
        lv_html TYPE string.
  DATA: lt_data TYPE cl_abap_browser=>load_tab WITH HEADER LINE.
  DATA: lr_stru TYPE REF TO data,
        lr_type TYPE REF TO cl_abap_structdescr,
        lt_comp TYPE abap_component_tab WITH HEADER LINE.
  FIELD-SYMBOLS: <ls_stru> TYPE any,
                 <lt_btab> TYPE STANDARD TABLE.




  LOOP AT gt_maps.
    lt_comp-name = gt_maps-tdname && gt_maps-tdbtype.
    lt_comp-type ?= cl_abap_datadescr=>describe_by_name( 'SWXMLCONT' ).
    APPEND lt_comp.
  ENDLOOP.
  lr_type  = cl_abap_structdescr=>create( lt_comp[] ).
  CREATE DATA lr_stru TYPE HANDLE lr_type.
  ASSIGN lr_stru->* TO <ls_stru>.


  lv_html = `<html><meta http-equiv="Content-Type" content="text/html;charset=utf-8"/>` &&
            `<table border=1 cellpadding=2 `  &&
            `style='border-collapse:collapse;font-size:10.5pt'>` &&
            `<tbody><TR style= 'background:#f4f4f4'></TR>` .


  gv_line = lines( gt_maps ).
  LOOP AT gt_maps.
    MESSAGE s000(oo) WITH sy-tabix '/' gv_line gt_maps-tdname INTO gv_text.
    CALL FUNCTION 'SAPGUI_PROGRESS_INDICATOR'
      EXPORTING
        percentage = 0
        text       = gv_text.


    CALL METHOD cl_ssf_xsf_utilities=>get_bds_graphic_as_bmp
      EXPORTING
        p_object       = 'GRAPHICS'
        p_name         = gt_maps-tdname
        p_id           = gt_maps-tdid
        p_btype        = gt_maps-tdbtype
      RECEIVING
        p_bmp          = lv_xstr
      EXCEPTIONS
        not_found      = 1
        internal_error = 2
        OTHERS         = 3.
    IF sy-subrc = 0.
      lv_pkey = gt_maps-tdname && gt_maps-tdbtype.
      ASSIGN COMPONENT lv_pkey OF STRUCTURE <ls_stru> TO <lt_btab>.
      CALL FUNCTION 'SCMS_XSTRING_TO_BINARY'
        EXPORTING
          buffer     = lv_xstr
        TABLES
          binary_tab = <lt_btab>.


      IF lv_xstr(2) = '424D'."BMP
        lt_data-name = lv_pkey && '.bmp'.
      ELSE.
        lt_data-name = lv_pkey && '.tif'.
      ENDIF.
      lt_data-type = 'image'.
      GET REFERENCE OF <lt_btab> INTO lt_data-dref.
      APPEND lt_data.


      SELECT SINGLE * FROM bdsphio3
        WHERE loio_id = gt_maps-docid+10.


      lv_html = lv_html && `<TR>` &&
                `<td style="BORDER-TOP: 1px solid; BORDER-RIGHT: 1px solid;` &&
                `BORDER-BOTTOM: 1px solid; BORDER-LEFT: 1px solid" nowrap>` &&
                gt_maps-tdname && `</td>` &&
                `<td style="BORDER-TOP: 1px solid; BORDER-RIGHT: 1px solid;` &&
                `BORDER-BOTTOM: 1px solid; BORDER-LEFT: 1px solid" nowrap>` &&
                bdsphio3-descript && `</td>` &&
                `<td style="BORDER-TOP: 1px solid; BORDER-RIGHT: 1px solid;` &&
                `BORDER-BOTTOM: 1px solid; BORDER-LEFT: 1px solid" nowrap>` &&
                `<img src="` && lt_data-name && `"></td> </tr>`.
    ENDIF.
  ENDLOOP.
  lv_html = lv_html && `</tbody></table> <br/> </html>`.


  cl_abap_browser=>show_html( title = '表格图形批量查看'
                              html_string = lv_html
                              data_table  = lt_data[] ).
ENDFORM.                    "view

8654a36b34667d1f71443f9bed53a081.jpeg

SAP_森林木
关注
SAP 系统图片修改以及 ABAP屏幕图片（大小调整）自适应设置
SAP自学之路
01-08 3860
一 、SAP系统图片 1.1上传图片 TCODE: SMW0 上传本地图片到SAP系统 1.2 设置为登录首页的背景。 TCODE: SM30 打开表视图维护功能。 输入表名 SSM_CUST，这是 SAP 提供的修改登录后主界面的设置表。然后点击“Maintain（维护）”，这时会出现一个提示，说明它是个...
sap事务代码_上传图片进SAP（事务代码：SE78）
weixin_39519072的博客
12-08 3266
SE78上传图片进SAP在这里我们讲讲如何把图片传进SAP，有时候公司需要在某些打印的报表上显示公司的Logo等等。1，输入事物代码SE782，选择你需要传到的位置，比如我需要传到“标准文本”下面的“ST”中3，双击“ST”，在右边出现“Name”和“语言”的对话框4，选择导入按钮，快捷键F55，输入文件的路径名称和文本名和文本语言----------------------------...
SAP中将URL的图片转化为BMP格式图片并上传se78,通过smartforms直接调用
最新发布
fuyangshida的博客
11-06 1938
'BCOL'"'BMON'"p_btype "颜色模式 BMON黑白 BCOL彩色。''"p_resident "依照打印请求驻留在打印机内存中 X 驻留。'BMAP'"p_id "ID 固定为 BMAP。'BMP'"p_format "BMP 格式。'X'"p_autoheight "自动高度。P_NAME "p_name "名字。
屏幕上显示 SE78 图片
liangziyisheng的专栏
04-26 3915
以下实例在屏幕9100上显示SE78上传的图片   屏幕9100里面创建一个容器控件，逻辑流： PROCESS BEFORE OUTPUT.  MODULE STATUS_9100. * PROCESS AFTER INPUT.  MODULE exit_prog.  MODULE USER_COMMAND_9100.     主程序代码： DATA: ok_code TY
SAP 下载SE78上传的图片
IamRunjiang的博客
02-13 820
SAP 下载SE78上传的图片。
SAP各种图片应用-图片上传到SAP系统
凌薇
08-25 5704
图片上传1. SMW0 SM30 修改SAP登录后的背景图片1.1 SMW0 图片格式类型-维护：1.2 SMW0 添加图片1.3 SM30 修改系统开始界面的背景图片：2. OAER-ALV报表LOGO图片上传3. SE78-SMARTFORM中打印图片 1. SMW0 SM30 修改SAP登录后的背景图片 1.1 SMW0 图片格式类型-维护： 将图片上传到SAP，必须保证SAP支持该类型文...
SE防伪和代理查询系统v1.3: 批量生成、产品管理及音乐追溯功能
4. CMS框架完整升级：CMS（Content Management System，内容管理系统）是用于管理网站内容的系统，其框架的完整升级意味着该系统已经升级了文章、图片、视频、音乐、下载等基本内容管理模块，为用户提供了一个更加...
网尽图片管理系统V5.1修正版发布，支持无限制批量上传
根据描述内容，“解决了图片批量上传（上传的图片大小没有限制了）”这一改进具有重大意义。在早期版本或其他同类系统中，图片上传往往受限于服务器配置或程序逻辑，存在单个文件大小上限（例如2MB或5MB），这极大...
图片采集-输入关键词批量收集图片免费
qq_787143156的博客
10-23 724
图片采集，有一个免费的图片采集软件就可以寻找网页上的各种图片，每个人都可以找到各种高清图源。支持任意格式的图片采集下载，只需要输入关键词或批量导入链接即可采集下载图片。不仅可以拥有大量的图片源还支持批量图片压缩/放大/添加水印等等处理/详细如图这款免费图片采集工具有以下功能特点：1、支持不同网页的图片采集/支持导入网址文件采集图片/关键词图片批量下载2、支持自定义图片存储目录或上传到网站，并按照网址特征自动为图片创建分类目录3、支持下载失败的图片一键再次采集4、支持下载图片去重5、支持采集过程中查看已下载的
批量改文件名工具
09-19
综上所述，批量改文件名工具无疑成为我们在IT工作和日常文件管理中的得力助手。特别适合那些需要处理大量文件的专业人士，它极大地简化了文件管理流程，让批量修改文件名和扩展名变得简单快捷。而且，对于电脑操作不...
SAP-下载SE78图片内容
04-12
通过创建附件中代码实现下载SAP系统中SE78事务中的图片内容
SE防伪和代理查询系统v1.3.zip_4 3 2 1_depthbqx_socialvrs_追溯_音乐管理系统
09-20
1 防伪码批量生成优化算法，避免重复生成 2 防伪码自动关联产品和代理商 3 增加的产品管理模块 4 CMS框架完整升级,默认包含文章、图片、视频、音乐、下载模块 5 后台管理员默认首页优化，调用各个模块统计数据 6 ...
SAP 上传图片 se78
weixin_45420932的博客
02-08 555
只能传bmp格式图片，且对bmp图片的色位有限制。
SAP 员工照片批量上传下载
weixin_42396921的博客
03-17 1128
涉及表TOAHRHR管理级的容器表 *根据员工号判断文件是否存在 CALL FUNCTION 'HR_IMAGE_EXISTS' EXPORTING p_pernr = L_PERNR P_TCLAS = 'A' * P_BEGDA = '18000101' * P_ENDDA ..
SAP smartform和ALV如何使用图片 & 如何下载SE78上传的图片到本地
qq_55488207的博客
11-21 2927
2. 在SmartForms设计时，在想要加入LOGO的地方，点击右键：创建->图形，然后在名称：ZERPLOGO，即可才打印的Form中打印出公司的LOGO或其它图形、图片。在使用Scripfrom或SmartForms工具开发凭证单据打印的时候，经常会遇到需要打印一些相关的图片到单据上的需求，比如：公司的LOGO，公司的印章、领导签名图片等。上传的图片一定要是BMP或DIB格式，选择上传图片的路径，填写名字和描述，然后一直执行下去就可以了，执行成功后显示如下。1 .执行SE78事务码，按如下图操作。
SMARTFORMS SE78 Colour graphic or logo has a grey background when printed
SAP小趴菜
03-28 490
When you upload a colour graphic into transaction SE78 and include it in your form, the background of the image appears grey or shaded. Usually this is not noticeable on the screen, but is noticeable on the printout.This issue can occur when you use a tru
SE78 PIC UPLOAD AND DOWNLOAD
SAP ERP/CRM
03-13 1万+
http://www.sapfans.com/forums/viewtopic.php?p=143772 SE78 - Downloading an imported graphic.   *&---------------------------------------------------------------------* *& Report  Z_EXPORT_GRAPHIC_
se78 上传图片（logo使用）/SWM0上传文件
热门推荐
fengyeyu090813的专栏
01-11 1万+
利用SmartForms开发的FORM凭证打印，可以将公司的LOGO一并打印，改善外观。 1、事物码SE78. 2、点开Graphics General Granpics下的子菜单，双击其下的子菜单BMAP Bitmapimages。 3、点击菜单栏上的“图形”项，选择“导入”。在文件名选择项上选择本地需要上传的图片路径。【注意：上传的图片一定要是BMP或DIB格式的单色位图或16位色图
se78 上传图片（logo使用）
xiang37的专栏
11-11 1113
利用SmartForms开发的FORM凭证打印，可以将公司的LOGO一并打印，改善外观。 1、事物码SE78. 2、点开Graphics General Granpics下的子菜单，双击其下的子菜单BMAP Bitmap images。 3、点击菜单栏上的“图形”项，选择“导入”。在文件名选择项上选择本地需要上传的图片路径。【注意：上传的图片一定要是BMP或DIB格式的单色位图或16位色...
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值