「2013NOIP提高组」火柴排队

火柴排队，这道题仔细读一读其实也不难，其大部分关注点还是在逆序对上。

额。。如果你要问逆序对是什么。。简单说一下：若是对于一个递增序列，有a[i]与a[j](i<j)，并且a[i]>a[j]则称a[i],a[j]为一对逆序对（i,j不一定要相邻）；

简单来看一下题：

CodeVS[3286]:

题目描述 Description

涵涵有两盒火柴，每盒装有 n 根火柴，每根火柴都有一个高度。现在将每盒中的火柴各自排成一列，同一列火柴的高度互不相同，两列火柴之间的距离定义为：
，其中 ai表示第一列火柴中第 i 个火柴的高度，bi表示第二列火柴中第 i 个火柴的高度。
每列火柴中相邻两根火柴的位置都可以交换，请你通过交换使得两列火柴之间的距离最小。请问得到这个最小的距离，最少需要交换多少次？如果这个数字太大，请输出这个最小交换次数对 99,999,997 取模的结果。

输入描述 Input Description

共三行，第一行包含一个整数 n，表示每盒中火柴的数目。
第二行有 n 个整数，每两个整数之间用一个空格隔开，表示第一列火柴的高度。
第三行有 n 个整数，每两个整数之间用一个空格隔开，表示第二列火柴的高度。

输出描述 Output Description

输出共一行，包含一个整数，表示最少交换次数对 99,999,997 取模的结果。

样例输入 Sample Input

[Sample 1]
4 
2 3 1 4 
3 2 1 4
[Sample 2]
4 
1 3 4 2 
1 7 2 4

样例输出 Sample Output

[Sample 1]
1
[Sample 2]
2

数据范围及提示 Data Size & Hint

【样例1说明】
最小距离是 0，最少需要交换 1 次，比如：交换第 1 列的前 2 根火柴或者交换第 2 列的前 2 根火柴。
【样例2说明】
最小距离是 10，最少需要交换 2 次，比如：交换第 1 列的中间 2 根火柴的位置，再交换第 2 列中后 2 根火柴的位置。
【数据范围】
对于 10%的数据， 1 ≤ n ≤ 10； 
对于 30%的数据，1 ≤ n ≤ 100； 
对于 60%的数据，1 ≤ n ≤ 1,000； 
对于 100%的数据，1 ≤ n ≤ 100,000，0 ≤火柴高度≤ 2^31 - 1。

对于此，我们首先要明确一点，就是什么时候那个距离最小。你或许也想到了，就是当这两个数列都对应好时（大对大，第二大对第二大…… 小对小 ），这有点类似方差。。至于怎么证明，（我也不知道）。

再说逆序对，有好几种找法（归并排序求逆序对，树状数组求逆序对，[暴力<-这里看看数据范围就知道不能用]……），比较喜欢的就是用归并了。

为了找对应关系，我们可以排个序，将两数列都分别排序，在这之前要用一个数组记录排序前的位置，排序时使其与数组连锁排序（这里用快排比较方便，连锁比较容易），我们用b表示这个数组，b[i,1]表示第一个数列，b[i,2]表示第二个数列，因此排完序后得到排序后的位置，用rank数组记录下来,便找到对应关系：

                                                                          rank[b[i,1]]=b[i,2]

此时rank[i]表示排序前第i个数在排序后数组中的位置下标，因为这些下标代表了这个数应该移到什么位置，所以我们只要对这个rank找一下逆序对的个数，便是答案了。（记得模数）

Pascal代码：

const
  inf=99999997;
var
  i,n:longint;
  ans:int64;
  r:array[1..100010] of longint;
  rank:array[1..100000] of longint;
  a,b:array[1..100000,1..2] of longint;      //a,b分别存数列与下标
procedure qsort(l,r,o:longint);              //o为下标，把两份快排压缩了
  var 
    i,j,mid,p,q:longint;
  begin
    i:=l;
    j:=r;
    mid:=a[(l+r) div 2,o];
    repeat
      while a[i,o]<mid do inc(i);
      while a[j,o]>mid do dec(j);
      if i<=j then 
        begin
          p:=a[i,o]; a[i,o]:=a[j,o]; a[j,o]:=p;       //连锁处理
          q:=b[i,o]; b[i,o]:=b[j,o]; b[j,o]:=q;
          inc(i); dec(j);
        end;
    until i>j;
    if l<j then qsort(l,j,o);
    if i<r then qsort(i,r,o);
  end;
  
procedure mergesort(s,t:longint);      //归并排序用来找逆序对
  var
    m,i,j,k:longint;
  begin
    if s=t then exit;
    m:=(s+t) div 2;
    mergesort(s,m);
    mergesort(m+1,t);
    i:=s;
    j:=m+1;
    k:=s;
    while (i<=m) and (j<=t) do
      begin
        if rank[i]<=rank[j] then
          begin r[k]:=rank[i]; inc(i); inc(k); end
        else                                      //在此加上ans计数器
          begin r[k]:=rank[j]; inc(j); inc(k); ans := (ans+(m mod inf)-(i mod inf)+1) mod inf; end;
      end;
    while i<=m do
      begin r[k]:=rank[i]; inc(i); inc(k); end;
    while j<=t do
      begin r[k]:=rank[j]; inc(j); inc(k); end;
    for i:=s to t do rank[i]:=r[i];
  end;
  
begin
  readln(n);
  for i:=1 to n do begin
    read(a[i,1]); b[i,1]:=i; end;  //分别初始化b[i,1]与b[i,2]
  for i:=1 to n do begin
    read(a[i,2]); b[i,2]:=i; end;
  qsort(1,n,1);
  qsort(1,n,2);
  for i:=1 to n do
    rank[b[i,1]]:=b[i,2];
  ans:=0;
  mergesort(1,n);
  write(ans);
end.

这样就解决了。