bzoj 1051 [HAOI2006]受欢迎的牛

Description

每一头牛的愿望就是变成一头最受欢迎的牛。现在有N头牛，给你M对整数(A,B)，表示牛A认为牛B受欢迎。 这种关系是具有传递性的，如果A认为B受欢迎，B认为C受欢迎，那么牛A也认为牛C受欢迎。你的任务是求出有多少头牛被所有的牛认为是受欢迎的。

Input

第一行两个数N,M。 接下来M行，每行两个数A,B，意思是A认为B是受欢迎的（给出的信息有可能重复，即有可能出现多个A,B）

Output

一个数，即有多少头牛被所有的牛认为是受欢迎的。

Sample Input

3 3
1 2
2 1
2 3

Sample Output

1

【数据范围】
10%的数据N<=20, M<=50
30%的数据N<=1000,M<=20000
70%的数据N<=5000,M<=50000
100%的数据N<=10000,M<=50000

 

先求强连通块，然后重构图，统计出度为0的块的个数，如果为1，输出那一块的大小，如果大于一输出零。

求强连通的算法参见：http://www.byvoid.com/blog/scc-tarjan/

 

AC CODE

 

program bzoj_1051;
var line,next:array[1..50000] of longint;
    en,cd,fa,sum,dfn,low,stack:array[1..10000] of longint;    //cd就是记录有多少个出度，其实可以用boolean记有没有就行了。

//sum记录每个连通块的大小。
    sta,p:array[1..10000] of boolean;    //p数组记录是否遍历过，sta数组记录是否在栈中
    n,time,tot,len,size:longint;
//============================================================================
function min(x,y:longint):longint;
begin
  if x<y then min:=x else min:=y;
end;
//============================================================================
procedure tarjan(u:longint);
var v,i:longint;
begin
  inc(time); dfn[u]:=time; low[u]:=time;
  inc(tot); stack[tot]:=u; i:=en[u];
  sta[u]:=true; p[u]:=true;
  while i<>0 do
  begin v:=line[i];
    if not(p[v]) then    //是p数组，不是sta数组。
    begin
      tarjan(v);
      low[u]:=min(low[v],low[u]);
    end else
    if sta[v] then
      low[u]:=min(dfn[v],low[u]);
    i:=next[i];
  end;
  if dfn[u]=low[u] then
  begin inc(size);
    repeat
      v:=stack[tot]; dec(tot);
      fa[v]:=size; inc(sum[size]);
      sta[v]:=false;
    until u=v;
  end;
end;
//============================================================================
procedure init;
var m,i,x,y:longint;
begin
  readln(n,m);
  for i:=1 to m do
  begin
    readln(x,y);
    inc(len); line[len]:=y;
    next[len]:=en[x]; en[x]:=len;
  end;
end;
//============================================================================
procedure main;
var i,u,v,ans,int:longint;
begin
  fillchar(p,sizeof(p),0);
  size:=0;
  for i:=1 to n do
    if not(p[i]) then
    begin
      time:=0;
      tarjan(i);
    end;
  for u:=1 to n do
  begin i:=en[u];
    while i<>0 do
    begin v:=line[i];
      if fa[v]<>fa[u] then inc(cd[fa[u]]);
      i:=next[i];
    end;
  end; ans:=0; int:=0;
  for i:=1 to size do
    if cd[i]=0 then
    begin
      inc(ans,sum[i]);
      inc(int);
    end;
  if int=1 then writeln(ans) else
    writeln('0');
end;
//============================================================================
begin
  init;
  main;
end.