TX2440 项目实战-2440init.s 祥解 (ADS1.2编译) arm汇编基础学习终结

TX2440 项目实战-2440init.s 祥解 (ADS1.2编译) arm汇编基础学习终结

 

2440init.s启动,我分成九大部分,如下:

***第一步***:关看门狗,关中断.

***第二步***:设置时间频率.

***第三步***:检查是否在sleep状态,如果是,要唤醒.否则,跳过这一步.

***第四步***:配置内存SDRAM,NANDFLASH寄存器.

***第五步***:检查是否有EINT0中断,如果有,将SDRAM的0x30000000开始所有的内存清0.否则,跳过这一步.

***第六步***:设置所有模式的堆栈地址

***第七步***:检查NAND 还是 NOR 启动.拷代码(也就是ro,rw,zi段)到SDRAM

***第八步***:查二级向量表的中断例程安装到一级向量表(异常向量表)里

***第九步***:跳到C语言的main函数处.(马拉松跑完,哈哈!!!)

 

下面是单步解析:

;//********************************************************
;//*************** EatonWooo procedure ********************
;//********************************************************

;=========================================
; NAME: 2440INIT.S
; DESC: C start up codes
;       Configure memory, ISR ,stacks
; Initialize C-variables
;=========================================

 GET option.inc     ;GET 相当于include
 GET memcfg.inc
 GET 2440addr.inc

BIT_SELFREFRESH EQU (1<<22)  ;用于节电模式中，SDRAM自动刷新:REFRESH寄存器[22]bit : 0- auto refresh; 1 - self refresh

;Pre-defined constants    ;处理器模式常量: CPSR寄存器的后5位决定目前处理器模式 M[4:0]
USERMODE    EQU  0x10
FIQMODE     EQU  0x11
IRQMODE     EQU  0x12
SVCMODE     EQU  0x13
ABORTMODE   EQU  0x17
UNDEFMODE   EQU  0x1b
MODEMASK    EQU  0x1f
NOINT       EQU  0xc0

;The location of stacks
UserStack EQU (_STACK_BASEADDRESS-0x3800) ;0x33ff4800 ~
SVCStack EQU (_STACK_BASEADDRESS-0x2800) ;0x33ff5800 ~
UndefStack EQU (_STACK_BASEADDRESS-0x2400) ;0x33ff5c00 ~
AbortStack EQU (_STACK_BASEADDRESS-0x2000) ;0x33ff6000 ~
IRQStack EQU (_STACK_BASEADDRESS-0x1000) ;0x33ff7000 ~
FIQStack EQU (_STACK_BASEADDRESS-0x0) ;0x33ff8000 ~

;Arm上电时处于ARM状态，故无论指令为ARM集或Thumb集，都先强制成ARM集，待init.s初始化完成后
;再根据用户的编译配置转换成相应的指令模式。为此，定义变量THUMBCODE作为指示，跳转到main之前
;根据其值切换指令模式  逻辑伪指令[｜] 和 if else endif 都是编译的时候已经确定。
;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
 GBLL    THUMBCODE         ;定义THUMBCODE全局变量注意EQU所定义的宏与变量的区别
 [ {CONFIG} = 16           ;如果发现是在用16位代码的话（编译选项中指定使用thumb指令）
THUMBCODE SETL  {TRUE}        ;一方面把THUMBCODE设置为TURE
     CODE32                ;另一方面暂且把处理器设置成为ARM模式，以方便初始化
   |
THUMBCODE SETL  {FALSE}       ;如果编译选项本来就指定为ARM模式,把THUMBCODE设置为FALSE
    ]

   MACRO
 MOV_PC_LR                 ;宏名
   [ THUMBCODE
     bx lr                 ;在ARM模式中要使用BX指令转跳到THUMB指令,并转换模式. bx指令会根据PC最后1位来确定是否进入thumb状态
   |
     mov pc,lr             ;如果目标地址也是ARM指令,进入子函数之前,bl会把下一指令的pc 保存进lr,子函数返回时直接从lr里恢复就行了。
   ]
 MEND

   MACRO
 MOVEQ_PC_LR               ;（同理）;和上面的宏一样,只是多了一个相等的条件
   [ THUMBCODE
        bxeq lr
   |
     moveq pc,lr
   ]
 MEND

;这是共用宏.相当于多个子函数.子函数个数取决于标号$HandlerLabel的多少.而$HandleLabel只是传进来的参数.HANDLER是这个宏的宏名.
   MACRO
$HandlerLabel HANDLER $HandleLabel

$HandlerLabel
 ;这个宏的作用是调用中断入口服务程序.
 sub sp,sp,#4       ;栈空间腾出4个字节出来.准备把中断入口程序压栈.(原来sp-4)
 stmfd sp!,{r0}         ;(先减后压),把sp指再往下递增4个字节后,把r0压栈后,再把减后的数值写回sp.(原来sp-8),也就是说,r0放在原来sp-8的位置上.
 ldr     r0,=$HandleLabel    ;把一些中断的首地址(硬件地址)加进来给r0.如:HandleFIQ,HandleIRQ等等.
 ldr     r0,[r0]             ;把中断程序的首地址(硬件地址)的内容(中断入口服务程序的地址)给r0
 str     r0,[sp,#4]          ;把中断入口服务程序的地址放到栈空间sp-4的地方.
 ldmfd   sp!,{r0,pc}         ;(先弹后增)出栈,恢复原来的r0(原来sp-8)和把中断入口服务程序的地址给pc(原来sp-4),最后,(原来sp-0)
 MEND

 ;段分布,除|Image$$RO$$Base|由手工设置(默认为0x8000)后,其它均可由编译器生成地址.(参考我之前写的博文,段分布知识)
 IMPORT  |Image$$RO$$Base| ; Base of ROM code  ;我设置是0x30000000
 IMPORT  |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)
 IMPORT  |Image$$RW$$Base|   ; Base of RAM to initialise
 IMPORT  |Image$$ZI$$Base|   ; Base and limit of area
 IMPORT  |Image$$ZI$$Limit|  ; to zero initialise

