poj 3126 Prime Path

Description

The ministers of the cabinet were quite upset by the message from the Chief of Security stating that they would all have to change the four-digit room numbers on their offices.
— It is a matter of security to change such things every now and then, to keep the enemy in the dark.
— But look, I have chosen my number 1033 for good reasons. I am the Prime minister, you know!
— I know, so therefore your new number 8179 is also a prime. You will just have to paste four new digits over the four old ones on your office door.
— No, it’s not that simple. Suppose that I change the first digit to an 8, then the number will read 8033 which is not a prime!
— I see, being the prime minister you cannot stand having a non-prime number on your door even for a few seconds.
— Correct! So I must invent a scheme for going from 1033 to 8179 by a path of prime numbers where only one digit is changed from one prime to the next prime.

Now, the minister of finance, who had been eavesdropping, intervened.
— No unnecessary expenditure, please! I happen to know that the price of a digit is one pound.
— Hmm, in that case I need a computer program to minimize the cost. You don't know some very cheap software gurus, do you?
— In fact, I do. You see, there is this programming contest going on... Help the prime minister to find the cheapest prime path between any two given four-digit primes! The first digit must be nonzero, of course. Here is a solution in the case above.

1033
1733
3733
3739
3779
8779
8179

The cost of this solution is 6 pounds. Note that the digit 1 which got pasted over in step 2 can not be reused in the last step – a new 1 must be purchased.

Input

One line with a positive number: the number of test cases (at most 100). Then for each test case, one line with two numbers separated by a blank. Both numbers are four-digit primes (without leading zeros).

Output

One line for each case, either with a number stating the minimal cost or containing the word Impossible.

Sample Input

3
1033 8179
1373 8017
1033 1033

Sample Output

6
7
0

Source

Northwestern Europe 2006

 

题目大意：给定一个四位质数，规定每一次可以改变它的任意一位，但满足改动后的四位数仍然是一个质数，再不断对新得到的数进行修改，知道得到给出的目标质数。

 

范围只限定在四位数，质数就更少了，所以直接广搜0ms过。不过要先打质数表，广搜的时候就会很方便了。同时打质数表又复习了一下线性筛法。

 

AC CODE

 

program pku_3126;
var a,p:array[1..10000] of longint;
      q:array[1..1000000] of longint;
      d:array[1..4] of longint;
      find:array[1000..9999] of boolean;
      size,l,r,all,i:longint;
//============================================================================
procedure get_prime;      //线性筛法。
var i,j:longint;
begin
  for i:=2 to 10000 do a[i]:=i;
  for i:=2 to 10000 do
  begin
      if a[i]=i then
      begin
          inc(size);
          p[size]:=i;
      end;
      for j:=1 to size do
      begin
          if p[j]*i>10000 then break;
          a[p[j]*i]:=p[j];
          if i mod p[j]=0 then break;
      end;
  end;
end;
//============================================================================
procedure change(x:longint);      //进行修改。
var now,num,next,i,j:longint;
begin
  now:=q[x];
  for i:=1 to 4 do
  begin
      num:=now div d[i] mod 10;
      for j:=0 to 9 do
      if (j<>num) and not((i=4) and (j=0)) then
      begin
          next:=now-(num-j)*d[i];
          if (a[next]=next) and not(find[next]) then
          begin
              inc(r); q[r]:=next; find[next]:=true;
          end;
      end;
  end;
end;
//============================================================================
procedure work;      //广搜。
var g,h,ans,be,en:longint;
begin
  fillchar(find,sizeof(find),0);
  readln(be,en); ans:=0;
  if be=en then
  begin
      writeln('0');
      exit;
  end;
  l:=1; r:=1; q[1]:=be; find[be]:=true;
  while l<=r do
  begin
      g:=r;
      for h:=l to g do change(h);
      l:=g+1; inc(ans);
      if find[en] then break;
  end; writeln(ans);
end;
//============================================================================
begin
  d[1]:=1; d[2]:=10; d[3]:=100; d[4]:=1000;
  get_prime;
  readln(all);
  for i:=1 to all do work;
end.