ALV 可编辑性（一）

SAP_亮亮

已于 2024-05-13 08:51:52 修改

阅读量1.4k

点赞数 25

于 2024-05-13 08:47:55 首次发布

本文链接：https://blog.csdn.net/Leo520liang/article/details/138783522

版权

Abap开发同时被 2 个专栏收录

20 篇文章 2 订阅

订阅专栏

FM ALV

16 篇文章 1 订阅

订阅专栏

前言

在ABAP ALV中，使列表具有可编辑性意味着允许用户直接在列表中修改数据，这对于交互式数据处理和快速数据更新非常有用。具体实现可分为整体可编辑、列可编辑和单元格可编辑。

实战

整体可编辑：

通过layout（slis_layout_alv）中的edit参数来设置整个网格（所有单元格）是否可编辑：
gs_layout-edit = 'X'.

列可编辑：

通过fieldcat中的edit参数来设置某列是否可编辑：
gs_fieldcat-edit = 'X'.

单元格可编辑：

        只能使用REUSE_ALV_GRID_DISPLAY_LVC，一般配置步骤如下：
            1、在输出内表中加上可编辑信息内表；
               cellstyles TYPE lvc_t_styl.
           2、先将对应的单元格设置为可编辑状态；
               gt_fieldcat-edit = 'X'.
           3、将原本可编辑的单元格切换到不可编辑（样式）；
               gs_style-style = cl_gui_alv_grid=>mc_style_disabled. "置灰
   注意：这里只是样式的切换，不能仅使用cl_gui_alv_grid=>mc_style_enabled来将单元格设置为可编辑状态，单元格真正是否可编辑是由fieldcat-edit或layout-edit来决定的，而仅设置为cl_gui_alv_grid=>mc_style_enabled是不可编辑的。

       下面这两行是常量, 你可以选择给他固定值,或者直接调用cl_gui_alv_grid中的常量
       cl_gui_alv_grid=>mc_style_disabled. "不可编辑初始值 '00100000'
         cl_gui_alv_grid=>mc_style_enabled. "可编辑初始值 '00080000'

核心代码：

*数据定义-内表中加lvc_t_styl类型的列
DATA:
 BEGIN OF gs_spfli  .
        INCLUDE TYPE spfli.
DATA   cellstyles TYPE lvc_t_styl.
DATA
END OF gs_spfli.
DATA: gs_style TYPE lvc_s_styl,
      gt_style TYPE lvc_t_styl.
*设置条件置灰列
  LOOP AT gt_data.
    IF gt_data-carrid NE 'AA' .
      gs_style-fieldname = 'DISTANCE'.
      gs_style-style = cl_gui_alv_grid=>mc_style_disabled. "置灰
      APPEND gs_style TO  gt_style.
      gt_data-cellstyles = gt_style.
      MODIFY gt_data.
      CLEAR gt_style.
    ENDIF.
  ENDLOOP.
*对fieldcat属性的修改
  gt_fieldcat-edit = 'X'.
*对layout设置可编辑信息内表
  gs_layout-stylefname = 'CELLSTYLES'."数据内表中哪列为可编辑信息内表

案例

展示效果：

完整代码：

*数据定义
DATA:
 BEGIN OF gs_spfli  .
        INCLUDE TYPE spfli.
DATA   cellstyles TYPE lvc_t_styl.
DATA
END OF gs_spfli.

DATA: gt_fieldcat TYPE TABLE OF lvc_s_fcat WITH HEADER LINE,
      gs_layout TYPE  lvc_s_layo.

DATA: gt_data LIKE TABLE OF gs_spfli WITH HEADER LINE.

DATA: gs_style TYPE lvc_s_styl,
      gt_style TYPE lvc_t_styl.

START-OF-SELECTION.
  PERFORM f_getdata.
  PERFORM f_catalog.
  PERFORM f_alvshow.

FORM f_getdata .
  SELECT * INTO CORRESPONDING FIELDS OF TABLE gt_data FROM spfli.
*设置条件置灰列
  LOOP AT gt_data.
    IF gt_data-carrid NE 'AA' .
      gs_style-fieldname = 'DISTANCE'.
      gs_style-style = cl_gui_alv_grid=>mc_style_disabled. "置灰
      APPEND gs_style TO  gt_style.
      gt_data-cellstyles = gt_style.
      MODIFY gt_data.
      CLEAR gt_style.
    ENDIF.
  ENDLOOP.
ENDFORM.                    " F_GETDATA

FORM f_catalog .
  CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
    EXPORTING
*     I_BUFFER_ACTIVE        =
      i_structure_name       = 'SPFLI'
*     I_CLIENT_NEVER_DISPLAY = 'X'
*     I_BYPASSING_BUFFER     =
*     I_INTERNAL_TABNAME     =
    CHANGING
      ct_fieldcat            = gt_fieldcat[]
    EXCEPTIONS
      inconsistent_interface = 1
      program_error          = 2
      OTHERS                 = 3.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
    WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.

  CLEAR gt_fieldcat.
*"对gt_fieldcat属性的修改
  READ TABLE gt_fieldcat  INDEX 13.
  gt_fieldcat-edit = 'X'.
  MODIFY gt_fieldcat  INDEX 13.
*对layout设置可编辑信息内表
  gs_layout-zebra = 'X'.
*  GS_LAYOUT-EDIT = 'X'.
  gs_layout-cwidth_opt = 'X'.
  gs_layout-stylefname = 'CELLSTYLES'."数据内表中哪列为可编辑信息内表
ENDFORM.                    " F_CATALOG

FORM f_alvshow .
  CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY_LVC'
    EXPORTING
      i_callback_program = sy-repid
      is_layout_lvc      = gs_layout
      it_fieldcat_lvc    = gt_fieldcat[]
    TABLES
      t_outtab           = gt_data[].
ENDFORM.                    " F_ALVSHOW

备注：后续继续分享动态单元格可编辑性，以及修改后的ALV自动刷新功能，敬请期待。