;ARM920T协处理器接口
;ARM920T处理器通过一个外部协处理器接口来支持连接片上协处理器。ARM处理器支持所有的协处理器指令。
;ARM920T协处理器接口允许你附加一个专门设计的协处理器到ARM920T。包括：
;1.附加一个加速器：用于浮点运算，DSP，3-D图形，加密解密。
;2.ARM指令集可支持连接多达16个协处理器到ARM处理器，编号为0~15
;内部协处理器
;ARM920T处理器包括两个内部协处理器
;1.CP14：用于调试控制
;2.CP15：用于内存系统控制和测试控制
;这就意味着连接到ARM920T处理器外面的协处理器不能被编号为15或14.其他协处理器编号用于ARM公司内部使用。可联系ARM公司，以获得保留的协处理器编号的清单。
 ;下面两个子函数是协处理器.似乎没有用到.
 IMPORT MMU_SetAsyncBusMode
 IMPORT MMU_SetFastBusMode ;

 ;这个是C程序的入口,CPU初始化完成,最终我们还是到回C里写代码,完成一切的功能,好处就不多说了.
 IMPORT  Main    ; The main entry of mon program

 ;只读代码段,说了这么久,我们的入口终于来了. Init这个标号是在编译器里设置的.
 AREA    Init,CODE,READONLY

 ENTRY   ;一个文件只能有一个,一个程序最少有一个.
 
 EXPORT __ENTRY   ;导出符号_ENTRY,但在那用到就还没查明,似乎没用到.
