10.7 剪草 2394

题目

有N棵小草，编号0至N-1。奶牛Bessie不喜欢小草，所以Bessie要用剪刀剪草，目标是使得这N棵小草的高度总和不超过H。在第0时刻，第i棵小草的高度是h[i]，接下来的每个整数时刻，会依次发生如下三个步骤：

（1）每棵小草都长高了，第i棵小草长高的高度是grow[i]。

（2）Bessie选择其中一棵小草并把它剪平，这棵小草高度变为0。注意：这棵小草并没有死掉，它下一秒还会生长的。

（3）Bessie计算一下这N棵小草的高度总和，如果不超过H，则完成任务，一切结束， 否则轮到下一时刻。

你的任务是计算：最早是第几时刻，奶牛Bessie能完成它的任务？如果第0时刻就可以完成就输出0，如果永远不可能完成，输出-1，否则输出一个最早的完成时刻。

1 ≤ N ≤ 50，0 ≤ H ≤ 1000000。h[i]。0 ≤ h[i] ≤ 100000

grow[i]。1 ≤ grow[i] ≤ 100000。

题解

动态规划是正解，不过不算纯正的动归，有贪心的成分
因为长得快的草如果先剪，那很快就会长高，如果先剪长得慢的草，那高度就增长慢一些，所以应先割长得慢的草。如果剪了n次还没有达到目标，那么永远也不会达到目标。
所以先排序，然后动归

f[j,k]表示前j棵草剪了k次的总最小高度
f[j,0]要预处理
对于每棵草和每次剪草，可以考虑剪这棵草和不剪这棵草。剪则总高度=f[j-1,k-1]+g[i]*(i-k),不剪则=f[j-1,k]+a[i]+g[i]*i
还有最后别忘了输出答案或-1

注意！比赛时如果中途halt了，就要在halt之前打close(input);close(output);不然评测机会显示答案错误

代码

var
  n,m,i,j,k:longint;
  f:array[0..50,0..50]of longint;
  h,g:array[0..50]of longint;

function min(a,b:longint):longint;
begin
  if a<b then exit(a) else exit(b);
end;

procedure sort;
var
  i,j,t:longint;
begin
  for i:=1 to n do
    for j:=i+1 to n do
      if g[i]>g[j] then
        begin
          t:=g[i];g[i]:=g[j];g[j]:=t;
          t:=h[i];h[i]:=h[j];h[j]:=t;
        end;
end;

begin
  readln(n,m);
  for i:=1 to n do
    begin
      read(h[i]);
      k:=k+h[i];
    end;
  if k<=m then begin writeln(0);halt;end;
  readln;
  for i:=1 to n do
    read(g[i]);
  sort;
  for i:=1 to n do
    begin
      for j:=1 to n do
        begin
          f[j,0]:=f[j-1,0]+h[j]+g[j]*i;
          for k:=1 to i do
            f[j,k]:=maxlongint div 100;
        end;
      for j:=1 to n do
        for k:=1 to i do
          f[j,k]:=min(f[j-1,k]+g[j]*i+h[j],f[j-1,k-1]+g[j]*(i-k));
      if f[n,i]<=m then
        begin
          writeln(i);
          halt;
        end;
    end;
  writeln(-1);
end.