bzoj 1854 并查集

Description

lxhgww最近迷上了一款游戏，在游戏里，他拥有很多的装备，每种装备都有2个属性，这些属性的值用[1,10000]之间的数表示。当他使用某种装备时，他只能使用该装备的某一个属性。并且每种装备最多只能使用一次。 游戏进行到最后，lxhgww遇到了终极boss，这个终极boss很奇怪，攻击他的装备所使用的属性值必须从1开始连续递增地攻击，才能对boss产生伤害。也就是说一开始的时候，lxhgww只能使用某个属性值为1的装备攻击boss，然后只能使用某个属性值为2的装备攻击boss，然后只能使用某个属性值为3的装备攻击boss……以此类推。 现在lxhgww想知道他最多能连续攻击boss多少次？

Input

输入的第一行是一个整数N，表示lxhgww拥有N种装备 接下来N行，是对这N种装备的描述，每行2个数字，表示第i种装备的2个属性值

Output

输出一行，包括1个数字，表示lxhgww最多能连续攻击的次数。

记得当时考这道题的前两天学的是并查集和匈牙利算法...然后说考的题只会从这两个算法里...然后就打了个匈牙利...被卡T了= =（我觉得一定是当时写了假的匈牙利）

好吧，说一下并查集做法...

把一个有a,b两种属性的武器，在a和b之间连一条边

对于一个连通块，

如果是一棵树，那么一定可以满足其中size-1个点

如果是一个环，那么这size个点一定都可以满足
那么就打标签维护就好了..

对于当前的新武器的两个属性x和y

如果x和y已经在一个联通块里，把根的标签置成真

如果x和y不在一个连通块里，就把x和y中小的那个的根置成真，如果小的已经为真，那么大的置为真。并把小的合并给大的

最后扫一遍即可

这里并查集的应用和bzoj 1116很像，都是维护连通块及联通块里环的信息（是否有环、联通块的形状）

注意细节：如果第i个属性的标签是false就break输出（i-1），但是有一种情况是所有属性都满足应该输出i，所以最后扫的时候要扫到i+1，这样只需要输出（i-1）即可

var
        n,a,b           :longint;
        flag            :array[0..10010] of boolean;
        f               :array[0..10010] of longint;
        i               :longint;
function get_father(x:longint):longint;
begin
   if x=f[x] then exit(x);
   f[x]:=get_father(f[x]);
   exit(f[x]);
end;

procedure swap(var a,b:longint);
var
        c:longint;
begin
   c:=a;a:=b;b:=c;
end;

begin
   read(n);
   for i:=1 to 10001 do f[i]:=i;
   fillchar(flag,sizeof(flag),false);
   for i:=1 to n do
   begin
      read(a,b);
      a:=get_father(a);
      b:=get_father(b);
      if (a<>b) then
      begin
         if a<b then swap(a,b);
         if flag[b] then flag[a]:=true else flag[b]:=true;
         f[b]:=a;
      end else flag[a]:=true;
   end;
   for i:=1 to 10001 do
    if not flag[i] then break;
   writeln(i-1);
end.

——by Eirlys