__ENTRY
ResetEntry
 ;1)The code, which converts to Big-endian, should be in little endian code.
 ;2)The following little endian code will be compiled in Big-Endian mode.
 ;  The code byte order should be changed as the memory bus width.
 ;3)The pseudo instruction,DCD can not be used here because the linker generates error.
 ASSERT :DEF:ENDIAN_CHANGE
 [ ENDIAN_CHANGE             ;//编译器里默认设成了小端模式.
     ASSERT  :DEF:ENTRY_BUS_WIDTH  ;//ASSERT 是断言伪指令,语法是:ASSERT +逻辑表达式;def 是逻辑伪操作符，格式为： :DEF:label，作用是：判断label是否定义过
     [ ENTRY_BUS_WIDTH=32
  b ChangeBigEndian     ;DCD 0xea000007
     ]

     [ ENTRY_BUS_WIDTH=16
  andeq r14,r7,r0,lsl #20   ;DCD 0x0007ea00
     ]

     [ ENTRY_BUS_WIDTH=8
  streq r0,[r0,-r10,ror #1] ;DCD 0x070000ea
     ]
 |                               ;如果没有定义总线宽度，则返回复位中断
     b ResetHandler       ;//大端模式进入.
    ]
 b HandlerUndef ;handler for Undefined mode
 b HandlerSWI ;handler for SWI interrupt
 b HandlerPabort ;handler for PAbort
 b HandlerDabort ;handler for DAbort
 b .  ;reserved
 b HandlerIRQ ;handler for IRQ interrupt
 b HandlerFIQ ;handler for FIQ interrupt

;@0x20
 b EnterPWDN ; Must be @0x20.
ChangeBigEndian
;@0x24
 [ ENTRY_BUS_WIDTH=32
     DCD 0xee110f10 ;0xee110f10 => mrc p15,0,r0,c1,c0,0
     DCD 0xe3800080 ;0xe3800080 => orr r0,r0,#0x80;  //Big-endian
     DCD 0xee010f10 ;0xee010f10 => mcr p15,0,r0,c1,c0,0
 ]
 [ ENTRY_BUS_WIDTH=16
     DCD 0x0f10ee11
     DCD 0x0080e380
     DCD 0x0f10ee01
 ]
 [ ENTRY_BUS_WIDTH=8
     DCD 0x100f11ee
     DCD 0x800080e3
     DCD 0x100f01ee
    ]
 DCD 0xffffffff  ;swinv 0xffffff is similar with NOP and run well in both endian mode.
 DCD 0xffffffff
 DCD 0xffffffff
 DCD 0xffffffff
 DCD 0xffffffff
 b ResetHandler
 
HandlerFIQ      HANDLER HandleFIQ
HandlerIRQ      HANDLER HandleIRQ
HandlerUndef    HANDLER HandleUndef
HandlerSWI      HANDLER HandleSWI
HandlerDabort   HANDLER HandleDabort
HandlerPabort   HANDLER HandlePabort

IsrIRQ
 sub sp,sp,#4       ;reserved for PC
 stmfd sp!,{r8-r9}
;===================================================================================
;这查表方法够好了吧,r8(入口)+index*4(别望了一条指令是4 bytes的喔),
;这不就是我们要找的那一项了吗.找到了表项,下一步做什么?肯定先装入了!
;==================================================================================

 ldr r9,=INTOFFSET
 ldr r9,[r9]
 ldr r8,=HandleEINT0
 add r8,r8,r9,lsl #2        ;//地址对齐，因为每个中断向量占4个字节，即isr = IvectTable + Offeset * 4  也就是查MAP表 _ISR_STARTADDRESS
 ldr r8,[r8]                ;//装入中断服务程序的入口
 str r8,[sp,#8]             ;//把入口也入栈,准备用旧招
 ldmfd sp!,{r8-r9,pc}     ;//施招,弹出栈,哈哈,顺便把r8弹出到PC了,跳转成功!

 LTORG

;=======
; ENTRY
;=======
ResetHandler
;//************************************************************************************
;//***第一步***:关看门狗,关中断.
;//************************************************************************************
 ldr r0,=WTCON       ;watch dog disable
 ldr r1,=0x0
 str r1,[r0]         ;//1.禁止看门狗

 ldr r0,=INTMSK
 ldr r1,=0xffffffff  ;all interrupt disable
 str r1,[r0]         ;//2屏蔽所有中断

 ldr r0,=INTSUBMSK
 ldr r1,=0x7fff  ;all sub interrupt disable
 str r1,[r0]         ;//3屏蔽所有子中断(0-14bit) (15-31bit未使用.)

 [ {FALSE}           ;//4可以点一下灯来指示进入复位程序,但被FALSE了.
 ;rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
 ; Led_Display
 ldr r0,=GPFCON
 ldr r1,=0x5500      ;//我板子应该是0x0055,GPF0-GPF3设置为输出.
 str r1,[r0]
 ldr r0,=GPFDAT
 ldr r1,=0x10        ;//我的板子,接在GPF0的灯坏了,用GPF1应该是 ~(1<<1),低电平亮灯.
 str r1,[r0]
 ]

;//************************************************************************************
;//***第二步***:设置时间频率.
;//************************************************************************************
;//5.为了减少PLL的lock time, 调整LOCKTIME寄存器
 ;To reduce PLL lock time, adjust the LOCKTIME register.
 ldr r0,=LOCKTIME
 ldr r1,=0xffffff    ;//;reset的默认值
 str r1,[r0]
 
;CPU跑起来的频率.计算公式.
;//MPLL Control Register
;Mpll = (2 * m * Fin) / (p * 2^S)
;m = (MDIV + 8), p = (PDIV + 2), s = SDIV
;//UPLL Control Register
;Upll = (m * Fin) / (p * 2^S)
;m = (MDIV + 8), p = (PDIV + 2), s = SDIV
;//PLL Value Selection Guide (MPLLCON)
;1. Fout = 2 * m * Fin / (p*2^S), FVCO = 2 * m * Fin / p   where: m=MDIV+8, p=PDIV+2, s=SDIV
;2. 600MHz <= FVCO <= 1.2GHz
;3. 200MHz <= FCLKout <= 600MHz
;4. Don not set the P or M value as zero, that is, setting the P=000000, M=00000000 can cause malfunction of  the PLL.
;   (P,M的值都不能为0,否则会发生故障)
;5. The proper range of P and M: 1 <= P <= 62, 1 <= M <= 248

    [ PLL_ON_START                          ;//GBLL  PLL_ON_START 在option.inc定义,并初始化为true
 ; Added for confirm clock divide. for 2440.
 ; Setting value Fclk:Hclk:Pclk
;//5-1.分频比.
 ldr r0,=CLKDIVN
 ldr r1,=CLKDIV_VAL  ; 0=1:1:1, 1=1:1:2, 2=1:2:2, 3=1:2:4, 4=1:4:4, 5=1:4:8, 6=1:3:3, 7=1:3:6. 
 str r1,[r0]             ;//P:H:F=1:4:8  分频
;//MMU_SetAsyncBusMode 和 MMU_SetFastBusMode 都在4K代码以上,内部SRAM也才4K,连这两个子函数都装不下.所以不用这两库,自已写实现一样功能.
; MMU_SetAsyncBusMode and MMU_SetFastBusMode over 4K, so do not call here
; call it after copy
; [ CLKDIV_VAL>1   ; means Fclk:Hclk is not 1:1.
; bl MMU_SetAsyncBusMode
; |
; bl MMU_SetFastBusMode ; default value.
; ]
;//自已写协处理器,实现一样的功能.
 ;program has not been copied, so use these directly
 [ CLKDIV_VAL>1   ; means Fclk:Hclk is not 1:1.   ;//Fclk == Hclk,意思是存在分频比时.
 mrc p15,0,r0,c1,c0,0
 orr r0,r0,#0xc0000000;R1_nF:OR:R1_iA
 mcr p15,0,r0,c1,c0,0
 |
 mrc p15,0,r0,c1,c0,0
 bic r0,r0,#0xc0000000;R1_iA:OR:R1_nF
 mcr p15,0,r0,c1,c0,0
 ]
 
;//5-2.配置UPLL (注意:小心了,设置UPLL寄存器后,硬件必须最少要7个时钟周期去完成配置.7个nop必不可少了.)
 ;Configure UPLL                            ;通过下面的设置.最后由UPLL公式计算出,USB频率为48M
 ldr r0,=UPLLCON
 ldr r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV)  ;//查表设置:Input Frequency   Output Frequency      MDIV    PDIV SDIV
 str r1,[r0]                                ;//查表设置:12.0000MHz         48.00 MHz(Note)    56(0x38)   2     2
 nop ; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.
 nop
 nop
 nop
 nop
 nop
 nop
 
;//5-3.配置MPLL
 ;Configure MPLL                            ;通过下面的设置.最后由MPLL公式计算出,FCLK频率为400M,再由分频比得出HCLK,PCLK分别为100M,50M.
 ldr r0,=MPLLCON
 ldr r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV)  ;Fin=16.9344MHz  ;//我的应该为Fin=12MHz
 str r1,[r0]
    ]
