【题解】LuoGu2161： [SHOI2009]会场预约

原题传送门
题目描述

PP大厦有一间空的礼堂，可以为企业或者单位提供会议场地。这些会议中的大多数都需要连续几天的时间（个别的可能只需要一天），不过场地只有一个，所以不同的会议的时间申请不能够冲突。也就是说，前一个会议的结束日期必须在后一个会议的开始日期之前。所以，如果要接受一个新的场地预约申请，就必须拒绝掉与这个申请相冲突的预约。 一般来说，如果PP大厦方面事先已经接受了一个会场预约，例如从10日到15日，就不会在接受与之相冲突的预约，例如从12日到17日。不过，有时出于经济利益，PP大厦方面有时会为了接受一个新的会场预约，而拒绝掉一个甚至几个之前预订的预约。 于是，礼堂管理员QQ的笔记本上笔记本上经常记录着这样的信息： 本题中为方便起见，所有的日期都用一个整数表示。例如，如果一个为期10天的会议从“90日”开始到“99日”，那么下一个会议最早只能在“100日”开始。 最近，这个业务的工作量与日俱增，礼堂的管理员QQ希望参加SHTSC的你替他设计一套计算机系统，方便他的工作。这个系统应当能执行下面两个操作： A操作：有一个新的预约是从“start日”到“end日”，并且拒绝掉所有与它相冲突的预约。执行这个操作的时候，你的系统应当返回为了这个新预约而拒绝掉的预约个数，以方便QQ与自己的记录相校对。 B操作：请你的系统返回当前的仍然有效的预约的总数。
输入输出格式
输入格式：

输入文件的第一行是一个整数n，表示你的系统将接受的操作总数。 接下去n行每行表示一个操作。每一行的格式为下面两者之一： “A start end”表示一个A操作； “B”表示一个B操作。

输出格式：

输出文件有n行，每行一次对应一个输入。表示你的系统对于该操作的返回值。

输入样例
6
A 10 15
A 17 19
A 12 17
A 90 99
A 11 12
B
输出样例
0
0
2
0
1
2

说明

N< = 200000

1< = Start End < = 100000

用上树状数组
对于A操作，一直在0~end的区间内找最大的前面还存在的start，直到与自己不再相交为止
树状数组查找区间第k大，总共时间复杂度$O(nlo{g}^{2}n)$

Code：

//e[s]表示起始位置为s的结束时间，不会同时出现两个相同的s，因为一旦如此，就会撤销掉前面那个会议
const
    maxn = 200005;
var
    tree, e : array[0..maxn] of longint;
    ch, kong : char;
    n, x, y, i, p, print, alive, z : longint;

procedure add(x, y : longint);

begin
    while x <= maxn do
    begin
        inc(tree[x], y);
        inc(x, x and -x);
    end;
end;

function query(x : longint) : longint;

begin
    query := 0;
    while x > 0 do
    begin
        inc(query, tree[x]);
        dec(x, x and -x);
    end;
end;

function find(x, y : longint) : longint;
var
    l, r, mid : longint;

begin
    l := 0; r := y;
    find := 0;
    while l <= r do
    begin
        mid := (l + r) >> 1;
        if query(mid) >= x then
        begin
            r := mid - 1;
            find := mid;
        end else l := mid + 1;
    end;
end;

begin
    readln(n);
    for i := 1 to n do
    begin
        read(ch);                                               
        if ch = 'A' then
        begin
            readln(kong, x, y);
            print := 0;
            p := query(y);
            while true do
            begin
                z := find(p - print, y);//查找0~end中起始位置最后的
                if e[z] >= x then//一旦找到的区间与自己不相交，就退出
                //因为我们现在保证的是起始位置要递减的，且还存在的每个区间是不相交的，所以下一个的end比当前的start还小，更加不可能
                begin
                    add(z, -1);
                    inc(print);
                    dec(alive);
                end else break;
            end;
            add(x, 1); inc(alive);
            e[x] := y;
            writeln(print);
        end else
        begin
            writeln(alive);
            readln;
        end;
    end;
end.