模拟字符串处理函数 stuff 处理 Ntext 字段

原创 2004年07月16日 09:27:00

if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_stuff]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_stuff]
GO

/*--Ntext字段处理

 模拟字符串处理函数 stuff
 完成表中 ntext 字段的 stuff 处理
 注意,表中需要有列名为:id 的主键(或标识字段),数据类型为int
 如果没有这个主键字段,或者是其他类型,则对应的需要修改存储过程

--邹建 2004.07(引用请保留此信息)--*/

/*--调用示例

 --测试数据
 create table tb(id int identity(1,1),content ntext)
 insert tb select 'a;sd'
 union all select 'a;sdfkjas2qasdfdfsg45yhjhdfg45645a'
 
 --调用存储过程,将第8~9的字符替换成'中国'
 exec p_stuff 'tb','content',8,2,'中国',''
 select * from tb
 
 drop table tb
--*/

create proc p_stuff
@tbname sysname, --要处理的表名
@fdname sysname, --text/ntext字段名
@start int=null, --开始位置,NULL表示追加数据
@length int=null, --替换的长度
@str nvarchar(4000),--要插入的字符串
@where nvarchar(1000)=''--要处理的记录的条件
as
if @str is null return
declare @s nvarchar(4000)
set @s='
declare @id int,@ptr varbinary(16),@start1 int

declare tb cursor local for
select id,start=datalength(['+@fdname+'])/2
from ['+@tbname+']
'+case isnull(@where,'') when '' then ''
 else ' where '+@where end+'

open tb
fetch tb into @id,@start1
while @@fetch_status=0
begin
 select @ptr=textptr(content)
 from ['+@tbname+']
 where id=@id

 if @start is null or @start1<@start
  updatetext ['+@tbname+'].['+@fdname+'] @ptr null null @str
 else
 begin
  set @start1=@start-1
  updatetext ['+@tbname+'].['+@fdname+'] @ptr @start1 @length @str
 end
 fetch tb into @id,@start1
end
close tb
deallocate tb
'
exec sp_executesql @s
 ,N'@start int,@length int,@str nvarchar(4000)'
 ,@start,@length,@str
go

相关文章推荐

模拟库中的字符串处理函数

1.模拟实现strcpy函数的功能#define _CRT_SECURE_NO_WARNINGS 1 #include #include #includechar *my_strcpy(char *d...

SQL Server字符串处理函数大全

  • 2014年07月09日 18:02
  • 37KB
  • 下载

常用字符串处理函数

  • 2013年08月29日 09:22
  • 50KB
  • 下载

SQL 7 计算字段 - 3. 数据处理函数

  像普通编程语言一样,SQL也支持使用函数处理数据,函数使用若干字段名或者常量值作为参数;参数的数量上不固定的,有函数的参数为空,甚至有的函数的参数个数可变里几乎所有函数都有返回值,返回值即为函数的...

字符串处理函数(9KB)

  • 2006年02月23日 09:05
  • 8KB
  • 下载

SQL学习总结(一)【计算字段&数据处理函数】

1.创建计算字段   计算字段并不实际存在于数据库中,计算字段是运行时在select语句内创建的。有拼接字段、对字段进行算术运算等方式创建计算字段。 select vend_name+'('+vend...

C字符串处理函数的源代码

  • 2012年10月14日 15:08
  • 23KB
  • 下载

【MySQL】SELECT语句 计算字段 数据处理函数 汇总函数 分组数据 子查询

第十章  创建计算字段     计算字段         存储在表中的数据一般不是应用程序所需要的格式。我们需要直接从数据库中检索出转换、计算或格式化的数据。而不只是检索出数据,然后再到应用程序或...
内容举报
返回顶部
收藏助手
不良信息举报
您举报文章:模拟字符串处理函数 stuff 处理 Ntext 字段
举报原因:
原因补充:

(最多只允许输入30个字)