;//************************************************************************************
;//***第三步***:检查是否在sleep状态,如果是,要唤醒.否则,跳过这一步.
;//************************************************************************************
;//6.检查CPU是否处于睡眠模式，如果是则需要唤醒CPU.
 ;Check if the boot is caused by the wake-up from SLEEP mode.
 ldr r1,=GSTATUS2
 ldr r0,[r1]
 tst r0,#0x2        ;//0:sleep ;write 1:wakeup
 ;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.
 bne WAKEUP_SLEEP   ;//如果状态为0,在sleep状态;tst 未置C位,所以不相等,跳去wakeup

 EXPORT StartPointAfterSleepWakeUp
StartPointAfterSleepWakeUp

;===============================================================================
;设置内存控制器等寄存器的值,因为这些寄存器是连续排列的,所以采用如下办法对这些
;寄存器进行连续设置.其中用到了SMRDATA的数据,这在代码后面有定义
;===============================================================================
;这是设置SDRAM,flash ROM 存储器连接和工作时序的程序,片选定义的程序
;SMRDATA map在下面的程序中定义
;SMRDATA中涉及的值请参考memcfg.inc程序
;//************************************************************************************
;//***第四步***:配置内存SDRAM,NANDFLASH寄存器.
;//************************************************************************************
 ;Set memory control registers
  ;ldr r0,=SMRDATA
  adrl r0, SMRDATA ;be careful!
 ldr r1,=BWSCON ;BWSCON Address
 add r2, r0, #52 ;End address of SMRDATA  ;//SMRDATA数据的结束地址,共有52字节的数据

0
 ldr r3, [r0], #4
 str r3, [r1], #4
 cmp r2, r0
 bne %B0                    ;//%表示搜索，B表示反向-back(F表示向前-forward)，0为局部标号(0~99)
;//HJ_start 
 ;===delay, hzh
 mov r0, #&1000
1
 subs r0, r0, #1
 bne %B1
 ;===
;//HJ_end
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
;;;;;;;;;;;;;       When EINT0 is pressed,  Clear SDRAM
;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
; check if EIN0 button is pressed
;//************************************************************************************
;//***第五步***:检查是否有EINT0中断,如果有,将SDRAM的0x30000000开始所有的内存清0.否则,跳过这一步.
;//************************************************************************************
       ldr r0,=GPFCON
 ldr r1,=0x0
 str r1,[r0]
 ldr r0,=GPFUP
 ldr r1,=0xff
 str r1,[r0]

 ldr r1,=GPFDAT
 ldr r0,[r1]
       bic r0,r0,#(0x1e<<1)  ; bit clear
 tst r0,#0x1
 bne %F1               ;//如果没有按,就跳到后面的1标号处 => Initialize stacks
 
 

; Clear SDRAM Start
 
 ldr r0,=GPFCON
 ldr r1,=0x55aa
 str r1,[r0]
; ldr r0,=GPFUP
; ldr r1,=0xff
; str r1,[r0]
 ldr r0,=GPFDAT
 ldr r1,=0x0
 str r1,[r0] ;LED=****

 mov r1,#0
 mov r2,#0
 mov r3,#0
 mov r4,#0
 mov r5,#0
 mov r6,#0
 mov r7,#0
 mov r8,#0
 
 ldr r9,=0x4000000   ;64MB         
 ldr r0,=0x30000000                
0 
 stmia r0!,{r1-r8}               ;//清空64M内存为0,每次清32个字节,直到64M全清0,我的板子是64M内存.
 subs r9,r9,#32
 bne %B0

;Clear SDRAM End

1

;//************************************************************************************
;//***第六步***:设置所有模式的堆栈地址
;//************************************************************************************
   ;Initialize stacks
 bl InitStacks

;===========================================================
 ;bl Led_Test

;//************************************************************************************
;//***第七步***:检查NAND 还是 NOR 启动.拷代码(也就是ro,rw,zi段)到SDRAM
;//************************************************************************************
 
;//BWSCON的[2:1]反映了外部引脚OM[1:0]:若OM[1:0] != 00, 从NOR FLash启动或直接在内存运行；若OM[1:0]==00，则为Nand Flash Mode

 ldr r0, =BWSCON
 ldr r0, [r0]
 ands r0, r0, #6  ;OM[1:0] != 0, NOR FLash boot     ;//BWSCON[2:1]为0时,Z = 1,相等;BWSCON[2:1]不为0时,Z = 0,不相等;
 bne copy_proc_beg  ;do not read nand flash           ;//OM[1:0] != 00，NOR FLash boot，不读取NAND FLASH
 adr r0, ResetEntry  ;OM[1:0] == 0, NAND FLash boot
 cmp r0, #0    ;if use Multi-ice,
 bne copy_proc_beg  ;do not read nand flash for boot
 ;nop
