洛谷 P1886 滑动窗口

题目大意：

现在有一堆数字共N个数字，以及一个大小为k的窗口。现在这个从左边开始向右滑动，每次滑动一个单位，求出每次滑动后窗口中的最大值和最小值。

50%的数据，n<=10^5
100%的数据，n<=10^6

题解：

这题是我学了单调队列做的第一题。
发现单调队列其实挺简单的。
这题是给出一个N长度的序列a1,a2,a3….an-1,an，
让你求出任意一段区间例
[1..k],[2..k+1]..[n-k,n-1],[n-k+1,n]的最小值跟最大值。

我们对于一个最小值，可以维护一个递增队列，
这个队列中任意一个数要满足位置在[i-k+1,i]，且位置也递增。
队列的维护就是：
①当前枚举到了i，那么队列中要从头向后将不在[i-k+1,i]之间的数给剔除掉！
②我们要将当前的ai跟加入到队列中，并且将队列的最大值变成ai！

如一个n=6,k=5的序列1 3 5 7 9 4，做到4的时候
队列中很明显是1 3 5 7 9，
位置分别是1 2 3 4 5
这时候4的位置是6，
那么很显然1的位置1<6-5+1所以剔除掉，队列变成
3 5 7 9，然后我们插入4，则
插入到3 和 5 之间，因为我们要的是最小值，那么队列中有了4，则不需要比它大的数了，
则队列从3 5 7 9 变成 3 4 5 7 9 再变成 3 4
这样的维护我们可以保证队列中数是单调递增，且可以保证队首的数最小值，就可以求出任意一个[i-k+1，i]的最小值！
而区间的最大值也同理可做。

var
   a,min,max:Array [0..1000001] of longint;
   i,n,m,xhead,ytail,phead,qtail:longint;

begin
   readln(n,m);
   for i:=1 to n do read(a[i]);
   xhead:=1; ytail:=0;
   phead:=1; qtail:=0;
   for i:=1 to n do
     begin
         while (phead<=qtail) and (min[phead]<i-m+1) do inc(phead);
         while (phead<=qtail) and (a[i]<a[min[qtail]]) do dec(qtail);
         qtail:=qtail+1;
         min[qtail]:=i;
         if i>=m then write(a[min[phead]],' ');
     end;

   writeln;

   for i:=1 to n do
     begin
         while (xhead<=ytail) and (max[xhead]<i-m+1) do inc(xhead);
         while (xhead<=ytail) and (a[i]>a[max[ytail]]) do dec(ytail);
         ytail:=ytail+1;
         max[ytail]:=i;
         if i>=m then write(a[max[xhead]],' ');
     end;
end.