MySQL 源码｜50 - 语法解析：基础表达式（simple_expr）

于 2024-08-21 13:21:43 发布
阅读量796 收藏 16
点赞数 18
分类专栏： MySQL源码 文章标签： mysql 源码 语法解析 基础表达式
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/Changxing_J/article/details/141391000
版权

目录文档：MySQL 源码｜源码剖析文档目录

源码位置（版本 = MySQL 8.0.37）：sql/sql_yacc.yy

前置文档：

在此之前，我们已经梳理的规则关系如下图所示。梳理基础表达式（simple_expr）规则的前置条件已经成熟，下面让我们开始梳理 simple_expr 规则。

在这里插入图片描述

simple_expr 规则相关关系如下图所示：其中绿色节点为本章节梳理，蓝色节点为之前章节已梳理，红色节点为后续章节梳理。

在这里插入图片描述

simple_expr 规则

simple_expr 规则用于匹配基础表达式，也可以理解为匹配一元表达式的结果，有如下备选方案：

  • 匹配 simple_ident 规则的结果：用于匹配 ident、ident.ident 或 ident.ident.ident
  • 匹配 function_call_keyword 规则匹配结果：用于匹配关键字函数，详见 MySQL 源码｜43 - 语法解析：关键字函数
  • 匹配 function_call_nonkeyword 规则匹配结果：用于匹配非关键字函数，详见 MySQL 源码｜44 - 语法解析：非关键字函数
  • 匹配 function_call_generic 规则匹配结果：用于匹配通用函数，详见 MySQL 源码｜45 - 语法解析：通用函数
  • 匹配 function_call_conflict 规则匹配结果：用于匹配为避免语法冲突专门处理的函数，详见 MySQL 源码｜46 - 语法解析：为避免语法冲突专门处理的函数
  • 依次匹配 simple_expr 规则匹配结果、COLLATE 关键字和 ident_or_text 规则匹配结果：用于在基础表达式的基础上指定排序规则
  • 匹配 literal_or_null 规则匹配结果：用于匹配字面值和 NULL 值，详见 MySQL 源码｜48 - 语法解析：字面值
  • 匹配 param_marker 规则匹配结果：用于匹配参数值，详见 MySQL 源码｜48 - 语法解析：字面值
  • 匹配 rvalue_system_or_user_variable 规则匹配结果：用于匹配系统变量或用户变量
  • 匹配 in_expression_user_variable_assignment 规则匹配结果：用于匹配用户变量赋值语句
  • 匹配 set_function_specification 规则匹配结果：用于匹配聚集函数，详见 MySQL 源码｜37 - 语法解析：聚集函数
  • 匹配 window_func_call 规则匹配结果：用于匹配窗口函数，详见 MySQL 源码｜38 - 语法解析：窗口函数
  • 依次匹配 simple_expr 规则匹配结果、||（OR_OR_SYM）和 simple_expr 关键字：用于匹配使用逻辑或符号连接的基础表达式
  • 依次匹配 + 和 simple_expr 规则匹配结果：用于匹配使用了 + 前缀一元表达式的基础表达式
  • 依次匹配 - 和 simple_expr 规则匹配结果：用于匹配使用了 - 前缀一元表达式的基础表达式
  • 依次匹配 ~ 和 simple_expr 规则匹配结果：用于匹配使用了 ~ 前缀一元表达式的基础表达式
  • 依次匹配 not2 规则匹配结果和 simple_expr 规则用于：用于匹配使用了 ! 前缀一元表达式（或 SQL_MODE 为 MODE_HIGH_NOT_PRECEDENCE 时的 NOT 关键字）的基础表达式
  • 匹配 row_subquery 规则匹配结果：用于匹配单行子查询，详见 MySQL 源码｜47 - 语法解析：子查询
  • 依次匹配 (、expr 规则匹配结果和 )：用于匹配被括号框柱的一个更高级别表达式
  • 依次匹配 ROW 关键字、(、expr 规则匹配结果、,、expr_list 和 )：用于匹配 ROW 子句和其中被括号框柱的多个更高级别表达式
  • 依次匹配 EXISTS 关键字和 table_subquery 规则匹配结果：用于匹配 EXISTS 子句和其中的多行子查询，详见 详见 MySQL 源码｜47 - 语法解析：子查询
  • 依次匹配 {、ident 规则匹配结果、expr 规则匹配结果和 }：用于匹配 ODBC 日期
  • 依次匹配 MATCH 关键字、ident_list_arg 规则匹配结果、AGAINST 关键字、(、bit_expr 规则匹配结果、fulltext_options 规则匹配结果和)：用于匹配全文搜索子句，其中 ident_list_arg 规则匹配任意数量的逗号分隔的标识符，fulltext_options 规则匹配全文搜索的配置
  • 依次匹配 BINARY 关键字和 simple_expr：用于匹配 BINARY 关键字将字符串转换为二进制字符串
  • 依次匹配 CAST 关键字、(、expr 规则匹配结果、AS 关键字、cast_type 规则匹配结果、opt_array_cast 规则匹配结果和 )：用于匹配 CAST 函数，详见 MySQL 源码｜49 - 语法解析：CAST 函数、CONVERT 函数和 BINARY 关键字
  • 依次匹配 CAST 关键字、(、expr 规则匹配结果、AT 关键字、LOCAL 关键字、AS 关键字、cast_type 规则匹配结果、opt_array_cast 规则匹配结果和 )：用于匹配 CAST 函数，详见 MySQL 源码｜49 - 语法解析：CAST 函数、CONVERT 函数和 BINARY 关键字
  • 依次匹配 CAST 关键字、(、expr 规则匹配结果、AT 关键字、TIME 关键字、ZONE 关键字、opt_interval 规则匹配结果、TEXT_STRING_literal 规则匹配结果、AS 关键字、DATETIME 关键字、type_datetime_precision 规则匹配结果和 )：用于匹配 CAST 函数，详见 MySQL 源码｜49 - 语法解析：CAST 函数、CONVERT 函数和 BINARY 关键字
  • 依次匹配 CASE 关键字、opt_expr 规则匹配结果、when_list 规则匹配结果 opt_else 规则匹配结果和 END 关键字：用于匹配 CASE 子句，其中 opt_expr 规则匹配可选的一般表达式，when_list 规则匹配 CASE 子句中任意数量的 WHEN {expr} THEN {expr} 子句，opt_else 规则匹配可选的 ELSE {expr} 子句
  • 依次匹配 CONVERT 关键字、(、expr 规则匹配结果，,、cast_type 规则匹配结果和 )：用于匹配 CONVERT 函数，详见 MySQL 源码｜49 - 语法解析：CAST 函数、CONVERT 函数和 BINARY 关键字依次匹配 CONVERT 关键字、(、expr 规则匹配结果、USING 关键字、charset_name 关键字匹配结果和 )：用于匹配 CONVERT 函数，详见 MySQL 源码｜49 - 语法解析：CAST 函数、CONVERT 函数和 BINARY 关键字
  • 依次匹配 DEFUALT 关键字、(、simple_ident 规则匹配结果和 )：用于匹配 DEFAULT 函数
  • 依次匹配 VALUES 关键字、(、simple_ident_nospvar 规则匹配结果和 )：用于匹配 VALUES 函数
  • 依次匹配 INTERVAL_SYM 关键字、expr 规则匹配结果、interval 规则匹配结果、+ 和 expr 规则匹配结果：用于匹配 INTERVAL 关键字引导的时间长度
  • 依次匹配 simple_ident 规则匹配结果、->（JSON_SEPARATOR_SYM 规则）和 TEXT_STRING_literal 规则匹配结果：用于匹配 Json 数据提取语句
  • 依次匹配 simple_ident 规则匹配结果、->>（JSON_UNQUOTED_SEPARATOR_SYM 规则）和 TEXT_STRING_literal 规则匹配结果：用于匹配 Json 数据提取语句