;===========================================================
nand_boot_beg
 mov r5, #NFCONF
 ;set timing value
 ldr r0, =(7<<12)|(7<<8)|(7<<4)
 str r0, [r5]
 ;enable control
 ldr r0, =(0<<13)|(0<<12)|(0<<10)|(0<<9)|(0<<8)|(1<<6)|(1<<5)|(1<<4)|(1<<1)|(1<<0)
 str r0, [r5, #4]
 
 bl ReadNandID
 mov r6, #0
 ldr r0, =0xec73
 cmp r5, r0
 beq %F1
 ldr r0, =0xec75
 cmp r5, r0
 beq %F1
 mov r6, #1
1 
 bl ReadNandStatus
 
 mov r8, #0
 ldr r9, =ResetEntry
2 
 ands r0, r8, #0x1f
 bne  %F3
 mov  r0, r8
 bl  CheckBadBlk
 cmp  r0, #0
 addne r8, r8, #32
 bne  %F4
3 
 mov r0, r8
 mov r1, r9
 bl ReadNandPage
 add r9, r9, #512
 add r8, r8, #1
4 
 cmp r8, #256
 bcc %B2
 
 mov r5, #NFCONF   ;DsNandFlash
 ldr r0, [r5, #4]
 bic r0, r0, #1
 str r0, [r5, #4]
 ldr pc, =copy_proc_beg
;===========================================================
copy_proc_beg
;//这里应该注意，使用的是adr，而不是ldr。使用ldr说明ResetEntry是个绝对地址，这个地址是在程序链接的时候
;//确定的。而使用adr则说明ResetEntry的地址和当前代码的执行位置有关，它是一个相对的地址。比如这段代码
;//在stepingstone里面执行，那么ResetEntry的地址就是零。如果在RAM里执行，那么ResetEntry就应是ＲＡＭ的一个
;//地址，应该等于RO base。

 adr r0, ResetEntry         
 ldr r2, BaseOfROM           ;//BaseOfROM内存上装的是0x30000000 ,r2 = 0x30000000(注:与ldr r2,=BaseOfROM不同)
 cmp r0, r2                 
 ldreq r0, TopOfROM        ;//如果相等的话(在内存运行 --- ice -- 无需复制code区中的ro段，但需要复制code区中的rw段),TopOfROM->r0
 beq InitRam                 ;//同时跳到InitRam
 ldr r3, TopOfROM
0 
 ldmia r0!, {r4-r7}
 stmia r2!, {r4-r7}        ;//不相等的话,也就是说,程序在stepstone时运行,把0地址(内部SRAM)开始的代码,复制到0x30000000(SDRAM)地址开始位置去.
 cmp r2, r3                  ;//直到,ro段(也就是代码段)复制完结束复制.
 bcc %B0
 
 sub r2, r2, r3              ;//因为 r2 = r3 ,所以r2 = r2 - r3 = 0;
 sub r0, r0, r2    ;//因为刚才循环复制时,r0,r2的代码增量是一样的.所以,r0的值,其实就是ro段的长度.所以,r0 = r0 - r2 = ro段的长度 - 0;
  
InitRam 
 ldr r2, BaseOfBSS
 ldr r3, BaseOfZero 
0
 cmp r2, r3                  ;//分两种情况
 ldrcc r1, [r0], #4        ;//1.SRAM运行的情况下,将SRAM里的RW段拷到SDRAM的RW段地址;2.SDRAM运行的情况下.r0=TopOfROM和r2=BaseOfBSS,其实是同一个地址(相当于无用功).
 strcc r1, [r2], #4
 bcc %B0 

 mov r0, #0
 ldr r3, EndOfBSS
1 
 cmp r2, r3
 strcc r0, [r2], #4        ;//ZI段循环清0, (EndOfBSS - BaseOfZero 这么大的大小.)
 bcc %B1
 
 ldr pc, =%F2  ;goto compiler address
2
 
; [ CLKDIV_VAL>1   ; means Fclk:Hclk is not 1:1.
; bl MMU_SetAsyncBusMode
; |
; bl MMU_SetFastBusMode ; default value.
; ]
 
 ;bl Led_Test

;//************************************************************************************
;//***第八步***:查二级向量表的中断例程安装到一级向量表(异常向量表)里
;//************************************************************************************
;===========================================================
;// 进入C语言前的最后一步了,就是把我们用说查二级向量表
;// 的中断例程安装到一级向量表(异常向量表)里.
;//5.设置缺省中断处理函数

   ; Setup IRQ handler
 ldr r0,=HandleIRQ       ;This routine is needed
 ldr r1,=IsrIRQ   ;if there is not 'subs pc,lr,#4' at 0x18, 0x1c
 str r1,[r0]       ;//把普通中断的处理程序入口放到MAP的HandleIRQ地址,供多HANDLER宏调用.
                   ;//如果,有b HandlerIRQ 这条指令的调用.进入到IsrIRQ这个子函数里,在这
                   ;//个子函数里面会查找是哪个

; ;Copy and paste RW data/zero initialized data
; ldr r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
; ldr r1, =|Image$$RW$$Base|  ; and RAM copy
; ldr r3, =|Image$$ZI$$Base|
;
; ;Zero init base => top of initialised data
; cmp r0, r1      ; Check that they are different
; beq %F2
;1
; cmp r1, r3      ; Copy init data
; ldrcc r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4
; strcc r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4
; bcc %B1
;2
; ldr r1, =|Image$$ZI$$Limit| ; Top of zero init segment
; mov r2, #0
;3
; cmp r3, r1      ; Zero init
; strcc r2, [r3], #4
; bcc %B3

;//************************************************************************************
;//***第九步***:跳到C语言的main函数处.(马拉松跑完,哈哈!!!)
;//************************************************************************************
;*****************************************************************************
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
;// 春天来了,终于来到Main函数了!!!!!!!!!!
;//       跳到C语言的main函数处了.
;!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
;*****************************************************************************

    [ :LNOT:THUMBCODE         ;//if THUMBCODE={false} bl main   L代表logic变量
   bl Main ;Do not use main() because ......
   ;ldr pc, =Main ;
   b .                 ;//注意小圆点
    ]

    [ THUMBCODE  ;for start-up code for Thumb mode
   orr lr,pc,#1
   bx lr
   CODE16
   bl Main ;Do not use main() because ......
   b .
  CODE32
    ]

;function initializing stacks
InitStacks
 ;Do not use DRAM,such as stmfd,ldmfd......
 ;SVCstack is initialized before
 ;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'
 mrs r0,cpsr
 bic r0,r0,#MODEMASK                                  ;//M0-M4 清0;
 orr r1,r0,#UNDEFMODE|NOINT                           ;//r1 = r0 | 0x11011011   ;置I,F,M4,M3,M1,M0
 msr cpsr_cxsf,r1  ;UndefMode                   ;//关闭中断，进入未定义模式
 ldr sp,=UndefStack  ; UndefStack=0x33FF_5C00     ;//进入未定义模式后,设置未定义模式堆栈顶指针

 orr r1,r0,#ABORTMODE|NOINT
 msr cpsr_cxsf,r1  ;AbortMode                   ;//关闭中断，进入异常模式
 ldr sp,=AbortStack  ; AbortStack=0x33FF_6000     ;//进入异常模式后,设置异常模式堆栈顶指针

 orr r1,r0,#IRQMODE|NOINT
 msr cpsr_cxsf,r1  ;IRQMode
 ldr sp,=IRQStack  ; IRQStack=0x33FF_7000       ;//进入中断模式后,设置中断模式堆栈顶指针

 orr r1,r0,#FIQMODE|NOINT
 msr cpsr_cxsf,r1  ;FIQMode
 ldr sp,=FIQStack  ; FIQStack=0x33FF_8000       ;//进入快速中断模式后,设置快速中断模式堆栈顶指针

 bic r0,r0,#MODEMASK|NOINT
 orr r1,r0,#SVCMODE
 msr cpsr_cxsf,r1  ;SVCMode
 ldr sp,=SVCStack  ; SVCStack=0x33FF_5800       ;//进入管理模式后,设置管理模式堆栈顶指针

 ;USER mode has not be initialized.

 mov pc,lr
 ;The LR register will not be valid if the current mode is not SVC mode.
 
;===========================================================
ReadNandID
 mov      r7,#NFCONF
 ldr      r0,[r7,#4]  ;NFChipEn();
 bic      r0,r0,#2
 str      r0,[r7,#4]
 mov      r0,#0x90  ;WrNFCmd(RdIDCMD);
 strb     r0,[r7,#8]
 mov      r4,#0   ;WrNFAddr(0);
 strb     r4,[r7,#0xc]
1       ;while(NFIsBusy());
 ldr      r0,[r7,#0x20]
 tst      r0,#1
 beq      %B1
 ldrb     r0,[r7,#0x10] ;id  = RdNFDat()<<8;
 mov      r0,r0,lsl #8
 ldrb     r1,[r7,#0x10] ;id |= RdNFDat();
 orr      r5,r1,r0
 ldr      r0,[r7,#4]  ;NFChipDs();
 orr      r0,r0,#2
 str      r0,[r7,#4]
 mov   pc,lr 
 
ReadNandStatus
 mov   r7,#NFCONF
 ldr      r0,[r7,#4]  ;NFChipEn();
 bic      r0,r0,#2
 str      r0,[r7,#4]
 mov      r0,#0x70  ;WrNFCmd(QUERYCMD);
 strb     r0,[r7,#8] 
 ldrb     r1,[r7,#0x10] ;r1 = RdNFDat();
 ldr      r0,[r7,#4]  ;NFChipDs();
 orr      r0,r0,#2
 str      r0,[r7,#4]
 mov   pc,lr

WaitNandBusy
 mov      r0,#0x70  ;WrNFCmd(QUERYCMD);
 mov      r1,#NFCONF
 strb     r0,[r1,#8]
1       ;while(!(RdNFDat()&0x40)); 
 ldrb     r0,[r1,#0x10]
 tst      r0,#0x40
 beq   %B1
 mov      r0,#0   ;WrNFCmd(READCMD0);
 strb     r0,[r1,#8]
 mov      pc,lr

CheckBadBlk
 mov  r7, lr
 mov  r5, #NFCONF
 
 bic      r0,r0,#0x1f ;addr &= ~0x1f;
 ldr      r1,[r5,#4]  ;NFChipEn()
 bic      r1,r1,#2
 str      r1,[r5,#4]

 mov      r1,#0x50  ;WrNFCmd(READCMD2)
 strb     r1,[r5,#8]
 mov      r1, #5;6  ;6->5
 strb     r1,[r5,#0xc] ;WrNFAddr(5);(6) 6->5
 strb     r0,[r5,#0xc] ;WrNFAddr(addr)
 mov      r1,r0,lsr #8 ;WrNFAddr(addr>>8)
 strb     r1,[r5,#0xc]
 cmp      r6,#0   ;if(NandAddr)  
 movne    r0,r0,lsr #16 ;WrNFAddr(addr>>16)
 strneb   r0,[r5,#0xc]
 
; bl  WaitNandBusy ;WaitNFBusy()
 ;do not use WaitNandBusy, after WaitNandBusy will read part A!
 mov r0, #100
1
 subs r0, r0, #1
 bne %B1
2
 ldr r0, [r5, #0x20]
 tst r0, #1
 beq %B2 

 ldrb r0, [r5,#0x10] ;RdNFDat()
 sub  r0, r0, #0xff
 
 mov      r1,#0   ;WrNFCmd(READCMD0)
 strb     r1,[r5,#8]
 
 ldr      r1,[r5,#4]  ;NFChipDs()
 orr      r1,r1,#2
 str      r1,[r5,#4]
 
 mov  pc, r7
 
ReadNandPage
 mov   r7,lr
 mov      r4,r1
 mov      r5,#NFCONF

 ldr      r1,[r5,#4]  ;NFChipEn()
 bic      r1,r1,#2
 str      r1,[r5,#4] 

 mov      r1,#0   ;WrNFCmd(READCMD0)
 strb     r1,[r5,#8] 
 strb     r1,[r5,#0xc] ;WrNFAddr(0)
 strb     r0,[r5,#0xc] ;WrNFAddr(addr)
 mov      r1,r0,lsr #8 ;WrNFAddr(addr>>8)
 strb     r1,[r5,#0xc] 
 cmp      r6,#0   ;if(NandAddr)  
 movne    r0,r0,lsr #16 ;WrNFAddr(addr>>16)
 strneb   r0,[r5,#0xc]
 
 ldr      r0,[r5,#4]  ;InitEcc()
 orr      r0,r0,#0x10
 str      r0,[r5,#4]
 
 bl       WaitNandBusy ;WaitNFBusy()
 
 mov      r0,#0   ;for(i=0; i<512; i++)
1
 ldrb     r1,[r5,#0x10] ;buf[i] = RdNFDat()
 strb     r1,[r4,r0]
 add      r0,r0,#1
 bic      r0,r0,#0x10000
 cmp      r0,#0x200
 bcc      %B1
 
 ldr      r0,[r5,#4]  ;NFChipDs()
 orr      r0,r0,#2
 str      r0,[r5,#4]
  
 mov   pc,r7

;--------------------LED test
 EXPORT Led_Test
Led_Test
 mov r0, #0x56000000
 mov r1, #0x5500
 str r1, [r0, #0x50]
0 
 mov r1, #0x50
 str r1, [r0, #0x54]
 mov r2, #0x100000
1
 subs r2, r2, #1
 bne %B1
 
 mov r1, #0xa0
 str r1, [r0, #0x54]
 mov r2, #0x100000
2
 subs r2, r2, #1
 bne %B2
 b %B0
 mov pc, lr

;===========================================================

 LTORG   ;//声明一个文字池

;GCS0->SST39VF1601
;GCS1->16c550
;GCS2->IDE
;GCS3->CS8900
;GCS4->DM9000
;GCS5->CF Card
;GCS6->SDRAM
;GCS7->unused

SMRDATA DATA
; Memory configuration should be optimized for best performance
; The following parameter is not optimized.
; Memory access cycle parameter strategy
; 1) The memory settings is  safe parameters even at HCLK=75Mhz.
; 2) SDRAM refresh period is for HCLK<=75Mhz.

 DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
 DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))   ;GCS0
 DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))   ;GCS1
 DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))   ;GCS2
 DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))   ;GCS3
 DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))   ;GCS4
 DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))   ;GCS5
 DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6
 DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7
 DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Tsrc<<18)+(Tchr<<16)+REFCNT)

 DCD 0x32     ;SCLK power saving mode, BANKSIZE 128M/128M

 DCD 0x30     ;MRSR6 CL=3clk
 DCD 0x30     ;MRSR7 CL=3clk
 
BaseOfROM DCD |Image$$RO$$Base|
TopOfROM DCD |Image$$RO$$Limit|
BaseOfBSS DCD |Image$$RW$$Base|
BaseOfZero DCD |Image$$ZI$$Base|
EndOfBSS DCD |Image$$ZI$$Limit|

 ALIGN
 
;Function for entering power down mode
; 1. SDRAM should be in self-refresh mode.
; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.
; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.
; 4. The I-cache may have to be turned on.
; 5. The location of the following code may have not to be changed.

;void EnterPWDN(int CLKCON);
EnterPWDN
 mov r2,r0  ;r2=rCLKCON
 tst r0,#0x8  ;SLEEP mode?
 bne ENTER_SLEEP

ENTER_STOP
 ldr r0,=REFRESH
 ldr r3,[r0]  ;r3=rREFRESH
 mov r1, r3
 orr r1, r1, #BIT_SELFREFRESH
 str r1, [r0]  ;Enable SDRAM self-refresh

 mov r1,#16   ;wait until self-refresh is issued. may not be needed.
0 subs r1,r1,#1
 bne %B0

 ldr r0,=CLKCON  ;enter STOP mode.
 str r2,[r0]

 mov r1,#32
0 subs r1,r1,#1 ;1) wait until the STOP mode is in effect.
 bne %B0  ;2) Or wait here until the CPU&Peripherals will be turned-off
   ;   Entering SLEEP mode, only the reset by wake-up is available.

 ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
 str r3,[r0]

 MOV_PC_LR

ENTER_SLEEP
 ;NOTE.
 ;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.

 ldr r0,=REFRESH
 ldr r1,[r0]  ;r1=rREFRESH
 orr r1, r1, #BIT_SELFREFRESH
 str r1, [r0]  ;Enable SDRAM self-refresh

 mov r1,#16   ;Wait until self-refresh is issued,which may not be needed.
0 subs r1,r1,#1
 bne %B0

 ldr r1,=MISCCR
 ldr r0,[r1]
 orr r0,r0,#(7<<17)  ;Set SCLK0=0, SCLK1=0, SCKE=0.
 str r0,[r1]

 ldr r0,=CLKCON  ; Enter sleep mode
 str r2,[r0]

 b .   ;CPU will die here.

WAKEUP_SLEEP
 ;Release SCLKn after wake-up from the SLEEP mode.
 ldr r1,=MISCCR
 ldr r0,[r1]
 bic r0,r0,#(7<<17)  ;//1):SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.;//2).清除对SDRAM信号线的保护,设置SDRAM为self-refresh
 str r0,[r1]

;-----------------------------------------
;//设置MISCCR,设置RAM，ROM的总线宽度与时序
;-----------------------------------------

 ;Set memory control registers
 ;//配置SDRAM存储器
  ldr r0,=SMRDATA ;be careful!
 ldr r1,=BWSCON ;BWSCON Address          ;//总线宽度和等待控制寄存器
 add r2, r0, #52 ;End address of SMRDATA
0
 ldr r3, [r0], #4   ;//;数据处理后R0自加4，[R0]->R3，R0+4->R0
 str r3, [r1], #4
 cmp r2, r0         ;//把Memory control的13个寄存器都循环设置完
 bne %B0            ;//局部标号:％{F|B}{A|T}    N{routname} ;如:F    指示编译器只向前搜索,A    指示编译器搜索宏的所有嵌套层次

 ;//设置所有的memory control register，他的初始地址为BWSCON，初始化
 ;//数据在以SMRDATA为起始的存储区
 ;//等待SDRAM清除自刷新

 mov r1,#256
0 subs r1,r1,#1 ;1) wait until the SelfRefresh is released.
 bne %B0

 ldr r1,=GSTATUS3  ;GSTATUS3 has the start address just after SLEEP wake-up
 ldr r0,[r1]         ;//sleep前,会把PC 保存到GSTATUS3寄存器里.唤醒会就会做以上的事情,然后才把PC恢复.

 mov pc,r0   ;//返回.
 
;=====================================================================
; Clock division test
; Assemble code, because VSYNC time is very short
;=====================================================================
 EXPORT CLKDIV124
 EXPORT CLKDIV144
 
CLKDIV124
 
 ldr     r0, = CLKDIVN
 ldr     r1, = 0x3  ; 0x3 = 1:2:4
 str     r1, [r0]
; wait until clock is stable
 nop
 nop
 nop
 nop
 nop

 ldr     r0, = REFRESH
 ldr     r1, [r0]
 bic  r1, r1, #0xff
 bic  r1, r1, #(0x7<<8)
 orr  r1, r1, #0x470 ; REFCNT135
 str     r1, [r0]
 nop
 nop
 nop
 nop
 nop
 mov     pc, lr

CLKDIV144
 ldr     r0, = CLKDIVN
 ldr     r1, = 0x4  ; 0x4 = 1:4:4
 str     r1, [r0]
; wait until clock is stable
 nop
 nop
 nop
 nop
 nop

 ldr     r0, = REFRESH
 ldr     r1, [r0]
 bic  r1, r1, #0xff
 bic  r1, r1, #(0x7<<8)
 orr  r1, r1, #0x630 ; REFCNT675 - 1520
 str     r1, [r0]
 nop
 nop
 nop
 nop
 nop
 mov     pc, lr

 ALIGN

 AREA RamData, DATA, READWRITE

 ^   _ISR_STARTADDRESS  ; _ISR_STARTADDRESS=0x33FF_FF00
HandleReset  #   4
HandleUndef  #   4
HandleSWI  #   4
HandlePabort    #   4
HandleDabort    #   4
HandleReserved  #   4
HandleIRQ  #   4
HandleFIQ  #   4

;Do not use the label 'IntVectorTable',
;The value of IntVectorTable is different with the address you think it may be.
;IntVectorTable
;@0x33FF_FF20
HandleEINT0  #   4
HandleEINT1  #   4
HandleEINT2  #   4
HandleEINT3  #   4
HandleEINT4_7 #   4
HandleEINT8_23 #   4
HandleCAM  #   4  ; Added for 2440.
HandleBATFLT #   4
HandleTICK  #   4
HandleWDT  #   4
HandleTIMER0  #   4
HandleTIMER1  #   4
HandleTIMER2  #   4
HandleTIMER3  #   4
HandleTIMER4  #   4
HandleUART2   #   4
;@0x33FF_FF60
HandleLCD   #   4
HandleDMA0  #   4
HandleDMA1  #   4
HandleDMA2  #   4
HandleDMA3  #   4
HandleMMC  #   4
HandleSPI0  #   4
HandleUART1  #   4
HandleNFCON  #   4  ; Added for 2440.
HandleUSBD  #   4
HandleUSBH  #   4
HandleIIC  #   4
HandleUART0  #   4
HandleSPI1   #   4
HandleRTC   #   4
HandleADC   #   4
;@0x33FF_FFA0
 END