LC3简易版四子棋

最新推荐文章于 2024-08-04 13:44:35 发布
最新推荐文章于 2024-08-04 13:44:35 发布
阅读量715 收藏 25
点赞数 19
分类专栏： 作业 文章标签： 汇编
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/ChainPray/article/details/139147256
版权

详情移步blog

题目要求

四子棋是一款普遍流行的简易型桌面游戏，据说，虎克船长曾因专注于此游戏而长期隐身在住所，当船员们发现船长的这一专长之后，他们称这个游戏为“船长的情妇”。

       四子棋是个双人游戏，两人轮流下棋，棋盘由行和列组成的网格，每个选手每次下一个子直到两人中有一人的棋子连成一条水平线、垂直线或者是对角线。

       本实验需要在LC-3中实现简易版四子棋的游戏，两位选手通过键盘和输出窗口轮流交互操作，棋盘由6 X 6的网格组成。

  •        两位选手依次轮流落子；
  •        选手不能悔棋；
  •        有子的地方不能继续落子；
  •        直到有一方的四个棋子能够连成一条水平线、垂直线或者是对角线；
  •        如果棋盘已满，无人获胜，则平局。

       游戏最初时应该打印空的棋盘，可以用ASCII码"-" （即ASCII 码 x002D）来表示该处为空，"O"(ASCII 码 x004F)表示第一位选手的棋子，"X" (ASCII 码 x0058)来表示第二位选手的棋子，为了让棋盘更易于观察，在各列间加一个空格，第6列之后不要添加。

选手一始终先下第一步棋，然后两者轮流落子，在每次落子之后，应该打印该选手的信息，提示他落子，以选手一为例，应该打印信息如下：

Player 1, choose a column:

       为了明确选手的落子的位置，该选手应该输入数字1-6，然后回车，数字1-6指示在落子所在的列，从左到右，无需输入行号，程序应默认从行号6到行号1递减的顺序填入该棋子，若前后输入的列号相同，则行号减一。例如，如果选手第一次在左起第二列落子，应该输入2，然后回车，则该棋子落在行6列2处，当后面输入的列号再次为2时，则将棋子落子行5列2处，以此类推，详情见后续示例输出。程序应该确保选手输入的数字对应正确的列的范围，如果输入不合理，应该输出一条错误信息，提示该选手继续输入，例如，如果对于选手一：

    Player 1, choose a column: D

    Invalid move. Try again.

    Player 1, choose a column: 7

    Invalid move. Try again.

    Player 1, choose a column:

       程序应该一直提示该选手，知道输入正确的数字，当用户输入完成，程序应通过显示回馈给选手，然后通过换行符(ASCII 码 x000A)换行。

       当选手输入成功后，程序应打印更新后的棋盘，并检查是否有人获胜，如果没人获胜，则轮到下一位输入。

       当其中一位获胜或平局时，游戏结束，程序显示最后的棋盘情况并终止（Halt）。例如，如果选手二有四子相连，应该输出：

Player 2 Wins.

如果平局，程序应该输出：

Tie Game.

示例输出

- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
Player 1, choose a column: 1
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
O - - - - - 
Player 2, choose a column: 2
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
O X - - - - 
Player 1, choose a column: 2
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
- O - - - - 
O X - - - - 
Player 2, choose a column: 3
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
- O - - - - 
O X X - - - 
Player 1, choose a column: 3
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
- O O - - - 
O X X - - - 
Player 2, choose a column: 1
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
X O O - - - 
O X X - - - 
Player 1, choose a column: 4
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
X O O - - - 
O X X O - - 
Player 2, choose a column: 4
- - - - - - 
- - - - - - 
- - - - - - 
- - - - - - 
X O O X - - 
O X X O - - 
Player 1, choose a column: 3
- - - - - - 
- - - - - - 
- - - - - - 
- - O - - - 
X O O X - - 
O X X O - - 
Player 2, choose a column: 4
- - - - - - 
- - - - - - 
- - - - - - 
- - O X - - 
X O O X - - 
O X X O - - 
Player 1, choose a column: 4
- - - - - - 
- - - - - - 
- - - O - - 
- - O X - - 
X O O X - - 
O X X O - - 
Player 1 Wins.
----- Halting the processor -----

