日常训练20161013 括号表达式

题意：统计长度为$n(2~\le~n~\le~200)$，深度为$k(1~\le~k~\le~150)$的合法括号表达式的数目。

法一：用$f[i][j][k]$表示前i位，最深深度为$j$，当前深度为$k$的方案数。枚举第$i+1$位左括号还是右括号，$O(1)$转移。总复杂度$O(nd^2)$。

var
  f:array[0..201,-1..151,-1..151] of int64;
  n,d,i,j,k:longint;
begin
  assign(input,'bracket.in');reset(input);
  assign(output,'bracket.out');rewrite(output);
  read(n,d);
  fillchar(f,sizeof(f),0);
  f[0][0][0]:=1;
  for i:=0 to n-1 do
    for j:=0 to d do
      for k:=0 to d do
        begin
          inc(f[i+1][j][k-1],f[i][j][k]);
          inc(f[i+1][j+ord(k+1>j)][k+1],f[i][j][k]);
        end;
  writeln(f[n][d][0]);
  close(input);close(output);
end.

法二：$f[i][j]$表示$i$个位置，深度小于等于$j$的方案数，为了避免重复计数，枚举分割点的时候强制给右半段套上一个括号（其实就是枚举当前段最右边括号的左括号在哪里）。状态$O(n^2)$，记忆化搜索，总复杂度$O(n^2)$。

var
  f:array[0..201,0..151] of int64;
  n,d,i,j:longint;
function calc(n,d:longint):int64;
  var
    i:longint;
  begin
    if (n=0) then exit(1);
    if (d=0) then exit(0);
    if (f[n][d]>0) then exit(f[n][d]);
    i:=0;
    while (i<n) do
      begin
        inc(f[n][d],calc(i,d)*calc(n-i-2,d-1));
        inc(i,2);
      end;
    exit(f[n][d]);
  end;
begin
  assign(input,'bracket.in');reset(input);
  assign(output,'bracket.out');rewrite(output);
  read(n,d);
  if (n and 1=1)
    then writeln(0)
    else writeln(calc(n,d)-calc(n,d-1));
  close(input);close(output);
end.