Bison 语法如下：

simple_expr:
          simple_ident
        | function_call_keyword
        | function_call_nonkeyword
        | function_call_generic
        | function_call_conflict
        | simple_expr COLLATE_SYM ident_or_text %prec NEG
          {
            warn_on_deprecated_user_defined_collation(YYTHD, $3);
            $$= NEW_PTN Item_func_set_collation(@$, $1, $3);
          }
        | literal_or_null
        | param_marker { $$= $1; }
        | rvalue_system_or_user_variable
        | in_expression_user_variable_assignment
        | set_function_specification
        | window_func_call
        | simple_expr OR_OR_SYM simple_expr
          {
            $$= NEW_PTN Item_func_concat(@$, $1, $3);
          }
        | '+' simple_expr %prec NEG
          {
            $$= $2; // TODO: do we really want to ignore unary '+' before any kind of literals?
            if ($$ != nullptr) $$->m_pos = @$;
          }
        | '-' simple_expr %prec NEG
          {
            $$= NEW_PTN Item_func_neg(@$, $2);
          }
        | '~' simple_expr %prec NEG
          {
            $$= NEW_PTN Item_func_bit_neg(@$, $2);
          }
        | not2 simple_expr %prec NEG
          {
            $$= NEW_PTN PTI_truth_transform(@$, $2, Item::BOOL_NEGATED);
          }
        | row_subquery
          {
            $$= NEW_PTN PTI_singlerow_subselect(@$, $1);
          }
        | '(' expr ')'
          {
            $$= $2;
            if ($$ != nullptr) $$->m_pos = @$;
          }
        | '(' expr ',' expr_list ')'
          {
            $$= NEW_PTN Item_row(@$, $2, $4->value);
          }
        | ROW_SYM '(' expr ',' expr_list ')'
          {
            $$= NEW_PTN Item_row(@$, $3, $5->value);
          }
        | EXISTS table_subquery
          {
            $$= NEW_PTN PTI_exists_subselect(@$, $2);
          }
        | '{' ident expr '}'
          {
            $$= NEW_PTN PTI_odbc_date(@$, $2, $3);
          }
        | MATCH ident_list_arg AGAINST '(' bit_expr fulltext_options ')'
          {
            $$= NEW_PTN Item_func_match(@$, $2, $5, $6);
          }
        | BINARY_SYM simple_expr %prec NEG
          {
            push_deprecated_warn(YYTHD, "BINARY expr", "CAST");
            $$= create_func_cast(YYTHD, @$, $2, ITEM_CAST_CHAR, &my_charset_bin);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CAST_SYM '(' expr AS cast_type opt_array_cast ')'
          {
            $$= create_func_cast(YYTHD, @$, $3, $5, $6);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CAST_SYM '(' expr AT_SYM LOCAL_SYM AS cast_type opt_array_cast ')'
          {
            my_error(ER_NOT_SUPPORTED_YET, MYF(0), "AT LOCAL");
          }
        | CAST_SYM '(' expr AT_SYM TIME_SYM ZONE_SYM opt_interval
          TEXT_STRING_literal AS DATETIME_SYM type_datetime_precision ')'
          {
            Cast_type cast_type{ITEM_CAST_DATETIME, nullptr, nullptr, $11};
            auto datetime_factor =
                NEW_PTN Item_func_at_time_zone(@3, $3, $8.str, $7);
            $$ = create_func_cast(YYTHD, @$, datetime_factor, cast_type, false);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CASE_SYM opt_expr when_list opt_else END
          {
            $$= NEW_PTN Item_func_case(@$, $3, $2, $4 );
          }
        | CONVERT_SYM '(' expr ',' cast_type ')'
          {
            $$= create_func_cast(YYTHD, @$, $3, $5, false);
            if ($$ == nullptr)
              MYSQL_YYABORT;
          }
        | CONVERT_SYM '(' expr USING charset_name ')'
          {
            $$= NEW_PTN Item_func_conv_charset(@$, $3,$5);
          }
        | DEFAULT_SYM '(' simple_ident ')'
          {
            $$= NEW_PTN Item_default_value(@$, $3);
          }
        | VALUES '(' simple_ident_nospvar ')'
          {
            $$= NEW_PTN Item_insert_value(@$, $3);
          }
        | INTERVAL_SYM expr interval '+' expr %prec INTERVAL_SYM
          /* we cannot put interval before - */
          {
            $$= NEW_PTN Item_date_add_interval(@$, $5, $2, $3, 0);
          }
        | simple_ident JSON_SEPARATOR_SYM TEXT_STRING_literal
          {
            Item_string *path=
              NEW_PTN Item_string(@3, $3.str, $3.length,
                                  YYTHD->variables.collation_connection);
            $$= NEW_PTN Item_func_json_extract(YYTHD, @$, $1, path);
          }
         | simple_ident JSON_UNQUOTED_SEPARATOR_SYM TEXT_STRING_literal
          {
            Item_string *path=
              NEW_PTN Item_string(@3, $3.str, $3.length,
                                  YYTHD->variables.collation_connection);
            Item *extr= NEW_PTN Item_func_json_extract(YYTHD, @$, $1, path);
            $$= NEW_PTN Item_func_json_unquote(@$, extr);
          }
        ;
simple_ident 规则

simple_ident 规则用于匹配 ident、ident.ident 或 ident.ident.ident，包含如下两种备选方案，其中 simple_ident_q 规则用于匹配 ident.ident 或 ident.ident.ident。Bison 语法如下：

simple_ident:
          ident
          {
            $$= NEW_PTN PTI_simple_ident_ident(@$, to_lex_cstring($1));
          }
        | simple_ident_q
        ;
simple_ident_q 规则

simple_ident_q 规则用于匹配 ident.ident 或 ident.ident.ident，Bison 语法如下：

simple_ident_q:
          ident '.' ident
          {
            $$= NEW_PTN PTI_simple_ident_q_2d(@$, $1.str, $3.str);
          }
        | ident '.' ident '.' ident
          {
            if (check_and_convert_db_name(&$1, false) != Ident_name_check::OK)
              MYSQL_YYABORT;
            $$= NEW_PTN PTI_simple_ident_q_3d(@$, $1.str, $3.str, $5.str);
          }
        ;
rvalue_system_or_user_variable 规则

rvalue_system_or_user_variable 规则用于匹配系统变量和用户变量，包含如下 2 种备选方案：

  • 依次匹配 @ 和 ident_or_text 规则匹配结果。
  • 依次匹配 @、@、opt_rvalue_system_variable_type 规则匹配结果和 rvalue_system_variable 规则匹配结果，其中 opt_rvalue_system_variable_type 规则用于匹配 GLOBAL 关键字、LOCAL 关键字或 SESSION 关键字。

Bison 语法如下：

rvalue_system_or_user_variable:
          '@' ident_or_text
          {
            $$ = NEW_PTN PTI_user_variable(@$, $2);
          }
        | '@' '@' opt_rvalue_system_variable_type rvalue_system_variable
          {
            $$ = NEW_PTN PTI_get_system_variable(@$, $3,
                                                 @4, $4.prefix, $4.name);
          }
        ;
opt_rvalue_system_variable_type 规则

opt_rvalue_system_variable_type 规则用于匹配 GLOBAL 关键字、LOCAL 关键字或 SESSION 关键字，Bison 语法如下：

opt_rvalue_system_variable_type:
          %empty          { $$=OPT_DEFAULT; }
        | GLOBAL_SYM '.'  { $$=OPT_GLOBAL; }
        | LOCAL_SYM '.'   { $$=OPT_SESSION; }
        | SESSION_SYM '.' { $$=OPT_SESSION; }
        ;
rvalue_system_variable 规则

rvalue_system_variable 规则用于匹配 ident_or_text[.ident]，Bison 语法如下：

rvalue_system_variable:
          ident_or_text
          {
            $$ = Bipartite_name{{}, to_lex_cstring($1)};
          }
        | ident_or_text '.' ident
          {
            // disallow "SELECT @@global.global.variable"
            if (check_reserved_words($1.str)) {
              YYTHD->syntax_error_at(@1);
              MYSQL_YYABORT;
            }
            $$ = Bipartite_name{to_lex_cstring($1), to_lex_cstring($3)};
          }
        ;
in_expression_user_variable_assignment 规则

in_expression_user_variable_assignment 规则用于匹配用户变量赋值语句，其中 SET_VAR 匹配 :=。Bison 语法如下：

in_expression_user_variable_assignment:
          '@' ident_or_text SET_VAR expr
          {
            push_warning(YYTHD, Sql_condition::SL_WARNING,
                         ER_WARN_DEPRECATED_SYNTAX,
                         ER_THD(YYTHD, ER_WARN_DEPRECATED_USER_SET_EXPR));
            $$ = NEW_PTN PTI_variable_aux_set_var(@$, $2, $4);
          }
        ;
not2 规则

not2 规则用于匹配 ! 运算符或 NOT2_SYM 关键字，其中 NOT2_SYM 关键字为 SQL_MODE 开启了 MODE_HIGH_NOT_PRECEDENCE 时的 NOT 关键字。Bison 语法如下：

not2:
          '!' { push_deprecated_warn(YYTHD, "!", "NOT"); }
        | NOT2_SYM
        ;
ident_list_arg 规则

ident_list_arg 规则用于匹配包含外层括号或不包含外层括号的标识符的、逗号分隔的、任意数量的标识符，Bison 语法如下：

ident_list_arg:
          ident_list          { $$= $1; }
        | '(' ident_list ')'  { $$= $2; }
        ;
ident_list 规则

ident_list 规则用于匹配使用逗号分隔的任意数量标识符，Bison 语法如下：

ident_list:
          simple_ident
          {
            $$= NEW_PTN PT_item_list(@$);
            if ($$ == nullptr || $$->push_back($1))
              MYSQL_YYABORT;
          }
        | ident_list ',' simple_ident
          {
            if ($1 == nullptr || $1->push_back($3))
              MYSQL_YYABORT;
            $$= $1;
            $$->m_pos = @$;
          }
        ;
fulltext_options 规则

fulltext_options 规则用于匹配全文搜索的配置，提供如下两种备选方案：

  • 依次匹配 opt_natural_language_mode 规则匹配结果和 opt_query_expansion 规则匹配结果，其中 opt_natural_language_mode 规则匹配可选的 IN NATURAL LANGUAGE MODE，opt_query_expansion 规则匹配可选的 WITH QUERY EXPANSION。
  • 依次匹配 IN 关键字、BOOLEAN 关键字和 MODE 关键字

Bison 语法如下：

fulltext_options:
          opt_natural_language_mode opt_query_expansion
          { $$= $1 | $2; }
        | IN_SYM BOOLEAN_SYM MODE_SYM
          {
            $$= FT_BOOL;
            DBUG_EXECUTE_IF("simulate_bug18831513",
                            {
                              THD *thd= YYTHD;
                              if (thd->sp_runtime_ctx)
                                YYTHD->syntax_error();
                            });
          }
        ;
opt_natural_language_mode 规则

opt_natural_language_mode 规则用于匹配可选的 IN NATURAL LANGUAGE MODE，Bison 语法如下：

opt_natural_language_mode:
          %empty { $$= FT_NL; }
        | IN_SYM NATURAL LANGUAGE_SYM MODE_SYM  { $$= FT_NL; }
        ;
opt_query_expansion 规则

opt_query_expansion 规则用于匹配可选的 WITH QUERY EXPANSION，Bison 语法如下：

opt_query_expansion:
          %empty { $$= 0;         }
        | WITH QUERY_SYM EXPANSION_SYM          { $$= FT_EXPAND; }
        ;
opt_expr 规则

opt_expr 规则用于匹配可选的一般表达式，Bison 语法如下：

opt_expr:
          %empty         { $$= nullptr; }
        | expr           { $$= $1; }
        ;
when_list 规则

when_list 规则用于匹配 CASE 子句中任意数量的 WHEN {expr} THEN {expr} 子句，Bison 语法如下：

when_list:
          WHEN_SYM expr THEN_SYM expr
          {
            $$= new (YYMEM_ROOT) mem_root_deque<Item *>(YYMEM_ROOT);
            if ($$ == nullptr)
              MYSQL_YYABORT;
            $$->push_back($2);
            $$->push_back($4);
          }
        | when_list WHEN_SYM expr THEN_SYM expr
          {
            $1->push_back($3);
            $1->push_back($5);
            $$= $1;
          }
        ;
opt_else 规则

opt_else 规则匹配可选的 ELSE {expr} 子句，Bison 语法如下：

opt_else:
          %empty       { $$= nullptr; }
        | ELSE expr    { $$= $2; }
        ;
长行
关注
  • 18
    点赞
  • 踩
  • 16
    收藏
    觉得还不错? 一键收藏
  • 打赏
    打赏
  • 0
    评论
专栏目录
ExprEval.rar_ExprEval_java 计算器_java表达式运算_jep-3.1.0-trial.jar_表达式
09-21
Java表达式运算的核心在于表达式解析器。在提供的"jep-3.1.0-trial.jar"中，JEP（Java Expression Parser）是一个强大的库，用于解析和求值数学表达式。JEP库提供了API，开发者可以通过这些接口来构建、解析和评估...
str-expr.zip_STR_expr_visual c_表达式计算
09-21
表达式计算源代码
expr-parser:Clike表达式解析器
03-25
"expr-parser:Clike表达式解析器"是一个使用Rust编程语言实现的项目，其目标是解析类似C语言的表达式。在计算机科学中，解析器是处理输入源代码并将其转化为计算机可理解形式的关键组件。这里，我们主要讨论的是如何...
xmljava系统源码-fin-expr:Java的表达式计算器。专注精准，可用于金融系统
06-06
java系统源码 FinExpr: an expression evaluator (support custom functions and variables) FinExpr: 一个表达式计算工具（支持添加自定义函数和变量） Brief introduction FinExpr is an expression evaluator ...
expr-eval:JavaScript中的数学表达式评估器
05-02
安装npm install expr-eval基本用法 const Parser = require ( 'expr-eval' ) . Parser ; const parser = new Parser ( ) ; let expr = parser . parse ( '2 * x + 1' ) ; console . log ( expr . evaluate ( { x : ...
MySQL中处理JSON数据:大数据分析的新方向
Chujun123528的博客
08-18 1146
灵活性：JSON数据类型允许你在单个列中存储复杂的数据结构，如数组和嵌套对象，这减少了需要创建多个表来存储相关信息的必要性。查询能力：MySQL为JSON数据类型提供了一系列内置的函数，如, , , , , 等，使得查询和修改JSON数据变得非常便捷。索引支持：MySQL支持为JSON文档中的特定路径创建虚拟列（Generated Columns），然后可以在这些虚拟列上创建索引，从而加速基于JSON内容的查询。性能优化：随着MySQL的不断改进，对JSON数据的处理性能也在不断提高。虽然与专门的NoSQL
Java学习Day28：Mysql 第二章：斗气大陆
weixin_51721783的博客
08-16 985
设计数据库时，某一个字段属于一张表，但它同时出现另一个或多个表中，且完全等同于它在其本来所属表的意义表示尽量遵循范式理论的规约，尽可能少的冗余字段，让数据库设计看起来精致合理加入冗余字段，减少join，让数据库执行性能更好添加索引首先应考虑在 where 及 order by 涉及的列上建立索引。索引的优点大大的提高查询速度可以显著的减少查询中分组和排序的时间。索引的缺点创建索引和维护索引需要时间，而且数据量越大时间越长。
MySQL单表条件查询语句
weixin_72431427的博客
08-19 319
MySQL中的一些常见的单表条件查询语句。
SpringBoot MySQL BinLog 监听数据变化(多库多表)
掐指一算乀缺钱
08-19 473
SpringBoot MySQL BinLog 监听数据变化(多库多表) 库.表,库1.表1,库1.表2
51 无显式主键时 mysql 增加的 DB_ROW_ID
970655147的专栏
08-19 423
假设有 implicit_id_table_02, 然后增加了 两条记录, 之后再向 implicit_id_table 中增加记录, 得到的 DB_ROW_ID 为 558。创建表的时候, 创建了该 三个系统字段, DB_ROW_ID, DB_TRX_ID, DB_ROLL_PTR。row_id 的处理是通过 dict_sys_get_new_row_id 函数来获取的。为 DB_ROW_ID, DB_TRX_ID, DB_POLL_PTR 分配存储空间的地方。
【MySQL】JDBC的基础使用
Starc_的博客
08-19 633
JDBC是Java连接和使用数据库的关键技术，它的重复性很高，仍然需要多加练习。源码JDBC的基础使用。
Mysql之视图
2301_77358096的博客
08-16 381
创建语法：create [or replace] view 视图名称 as select * from where [with check option]查询：show create view 视图名称查看视图数据：select * from 视图名称修改：1，可以使用创建的语法更新，记得加or replace2.alter view 视图名称 as select 表名删除：drop view [if exists] 视图名称。
MYSQL 关键字 先后顺序
gu2022_3_5_21_23的博客
08-16 120
SELECTFROMWHEREGROUP BYHAVINGORDER BYLIMIT。
SSH 隧道方式连接 MySQL 服务器
Sally_xy的博客
08-16 611
本文介绍通过 Navictat 或 MySQL Workbench 工具以 SSH 隧道方式连接MySQL 服务器的方法。
python工具--mysql2doris的datax json生成工具
weixin_45399602的博客
08-16 398
提供DDL生成datax的json
mysql篇-mysql的锁
qq_38360229的博客
08-15 260
此文为mysql 45第21课学习笔记。
MySQL中的EXPLAIN的详解
SHI940637335的博客
08-17 996
是一种优化技术，允许 MySQL 在存储引擎层面应用部分。
MySQL的子查询
最新发布
weixin_72431427的博客
08-20 196
MySQL中的子查询是一种强大的查询技术，它允许在一个查询中嵌套另一个查询。子查询可以在查询过程中引用其他表或同一表的不同列，并且可以用于过滤、排序和计算数据。
Django 链接MySQL数据库，报错Did you install mysqlclient?
梨子社区
08-13 331
之后为了测试这个问题是否和mysql-connector-c有关系，我提前把这个应用给卸了。据说是在python3里面，已经用pymysql替换了MySQLdb来进行数据库连接。所以，先安装pymysql。之后在整个项目根目录的。
error: C2780: “unknown-type std::invoke(_Callable &&) noexcept(<expr>)”: 应输入 1 个参数，却提供了 8 个
05-26
这个错误通常是因为你在使用 `std::invoke` 的时候传递了错误的参数。`std::invoke` 的第一个参数应该是一个可调用的对象（比如函数指针、成员函数指针、重载函数对象等），后面的参数是用于调用这个可调用对象的参数。请检查你的代码，看看是否有参数传递错误的情况。如果你需要更详细的帮助，请提供更多的代码信息。
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包

打赏作者

长行

你的鼓励将是我创作的最大动力

¥1 ¥2 ¥4 ¥6 ¥10 ¥20
扫码支付：¥1
获取中
扫码支付

您的余额不足，请更换扫码支付或充值

打赏作者

实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值