思路

代码流程

  • LOOP
    • 更换玩家
    • 展示地图
    • 输入列号
      • 不是1-6重新输入
      • 这一列没有空位重新输入
    • 修改地图内存实现落子
    • 判断胜利（子程序）
    • 判断平局（子程序）

难点

地图存储

一行加上换行刚好12个字符，所以使用一个内存指针R5访问地图，初始化为MAP的地址，移动到下一行+12，移动到下一列+2

判断是不是1-6

使用两个label存储1和6的ascall码，然后比较即可

BRnzp #2
NUMBER1 .FILL x0031
NUMBER6 .FILL x0036
;判断输入字符是否可行
LD R0,NUMBER1
NOT R0,R0
ADD R0,R0,#1;正数取反
ADD R0,R0,R2
BRn INVAL;小于1违法
LD R0,NUMBER6
NOT R0,R0
ADD R0,R0,#1;正数取反
ADD R0,R0,R2
BRp INVAL;大于6违法

判断是否有空位落子

内存开辟一段6位的空间，用ACCOUNT标记，存放每一列已落棋子个数，落子时从内存中取出对应值，判断是否小于6即可。然后将行存储下来（我赋值给了R3，从0开始）

;判断有没有空位
LEA R0, ACCOUNT 
ADD R0,R0,R2
LDR R3,R0,#0
ADD R3,R3,#-6
BRzp INVAL;没有空位，违法，重新输入
ADD R3,R3,#7
STR R3,R0,#0;更新account记录
NOT R3,R3
ADD R3,R3,#7;R3现在为行坐标（0开始）

修改地图实现落子

采用指针R5来定位，初始化为MAP首地址，然后+12*行+2*列即可定位（PS：我的行和列从0开始），然后LDR R4,R5,#0即可将当前玩家对应的子存到地图中

;修改地图
ADD R0,R3,#1;
LEA R5,MAP;R5为地图指针
LOOP1 
  ADD R0,R0,#-1
  BRnz LOOPEND1
  ADD R5,R5,#12
  BRnzp LOOP1
LOOPEND1
ADD R5,R5,R2;
ADD R5,R5,R2;R5指针定位完毕
STR R4,R5,#0

判断胜利

该实验最大的难点是如何判断胜利，因为LC3的寄存器有限，无法像C++那样多重循环去判断。所以我分成两步进行

  1. 计算八个方向（上下左右，右上右下左上左下）以落子点开始的连续相同棋子个数（不计入当前落子）
    • 每个方向使用循环一直将R3，R2，R5（行，列，map内存指针）往对应方向变，直到出现和当前落子不相等的符号，跳出循环，存储连续个数R0
    • 注意在取R5对应的字符前判断是否越界，越界跳出循环，存储连续个数R0
    • 在每个方向的循环前有个存储R0，加载R2,R3,R5的过程
  2. 按照左右，上下，主对角线，副对角线4个方向计算连续棋子个数是否>=4（eg上+下，左上+右下）
    • 占用8位内存的ACCOUNT2按顺序存储右，左，上，下，右上，右下，左上，左下的连续个数

如果胜利BR到胜利逻辑然后HALT，否则RET（JMP R7简写）

判断平局

这个简单，将ACCOUNT中所有列的落子个数相加然后和36比较就行，注意ADD一次最多加15

如果平局BR到平局逻辑然后HALT，否则RET

一些思考

本来我没用JSR，但是JUDGE_WIN逻辑的代码太多了，导致BR的PC_offset9不够用，只能用11位的JSR了

除此之外要充分利用BR的负数部分，可以吧结尾的.STRINGZ / .FILL / .BLKW放一些在程序开始，用BRNZP跳过即可，这样可以充分利用LD，ST，BR等指令9位offset的范围，防止越界（只在不行还是用子程序吧TAT）

因为我所有的寄存器都是当全局变量使用的，所以子程序也就没有ST和LD恢复的部分了

代码实现

.ORIG x3000
AND R1,R1,#0
ADD R1,R1,#1;R1存储当前玩家

BRNZP LOOP0
NUMBER1 .FILL x0031
NUMBER6 .FILL x0036
ENTER .FILL x000A
OCCUPY_1 .FILL x004F;"O"
OCCUPY_2 .FILL x0058;"X"

