KDB+ 进程通信与Callbacks

KDB+ Callbacks

KDB+Q 的进程通信方便之极，本节主要讲IPC通信，有同步异步之分。同步是阻塞等待，异步是回调 。

相关内容可以参考官网： https://code.kx.com/v2/kb/ipc/

简单案例1：

在一个终端开启

q -p 5000

在一个终端开启q 进入

h:hopen `::5000                 //h是一个大于0的数字
h "a:1" 

这样就在5000端口开启的那个进程存了一个a为1的变量，并且是同步传过去的。
也可以

h ({`a set x};1)　

这种是函数加参数的方式。第一种是字符串ｑ语言的方式。

q)h ({`a set x;`b set y};1;2)

这种是传两个参数的形式。
也可以异步执行，也就是把h这个整数取个相反数

(neg h) "a:1"；

简单案例２：同步与异步
刚刚我们传入了一个ａ:１在5000进程。
现在我们从远程进程读出来：

q)h "a"

当即返回1

如果我们是异步读取就返回为空：

(neg h) "a"

因为异步是当时返回为空的。。。
那么我们要怎么异步拿到数据呢？

(neg h) "(.z.w )a";h(::) 

.z.w 的意思是那边的进程把a同步发过来的意思。
h(:? 表示这边这个进程接收；
如果在q 交互程序里这两句话必须写在一行，但是在q代码文件里可以写在不同的位置，如第一行发送一个异步查询请求，第100行才接收也是可以的。

先消化上面的知识才可以往下看各种高级的callbacks：

下面的例子是官网例子 https://code.kx.com/v2/kb/callbacks/
我只是讲解一遍。

例子1：

开启两个q进程，进程5000 和进程5001
定义下面两个函数在进程5000（以5000位端口的q进程）

q)echo:{0N!x;}
q)add:{echo x+y} 

定义下面这个函数在5001端口：

q)proc:{echo x; h:.z.w; (neg h) (y; 43)}
q)echo:{0N!x;}

在5000进程输入：

q)h:hopen `::5001
q)(neg h) (`proc; 42; `echo)
  ...
q)hclose h

q)(neg h) (proc; 42;echo) 的意思是：
调用5001的proc函数，这个函数需要两个参数，42 作为第一个参数和 函数echo作为第二个参数传过去。
然后我们看proc这个函数做了什么事：
第一步 调用自己进程的echo函数打印x，这里的x就是从5000端口传来的第一个参数42.
第二步 设置h为.z.w: 这里的h 是从5001 到 5000 端口的连接。然后后面一句是向5000端口异步的发送请求，请求的内容是调用5000端口的echo函数，同时传入参数43.
这里的y就是我们从5000传过去的第二个参数。
所以最终看到的是 5001端口先打印42，5000端口打印43.

以上内容看起来有些绕，但十分关键，例子1理解好了，后面就相当容易。

例子2：

定义下面两个函数在5001端口的q进程：

q)add3:{x+y+z}
q)proc3:{ echo r:add3 . x; (neg .z.w) (y; r)}

在5000端口输入：

q)(neg h) (`proc3; 1 2 3; `echo)

这句话的意思是：
调用5001端口的proc3函数，同时传入第一个参数（1；2；3），第二个参数本地5000端口的echo函数
下面看5001端口做了啥事：
第一步：将5000端口传来的1 2 3加起来赋值变量r，同时打印r。
（. 符号是把数组转为函数对应的参数然后执行函数，以后有详细章节讲解.符号）
第二步：往5000端口异步调用从5000传来的echo函数，函数的参数就是刚计算的r
所以最终5000程序打印6 ，5001程序打印6

例子3：

加入以下代码到5001进程：

q)add3:{x+y+z}
q)marshal:{(neg .z.w) (z; (value x) . y)}

在5000进程输入：

q)(neg h) (`marshal; `add3; 1 2 3; `echo)

这句话的意思是：调用远程5001端口的marshal函数，并且传入三个参数:参数1是add3 引用，当然本地没有定义这个函数，只是一个symbol类型的，到了那边5001就可以当做函数名调用，所以传的知识一个函数名， 第二个参数是1 2 3 数组，第三个参数是本地的echo函数，当然也可以当做一个symbol。

远程5001收到后做了下面几件事：
立刻向5000端口调用 z ，z就是第三个参数，也就是我们传的echo函数。 z函数的参数是 （value x） . y
value x就是 将函数名转为函数本身执行(参看我写的函数和右解析那个文章)：
所以 add3 我们 可以直接 (value `add)[1;2;3]
所以5000端口打印6 。5001 端口不打印。

例子4：5000进程输入下面：

(neg h) ({(neg .z.w) (z; x*y)}; 6; 7; `echo)

把所有的定义缩在一句话。。。如果你看懂了了这篇课题就可以自己理解了。