汇编第九节-转移指令的原理

第九节:转移指令的原理

可以修改IP，或同时修改CS和IP的指令通称为转移指令(可以控制CPU执行内存中某处代码的指令)

8086CPU按转移行为分类:
a.段内转移:只修改IP eg:jmp ax
b.段间转移:同时修改CS和IP时 eg:jmp 1000:0

由于转移指令对IP的修改范围不同，段内转移分类：
a.短转移IP的修改范围为-128~127
b.近转移IP的修改范围为-32768~32767

8086CPU的转移指令分为以下几类:
无条件转移指令(jmp);条件转移指令;循环指令(loop);过程;中断;

1.操作符offset:

offset由编译器处理的符号，功能是取得标号的偏移地址

assume cs:codesg
codesg segment
    start:mov ax,offset start   ;相当于mov ax,0
        s:mov ax,offset s       ;想当于mov ax,3
codesg ends
end start

2.jmp指令:

jmp为无条件转移指令，可以只修改IP，也可以同时修改CS和IP
jmp指令需要给出两种信息:
a.转移的目的地址
b.转移的距离(段间距离,段内短转移,段内近转移)

3.依据位移进行转移的jmp指令:

a.jmp short 标号(转到标号处执行指令) ;段内短转移
对IP修改范围-128~127
转移指令结束后，CS:IP应该指向标号处的指令

assume cs:codesg
codesg segment 
    start:mov ax,0
          jmp short s
          add ax,1
        s:inc ax 
codesg ends
end start

程序运行完，ax=1，执行jmp short s 越过add ax,1;
*注意 CPU在执行jmp指令的时候并不需要转移的目的地址，只需要告诉IP向后移动的字节数;

jmp short 标号 功能:(IP)=(IP)+8位位移
1.8位位移=标号处的地址-jmp指令后的第一个字节的地址
2.short 指明此处的位移为8位位移
3.8位位移的范围-128~127,用补码表示
4.8位位移由编译程序在编译的时候算出

b.jmp near ptr 标号 ;段内近转移
功能:(IP)=(IP)+16位位移
1.16位位移=标号处的地址-jmp指令后的第一个字节的地址
2.near ptr指明此处的位移为16位位移，进行的是段内近转移
3.16位位移的范围-32768~32767,用补码表示
4.16位位移由编译程序在编译的时候算出

4.转移的目的地址在指令中的jmp指令:

jmp far ptr 标号 实现的是段间转移(远转移)
功能:(cs)=标号所在段的段地址;(IP)=标号在段中的偏移地址。
far ptr指明了指令用标号的段地址和偏移地址修改CS和IP

assume cs:codesg
codesg segment
    start:mov ax,0
          mov bx,0
          jmp far ptr s
          db  256 dup (0)
        s:add ax,1
          inc ax
codesg ends
end start

在debug中运行时，jmp far ptr s对应的机器码EA 0B 01 BD 0B
(每个人的地址不一样)其中包括了转移的目的地址。0B 01 BD 0B是目的地址的存储顺序， BD 0B 是转移的段地址：0BBDH 低地址 0B 01 是偏移地址 010BH

5.转移地址在寄存器中的jmp指令:

仅修改IP的内容 jmp 16位reg
功能:(IP)=(16位reg)

jmp ax， 指令执行前：AX=1000H，CS=2000H IP=0003H
指令执行后：AX=1000H,CS=2000H,IP=1000H

用寄存器中值修改IP

6.转移地址在内存中的jmp指令:

转移地址在内存中的jmp指令有两种格式:
a.jmp word ptr 内存单元地址(段内转移)
功能：从内存单元地址处开始存放着一个字，是转移的目的偏移地址mov ax,0123H

mov ds:[0],ax
jmp word ptr ds:[0]
执行后(IP)=0123H

b.jmp dword ptr 内存单元地址(段间转移)
功能：从内存单元地址处开始存放着两个字，高地址处的字是转移的目的地址，低地址处是转移的目的偏移地址
(cs)=(内存单元地址+2)
(IP)=(内存单元地址)

mov ax,0123H
mov ds:[0],ax
mov word ptr ds:[2],0
jmp dword ptr ds:[0]
执行后 (cs)=0,(IP)=0123H,CS:IP指向0000:0123

7.jcxz指令:

条件转移指令，所有的有条件转移指令都是段转移,在对应的机器码中包含转移的位移，而不是目的地址。
(IP)修改范围-128~127
指令格式:jcxz 标号 (如果(cx)=0，转移到标号处执行)
操作:当(cx)=0时，(IP)=(IP)+8位位移；
8位位移=标号处的地址-jcxz指令后的第一个字节的地址
8位位移的范围-128~127,用补码表示
8位位移由编译程序在编译的时候算出

8.loop指令:

loop指令为循环指令，所有的循环指令都是短转移，在对应的机器码中包含转移的位移，而不是目的地址。
(IP)修改范围-128~127
指令格式:loop 标号 ((cx)=(cx)-1,如果(cx)不等于0，转移到标号处执行)
操作:
a.(cx)=(cx)-1;
b.如果(cx)不等于0，(IP)=(IP)+8位位移

8位位移=标号处的地址-loop指令后的第一个字节的地址
8位位移的范围-128~127,用补码表示
8位位移由编译程序在编译的时候算出

9.根据位移进行转移的意义:

jmp short 标号
jmp near 标号
jcxz 标号
loop 标号

10.编译器对转移位移超界的检测:

eg：

assume cs:code
code segment
    start:jmp short s
          db 128 dup (0)
        s:mov ax,0ffffh
code ends
end start

jmp short s的转移范围 -128~127,IP最多向后移动127个字节。