LOOP0
NOT R1,R1
ADD R1,R1,#2
BRz #2
LD R4,OCCUPY_2
BRnzp #1
LD R4,OCCUPY_1
;R4存放当前玩家的子

LEA R0, MAP
PUTS;展示地图
INPUT 
  LEA R0,PROMPT_1
  PUTS
  LD R0,NUMBER1;载入字符1的ascall码
  ADD R0,R0,R1
  OUT;显示玩家编号
  LEA R0, PROMPT_2 
  PUTS
GETC
OUT;回显
ADD R2,R0,#0;R2存储输入的字符
LD R0,ENTER
OUT;换行

;判断输入字符是否可行
LD R0,NUMBER1
NOT R0,R0
ADD R0,R0,#1;正数取反
ADD R0,R0,R2
BRn INVAL;小于1违法
LD R0,NUMBER6
NOT R0,R0
ADD R0,R0,#1;正数取反
ADD R0,R0,R2
BRp INVAL;大于6违法

;'1'对应0，将ascall转成int
LD R0,NUMBER1
NOT R0,R0
ADD R0,R0,#1;
ADD R2,R0,R2;R2存放列

;判断有没有空位
LEA R0, ACCOUNT 
ADD R0,R0,R2
LDR R3,R0,#0
ADD R3,R3,#-6
BRzp INVAL;没有空位，违法，重新输入
ADD R3,R3,#7
STR R3,R0,#0;更新account记录
NOT R3,R3
ADD R3,R3,#7;R3现在为行坐标（0开始）

;修改地图
ADD R0,R3,#1;
LEA R5,MAP;R5为地图指针
LOOP1 
  ADD R0,R0,#-1
  BRnz LOOPEND1
  ADD R5,R5,#12
  BRnzp LOOP1
LOOPEND1
ADD R5,R5,R2;
ADD R5,R5,R2;R5指针定位完毕
STR R4,R5,#0

;连线判断输赢
JSR JUDGE_WIN
JSR JUDGE_TIE

BRnzp LOOP0;while循环

INVAL
LEA R0,WARNING 
PUTS
BRNZP INPUT;违法，重新输入

MAP .STRINGZ "- - - - - -\n- - - - - -\n- - - - - -\n- - - - - -\n- - - - - -\n- - - - - -\n"
PROMPT_1 .STRINGZ "Player "
PROMPT_2 .STRINGZ ", choose a column: "
PROMPT_WIN .STRINGZ " Wins."
PROMPT_TIE .STRINGZ "Tie Game."
WARNING .STRINGZ "Invalid move. Try again.\n"
ACCOUNT .STRINGZ "\0\0\0\0\0\0\0";计数器，记录每列已落棋子个数

JUDGE_TIE
AND R5,R5,#0
LEA R0,ACCOUNT
LDR R6,R0,#0
ADD R5,R5,R6
LDR R6,R0,#1
ADD R5,R5,R6
LDR R6,R0,#2
ADD R5,R5,R6
LDR R6,R0,#3
ADD R5,R5,R6
LDR R6,R0,#4
ADD R5,R5,R6
LDR R6,R0,#5
ADD R5,R5,R6
ADD R5,R5,#-10
ADD R5,R5,#-10
ADD R5,R5,#-10
ADD R5,R5,#-6
BRz TIE
RET

;平局逻辑
TIE
  LEA R0,MAP
  PUTS
  LEA R0,PROMPT_TIE 
  PUTS
  HALT

;胜利逻辑
WIN
  LEA R0,MAP
  PUTS
  LEA R0,PROMPT_1
  PUTS
  LD R0,NUMBER1;载入字符1的ascall码
  ADD R0,R0,R1
  OUT;显示玩家编号
  LEA R0, PROMPT_WIN
  PUTS
  HALT;结束程序

;判断胜利子程序
JUDGE_WIN
ST R2,Y
ST R3,X
ST R5,POINTER;

;右
RIGHT_BEFORE
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

RIGHT
ADD R2,R2,#1
ADD R6,R2,#-6
BRzp LEFT_BEFORE;超边界跳出
ADD R5,R5,#2
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP RIGHT

