【寒假任务】 洛谷1068 分数线划定

问题描述
给出n组数据，要求划定分数线，分数线为给出的第m*1.5名的分数，输出分数线，录取人数和录取考生的考号，分数。若分数相同则按考号从大到小排序。
输入
第一行，两个整数 n，m（5 ≤ n ≤ 5000，3 ≤ m ≤ n），中间用一个空格隔开，其中 n 表示报名参加笔试的选手总数，m 表示计划录取的志愿者人数。输入数据保证 m*150%向下取整后小于等于 n。
第二行到第 n+1 行，每行包括两个整数，中间用一个空格隔开，分别是选手的报名号 k（1000 ≤ k ≤ 9999）和该选手的笔试成绩 s（1 ≤ s ≤ 100）。数据保证选手的报名号各不相同。
输出
第一行，有两个整数，用一个空格隔开，第一个整数表示面试分数线；第二个整数为进入面试的选手的实际人数。从第二行开始，每行包含两个整数，中间用一个空格隔开，分别表示进入面试的选手的报名号和笔试成绩，按照笔试成绩从高到低输出，如果成绩相同，则按报名号由小到大的顺序输出。
样例输入
6 3
1000 90
3239 88
2390 95
7231 84
1005 95
1001 88
样例输出
88 5
1005 95
2390 95
1000 90
1001 88
3239 88
算法讨论
本题主要还是排序，要注意的就是分数相同时要按考号从小到大排序，由于数据相对较大，用冒泡，选择会超时，所以使用快排。时间复杂度O(n log n)。

const
  maxn=5000;
var
  a:array[1..maxn,1..2] of longint;
  i,j,n,m:longint;

procedure qsort(l,r:longint);
var
  i,j,m,m1,t:longint;
begin
  if l>r
    then exit;
  i:=l; j:=r;
  m:=a[(l+r) div 2,2];
  m1:=a[(l+r) div 2,1];
  repeat
    while (a[i,2]>m) or ((a[i,2]=m) and (a[i,1]<m1)) do
      inc(i);
    while (a[j,2]<m) or ((a[j,2]=m) and (a[j,1]>m1)) do
      dec(j);
    if i<=j
      then begin
             t:=a[i,1]; a[i,1]:=a[j,1]; a[j,1]:=t;
             t:=a[i,2]; a[i,2]:=a[j,2]; a[j,2]:=t;
             inc(i); dec(j);
           end;
  until i>j;
  if l<j
    then qsort(l,j);
  if i<r
    then qsort(i,r)
end;

begin
  read(n,m);
  for i:=1 to n do
    read(a[i,1],a[i,2]);
  m:=trunc(m*1.5);
  qsort(1,n);
  for j:=n downto 1 do
    if a[j,2]>=a[m,2]
      then break;
  writeln(a[m,2],' ',j);
  for i:=1 to j do
    writeln(a[i,1],' ',a[i,2])
end.

Pixiv ID：59128091