文章标题

微机原理实验 系列

        实验三  并行I/O接口的扩展

这次挺有意思，需要在实验箱上接接线，可以看到LED等和数码管的显示，成就感满满的！
（一）A口输出 C口输入

DATA SEGMENT
LED     DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H
        DB 7FH,67H,77H,7CH,39H,5EH,79H,71H
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA
START:  MOV AX,DATA
        MOV DS,AX
        MOV DX,0E48BH
        MOV AL,89H
        OUT DX,AL
INOUT:  MOV DX,0E48AH
        IN AL,DX
        AND AL,0FH
        MOV BX,OFFSET LED
        XLAT
        MOV DX,0E488H
        OUT DX,AL
        MOV AH,1
        INT 16H
        JZ INOUT
        MOV AH,4CH
        INT 21H
CODE ENDS
END START

（二）A口输入 C口输出

DATA SEGMENT
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA
START:  MOV AX,DATA
        MOV DS,AX     ;初始化DS
        MOV DX,0E48BH
        MOV AL,90H    ;设置方式控制字，A口输入，C口输出
        OUT DX,AL
INOUT:  MOV DX,0E488H    ;设置8255A工作方式
        IN AL,DX    ;A口输入
        MOV BL,0    ;计数变量，用于记录输入的高电平个数
        MOV CH,0    ;循环变量，每次查看最低位并不断右移，通过循环变量来判断是否已经完成统计
NEXT:   CMP CH,8
        JZ EXIT    ;所有位已统计完毕，跳出循环
        INC CH    ;循环变量加一
        MOV AH,AL
        AND AH,1    ;取出最低位
        CMP AH,0    ;进行判断是否是一
        JZ LL    ;若是零，说明此位输入的是低电平，计数变量不改变
        INC BL    ;说明此位输入的是高电平，计数变量加一
LL:     MOV CL,1
        SHR AL,CL    ;右移一位，用于下轮判断
        JMP NEXT    ;开始下一轮循环
EXIT:   MOV AL,BL     ;此时BL中存放的是输入中高电平的个数
        MOV DX,0E48AH      ;设置8255A工作方式
        OUT DX,AL    ;C口输出
        MOV AH,1
        INT 16H
        JZ INOUT     ;无按键转移
        MOV AH,4CH      ;有按键则返回DOS
        INT 21H
CODE ENDS
END START

（三）A口输出 C口输入

DATA SEGMENT
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA
START:  MOV AX,DATA
        MOV DS,AX     ;初始化DS
        MOV DX,0E48BH
        MOV AL,89H    ;设置方式控制字，A口输出，C口输入
        OUT DX,AL
INOUT:  MOV DX,0E48AH     ;设置8255A工作方式
        IN AL,DX    ;C口输入
        MOV BL,AL    ;先保存原输入
        AND AL,0FH     ;取出低四位
        MOV CL,4
        SHR BL,CL    ;将保留的原输入右移四位
        AND BL,0FH     ;取出低四位
        ADD AL,BL    ;求和
        DAA     ;转BCD码
        MOV DX,0E488H
        OUT DX,AL    ;A口输出
        MOV AH,1
        INT 16H
        JZ INOUT    ;无按键转移
        MOV AH,4CH    ;有按键则返回DOS
        INT 21H
CODE ENDS
END START

（四）A口输出 C口输入

DATA SEGMENT
        LED DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H
            DB 7FH,67H,77H,7CH,39H,5EH,79H,71H
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA
START:  MOV AX,DATA
        MOV DS,AX
        MOV DX,0E48BH     ;设置8255A工作方式
        MOV AL,80H    ;A口输出，C口输出
        OUT DX,AL
INOUT:  MOV DI,0    ;循环变量，0~F，此处是第一个循环，控制S0数码管
LL1:    CMP DI,10H
        JZ NEXT    ;循环结束，进入第二个循环，控制S1数码管
        MOV AL,1     ;设置A口输出的S0数码管显示
        MOV DX,0E488H
        OUT DX,AL    ;A口输出
        AND DI,0FH    ;取出DI低四位
        MOV AX,DI
        MOV BX,OFFSET LED
        XLAT     ;换码DS:[BX+AL]
        MOV DX,0E48AH
        OUT DX,AL     ;C口输出
        MOV AH,86H
        MOV CX,5
        MOV DX,0
        INT 15H    ;设置延迟
        INC DI    ;循环变量递增
        JMP LL1     ;返回循环开始
NEXT:   MOV DI,0     ;循环变量
LL2:    CMP DI,10H
        JZ INOUT    ;循环结束
        MOV AL,2    ;设置A口输出的S1数码管显示
        MOV DX,0E488H
        OUT DX,AL    ;A口输出
        AND DI,0FH
        MOV AX,DI
        MOV BX,OFFSET LED
        XLAT     ;换码DS:[BX+AL]
        MOV DX,0E48AH
        OUT DX,AL     ;C口输出
        MOV AH,86H
        MOV CX,5
        MOV DX,0
        INT 15H     ;设置延迟
        INC DI    ;循环变量递增
        JMP LL2
        MOV AH,1
        INT 16H
        JZ INOUT     ;无按键转移
        MOV AH,4CH      ;有按键则返回DOS
        INT 21H
CODE ENDS
END START

（五）秒表（利用数码管显示）

DATA SEGMENT
LED     DB 3FH,06H,5BH,4FH,66H,6DH,7DH,07H
        DB 7FH,67H,77H,7CH,39H,5EH,79H,71H
DATA ENDS

CODE SEGMENT
        ASSUME CS:CODE,DS:DATA
START:  MOV AX,DATA
        MOV DS,AX     ;初始化DS
        MOV DX,0E48BH
        MOV AL,80H    ;A口输出，C口输出
        OUT DX,AL
        MOV BX,0   ;BL用于秒表个位计数，BH用于秒表高位计数
INOUT:  MOV DI,0   ;循环变量，用于刷新
NEXT:   MOV AL,1   ;秒表个位，控制S0数码管
        MOV DX,0E488H    ;设置A口输出
        OUT DX,AL
        MOV DX,0E48AH    ;设置C口输出个位数字
        PUSH BX    ;保存BX
        MOV AL,BL
        MOV BX,OFFSET LED
        XLAT     ;换码
        OUT DX,AL
        POP BX    ;恢复BX
        MOV AH,86H    ;延迟
        MOV CX,0
        MOV DX,1400H   ;延迟1/64s
        INT 15H
        MOV AL,2     ;秒表十位，控制S1数码管
        MOV DX,0E488H      ;设置A口输出
        OUT DX,AL
        MOV DX,0E48AH      ;设置C口输出十位数字
        PUSH BX     ;保存BX
        MOV AL,BH
        MOV BX,OFFSET LED
        XLAT    ;换码
        OUT DX,AL
        POP BX    ;恢复BX
        MOV AH,86H    ;延迟
        MOV CX,0
        MOV DX,1400H    ;延迟1/64s
        INT 15H
        INC DI   ;开始循环，刷新数码管
        CMP DI,32    ;循环次数
        JNZ NEXT
        INC BL    ;一秒显示结束
        CMP BL,10
        JL EXIT
        MOV BL,0   ;十秒结束，需改变十位,并使个位归零
        INC BH
        CMP BH,10
        JL EXIT    ;一百秒结束，归零，重新开始循环
        MOV BH,0
EXIT:   MOV AH,1
        INT 16H
        JZ INOUT    ;无按键转移
        MOV AH,4CH     ;有按键则返回DOS
        INT 21H
CODE ENDS
END START