;左
LEFT_BEFORE
LEA R6,ACCOUNT2
STR R0,R6,#0
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

LEFT
ADD R2,R2,#-1
BRn UP_BEFORE;超边界跳出
ADD R5,R5,#-2
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP LEFT


;上
UP_BEFORE
LEA R6,ACCOUNT2
STR R0,R6,#1
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

UP
ADD R3,R3,#-1
BRn DOWN_BEFORE;超边界跳出
ADD R5,R5,#-12
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP UP


;下
DOWN_BEFORE
LEA R6,ACCOUNT2
STR R0,R6,#2
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

DOWN
ADD R3,R3,#1
ADD R6,R3,#-6
BRzp RIGHTUP_BEFORE;超边界跳出
ADD R5,R5,#12
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP DOWN


;右上
RIGHTUP_BEFORE
LEA R6,ACCOUNT2
STR R0,R6,#3
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

RIGHTUP
ADD R2,R2,#1
ADD R6,R2,#-6
BRzp RIGHTDOWN_BEFORE;超边界跳出
ADD R3,R3,#-1
BRn RIGHTDOWN_BEFORE;超边界跳出
ADD R5,R5,#-10;-12+2
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP RIGHTUP



;右下
RIGHTDOWN_BEFORE
LEA R6,ACCOUNT2
STR R0,R6,#4
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

RIGHTDOWN
ADD R2,R2,#1
ADD R6,R2,#-6
BRzp LEFTUP_BEFORE;超边界跳出
ADD R3,R3,#1
ADD R6,R3,#-6
BRzp LEFTUP_BEFORE;超边界跳出
ADD R5,R5,#14
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP RIGHTDOWN

;左上
LEFTUP_BEFORE
LEA R6,ACCOUNT2
STR R0,R6,#5
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

LEFTUP
ADD R2,R2,#-1
BRn LEFTDOWN_BEFORE;超边界跳出
ADD R3,R3,#-1
BRn LEFTDOWN_BEFORE;超边界跳出
ADD R5,R5,#-14
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP LEFTUP


;左下
LEFTDOWN_BEFORE
LEA R6,ACCOUNT2
STR R0,R6,#6
AND R0,R0,#0
LD R2,Y
LD R3,X
LD R5,POINTER

LEFTDOWN
ADD R2,R2,#-1
BRn PRE_OP_END;超边界跳出
ADD R3,R3,#1
ADD R6,R3,#-6
BRzp PRE_OP_END;超边界跳出
ADD R5,R5,#10
LDR R6,R5,#0
NOT R6,R6;
ADD R6,R6,#1
ADD R6,R6,R4
BRnp #2
ADD R0,R0,#1
BRNZP LEFTDOWN

PRE_OP_END
LEA R6,ACCOUNT2
STR R0,R6,#7


;左右、上下、主副对角线求和，判断有没有>=3个子
LEA R6,ACCOUNT2
;左右
LDR R2,R6,#0
LDR R3,R6,#1
ADD R2,R2,R3
ADD R2,R2,#-3
BRzp WIN
;上下
LDR R2,R6,#2
LDR R3,R6,#3
ADD R2,R2,R3
ADD R2,R2,#-3
BRzp WIN
;主对角线
LDR R2,R6,#5
LDR R3,R6,#6
ADD R2,R2,R3
ADD R2,R2,#-3
BRzp WIN
;副对角线
LDR R2,R6,#4
LDR R3,R6,#7
ADD R2,R2,R3
ADD R2,R2,#-3
BRzp WIN
RET;返回循环

ACCOUNT2 .STRINGZ "\0\0\0\0\0\0\0\0"
X .BLKW 1
Y .BLKW 1
POINTER .BLKW 1

.END

ChainPray
关注
  • 19
    点赞
  • 踩
  • 25
    收藏
    觉得还不错? 一键收藏
  • 1
    评论
