ABAP - SALV教程06 - 列的设置(隐藏、修改、优化列宽)

HeathlX

已于 2024-03-03 04:43:45 修改

阅读量1k

点赞数 22

分类专栏： ABAP-SALV 文章标签： ABAP

于 2024-03-03 00:01:07 首次发布

本文链接：https://blog.csdn.net/HeathlX/article/details/136424871

版权

ABAP-SALV 专栏收录该内容

23 篇文章 1 订阅

订阅专栏

SAVL要想像Function ALV或OO ALV那样设置Fieldcat，也是有方法的。

通过取得全体列的类引用 CL_SALV_COLUMNS来进行修改

  METHOD set_columns.

*   取得全部列的对象
    DATA(lo_cols) = co_alv->get_columns( ).

*   设置自动优化列宽度
    lo_cols->set_optimize( 'X' ).


    TRY.
      "修改列VBELN的标签名字和输出长度
      lo_cols->get_column( 'VBELN' )->set_long_text( 'Sale Order' ).  "长描述
      lo_cols->get_column( 'VBELN' )->set_medium_text( 'Sale Order' )."中描述
      lo_cols->get_column( 'VBELN' )->set_short_text( 'Sale Order' ). "短描述
      lo_cols->get_column( 'VBELN' )->set_output_length( 15 ).
      
      "隐藏列
      lo_cols->get_column( 'ERNAM' )->set_visible( value = if_salv_c_bool_sap=>false ).
      ...
      CATCH cx_salv_not_found.
    ENDTRY.

  ENDMETHOD.                    "SET_COLUMNS

显示效果如下图所示：

完整代码

CLASS lcl_model DEFINITION.
  PUBLIC SECTION.
    TYPES:BEGIN OF TY_dATA,
            vbeln TYPE vbak-vbeln,
            erdat TYPE erdat,
            erzet TYPE erzet,
            ernam TYPE ernam,
            auart TYPE auart.
    TYPES:END  OF ty_data.

    DATA mt_data TYPE TABLE OF ty_data.

    DATA mo_salv TYPE REF TO cl_salv_table.

    "获取数据的方法
    METHODS get_data.
    "展示SALV的方法
    METHODS alv_show.

  PRIVATE SECTION.
    METHODS:
      set_status  CHANGING co_alv TYPE REF TO cl_salv_table.
    METHODS:
      set_columns CHANGING co_alv TYPE REF TO cl_salv_table.

ENDCLASS.

CLASS lcl_model IMPLEMENTATION.
  METHOD get_data.
    SELECT vbeln erdat erzet ernam auart
      INTO TABLE mt_data
      FROM vbak
      UP TO 20 ROWS.
  ENDMETHOD.

  METHOD alv_show.
    DATA: lx_msg TYPE REF TO cx_salv_msg.
    TRY.
        cl_salv_table=>factory(
          IMPORTING
            r_salv_table = mo_salv
          CHANGING
            t_table      = mt_data ).
      CATCH cx_salv_msg INTO lx_msg.
    ENDTRY.
    me->set_status( CHANGING co_alv = mo_salv ).
    me->set_columns( CHANGING co_alv = mo_salv ).
    mo_salv->display( ).
  ENDMETHOD.

  METHOD set_status.
    DATA(lo_functions) = co_alv->get_functions( ).
    "cl_salv_functions_list类型的实例对象的添加状态方法
    lo_functions->set_all( abap_true ).
    "lo_functions->set_default( abap_true ).
  ENDMETHOD.

  METHOD set_columns.

*   取得全部列的对象
    DATA(lo_cols) = co_alv->get_columns( ).

*   设置自动优化列宽度
    lo_cols->set_optimize( 'X' ).

*   修改列VBELN的标签名字和输出长度
    TRY.
      lo_cols->get_column( 'VBELN' )->set_long_text( 'Sale Order' ).  "长描述
      lo_cols->get_column( 'VBELN' )->set_medium_text( 'Sale Order' )."中描述
      lo_cols->get_column( 'VBELN' )->set_short_text( 'Sale Order' ). "短描述
      lo_cols->get_column( 'VBELN' )->set_output_length( 15 ).
      CATCH cx_salv_not_found.
    ENDTRY.

  ENDMETHOD.                    "SET_COLUMNS

ENDCLASS.

START-OF-SELECTION.
  DATA(lo_model) = NEW lcl_model( ).
  lo_model->get_data( ).
  lo_model->alv_show( ).