专栏目录
LC-3下汇编实现简易版四子棋的游戏
Elvis.
05-06 7579
问题描述： 两位选手通过键盘和输出窗口轮流交互操作，棋盘由6 X 6的网格组成。 游戏规则如下： 两位选手依次轮流落子； 选手不能悔棋； 有子的地方不能继续落子； 直到有一方的四个棋子能够连成一条水平线、垂直线或者是对角线； 如果棋盘已满，无人获胜，则平局。 游戏最初时应该打印空的棋盘，可以用ASCII码"-" （即ASCII 码 x002D）来表示该处为空，"O"(ASCII 码
LC-3简易四子棋（深大计系1实验4） 思路+代码+详细注释
AKGWSB 's blog
05-26 7909
明天做LC-3的四子棋实验，但是我想睡懒觉就今天把他做了，这个实验挺难的，要写好久还容易出bug，我把自己的思路和代码分享一下，让大家少走弯路 目录前置知识标号伪操作TRAP伪指令代码块（函数）调用题目描述实现思路流程判断胜利思路矩阵存放与填写测试结果代码 前置知识 在做实验前要掌握LC-3的一些伪指令和操作 标号 标号 = 内存地址 （可以这么粗略的理解，编译器建立了名字到内存的映射） 伪操作 特性：相当于库函数了，调用这些伪操作，编译器自动帮你做一些工作，标号以.开头，下面给出标号的解释表格
基于LC3模拟器的简单游戏设计：简易四子棋
曹无悔的博客
05-22 1517
基于LC3仿真器的简易四子棋设计，深圳大学计算机与软件学院《计算机系统1》的实验4.本文提供完整的思路和代码。
LC-3 汇编语言实现简易四子棋
sunny_code_的博客
07-18 388
四子棋是一款普遍流行的简易型桌面游戏，据说，虎克船长曾因专注于此游戏而长期隐身在住所，当船员们发现船长的这一专长之后，他们称这个游戏为“船长的情妇”。​ 四子棋是个双人游戏，两人轮流下棋，棋盘由行和列组成的网格，每个选手每次下一个子直到两人中有一人的棋子连成一条水平线、垂直线或者是对角线。​ 本实验需要在LC-3中实现简易版四子棋的游戏，两位选手通过键盘和输出窗口轮流交互操作，棋盘由6 X 6的网格组成。​ 如果棋盘已满，无人获胜，则平局。​ 有子的地方不能继续落子；
【深圳大学计算机系统1】实验四 简易四子棋
归忆_AC的博客
01-15 1413
为了明确选手的落子的位置，该选手应该输入数字1-6，然后回车，数字1-6指示在落子所在的列，从左到右，无需输入行号，程序应默认从行号6到行号1递减的顺序填入该棋子，若前后输入的列号相同，则行号减一。例如，如果选手第一次在左起第二列落子，应该输入2，然后回车，则该棋子落在行6列2处，当后面输入的列号再次为2时，则将棋子落子行5列2处，以此类推，详情见后续示例输出。程序应该一直提示该选手，知道输入正确的数字，当用户输入完成，程序应通过显示回馈给选手，然后通过换行符(ASCII 码 x000A)换行。
深圳大学 计系1实验四—四子棋实验
weixin_61285310的博客
05-28 1453
.ORIG X3000 ; ;初始化空白棋盘init LD R3,DATA ;指向开辟数据区的首地址 LD R2,SIX ;R2作为初始化六行的计数器 ADD R2,R2,#1 ; LOOPOUT0 LD R1,SIX ;R1作为初始化六列的计数器 ADD R2,R2,#-1 ; BRp LOOPIN0 ;R2>0，继续循环 BRz NEXT0 ;循环结束，来到下一部分 LOOPIN0 AND ...
【LC-3汇编实验】简易四子棋游戏设计
ShirohaWang的博客
06-06 978
为了明确选手的落子的位置，该选手应该输入数字1-6，然后回车，数字1-6指示在落子所在的列，从左到右，无需输入行号，程序应默认从行号6到行号1递减的顺序填入该棋子，若前后输入的列号相同，则行号减一。参考程序在内存中分配36个空间来表示棋盘的每个位置，最简单的遍历棋盘的方法为：如果该位置为空，则存放0，如果该位置为选手一的棋子，则存放1，如果为选手二的棋子，则存放-1，这样可以最大程度的使用状态码。当选手输入成功后，程序应打印更新后的棋盘，并检查是否有人获胜，如果没人获胜，则轮到下一位输入。
实验四 LC-3简单游戏设计
2301_80112744的博客
06-12 126
本实验需要在LC-3中实现简易版四子棋的游戏，两位选手通过键盘和输出窗口轮流交互操作，棋盘由6 X 6的网格组成。直到有一方的四个棋子能够连成一条水平线、垂直线或者是对角线；如果棋盘已满，无人获胜，则平局。有子的地方不能继续落子；两位选手依次轮流落子；
深圳大学计算机系统（1）实验四（LC3汇编语言简单四子棋）
2302_78966864的博客
06-06 695
为了明确选手的落子的位置，该选手应该输入数字1-6，然后回车，数字1-6指示在落子所在的列，从左到右，无需输入行号，程序应默认从行号6到行号1递减的顺序填入该棋子，若前后输入的列号相同，则行号减一。参考程序在内存中分配36个空间来表示棋盘的每个位置，最简单的遍历棋盘的方法为：如果该位置为空，则存放0，如果该位置为选手一的棋子，则存放1，如果为选手二的棋子，则存放-1，这样可以最大程度的使用状态码。当选手输入成功后，程序应打印更新后的棋盘，并检查是否有人获胜，如果没人获胜，则轮到下一位输入。
深圳大学计算机系统LC-3中实现简易版四子棋实验报告（含源代码及截图）
12-11
**深圳大学计算机系统LC-3实现简易版四子棋实验报告** 本次实验是基于计算机系统课程中的第四次实践任务，目标是使用LC-3（Little Computer 3）模拟器来设计一个简易版的四子棋游戏。LC-3是一种简单的微处理器模型...
汇编语言简易四子棋
08-01
简单的了解 汇编语言编写的 LC3环境下的 简易四子棋小游戏
四子棋实验报告1
08-03
【四子棋实验报告1】 本实验报告主要探讨了四子棋游戏的机器对弈策略，涉及到了人工智能领域的蒙特卡罗方法及其在棋盘游戏中应用的算法。实验旨在通过模拟人类玩家的行为，构建一个能够自主决策并进行有效对弈的AI...
计算机系统1-简易四子棋.docx
04-13
【计算机系统1-简易四子棋.docx】的实验报告主要涵盖了使用LC-3汇编语言设计和实现一个简易版的四子棋游戏。实验旨在让学习者深入理解子程序的编写与应用，同时增强对计算机系统基础的理解。以下是实验的具体内容和...
LC3蓝牙编码功能介绍
11-19
LC3蓝牙编码功能介绍 LC3蓝牙编码功能是一种基于块的转换音频编解码技术，定义了应用于音频配置文件的有效蓝牙音频编解码器。该编解码器可通过多种比特率对语音和音乐进行编码，并且可以合并到任何蓝牙音频配置文件...
C 语言学习(5) ---- 汇编语法基础
最新发布
小猪佩奇的博客
08-04 1077
其低16位形成了一个原始的 8086 寄存器 AX，读者可以通过寄存器名称 AL 访问 AX 的低字节，通过 AH 访问 AX 的高字节。是一个32位的寄存器，用于处理 32 位的数据，而 AX 是一个 16 位的寄存器，用于处理 16 位的数据。基于原始的 8086 指令集，寄存器是16位宽，而32bit 的。为了保证向后兼容性，新指令集中使用的寄存器是旧的寄存器的超集。正如前面所提到的，不同的汇编器对汇编程序有不同的语法，表示。在汇编中指定寄存器的操作数，需要是以寄存器的名称，比如。
【C语言】程序环境，预处理，编译，汇编，链接详细介绍，其中预处理阶段重点讲解
林宇恒的博客
08-02 2912
介绍程序环境的分类，详细讲解翻译环境的预处理阶段。
编译和汇编的区别
just do it
08-03 727
编译是将高级语言（如C、C++、Java等）编写的源代码转换成计算机可以直接执行的低级语言（通常是机器语言或汇编语言）的过程编译 —— 将人类可读的源代码转换为计算机可执行的指令集。
"深圳大学计算机系统1实验报告：简易四子棋
在本实验中，我们首先从理论层面了解了LC-3的基本知识和指令集，然后深入研究了四子棋游戏的规则和算法，最终尝试使用LC-3的汇编语言编写了一个简易的四子棋游戏程序。 在实验过程中，我们意识到在编写程序时需要...
评论 1
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值