winscp将windows文件传输到linux服务器

首先是备份orcal数据库

winscp将windows文件传输到linux服务器

链接: https://pan.baidu.com/s/1U0GnbZIG9xpIZqozFuoSEw 提取码: uy49

@echo off   
echo ================================================   
echo  Windows环境下Oracle数据库的自动备份脚本  
echo  1. 使用当前日期命名备份文件。  
echo  2. 自动删除7天前的备份。  
echo ================================================  
::以“YYYYMMDD”格式取出当前时间。  
set BACKUPDATE=%date:~0,4%%date:~5,2%%date:~8,2%
::设置用户名、密码和要备份的数据库。  
set USER=数据库用户名
set PASSWORD=数据库密码
set DATABASE=ORCL
::创建备份目录
if not exist "D:\backup\data"       mkdir D:\backup\data  
if not exist "D:\backup\log"        mkdir D:\backup\log  
set DATADIR=D:\backup\data
set LOGDIR=D:\backup\log

exp %USER%/%PASSWORD%@%DATABASE%  file=%DATADIR%\data_%BACKUPDATE%.dmp log=D:\backup\log\log_%BACKUPDATE%.log
::删除7天前的备份。  
forfiles /p "%DATADIR%" /s /m *.* /d -7 /c "cmd /c del @path"  
forfiles /p "%LOGDIR%" /s /m *.* /d -7 /c "cmd /c del @path"  

:: 设置winscp目录
SET rootPath=F:\WinScp
:: 设置服务器路径
SET sftpPath=scp://用户名:密码@ip地址
:: 设置里Linux目录
SET targetFilePath=/home/soft/
:: 日志文件存储路径
SET logFileName=D:\backup\log\winscp_%BACKUPDATE%.log

:: 命令行用到的变量，无需更改
:: 本地文件路径(windows)
SET localFilePath=%DATADIR%\data_%BACKUPDATE%.dmp
:: 本地日志标志
SET logPath=/log
cd /d %rootPath%
winscp.exe /console /command "option batch continue" "option confirm off" "open %sftpPath%" "option transfer binary" "put %localFilePath% %targetFilePath%" "exit" %logPath%=%logFileName%

:: 命令解析
:: winscp.exe /console /command "option batch continue" "option confirm off" "open sftp://user:pwd@ip:port" "option transfer binary" "put D:\需要上传的文件路径 /服务器文件存放目录" "exit" /log=log_file.txt

:: winscp.exe /console /command	---命令名
:: "option batch continue"	---默认批处理
:: "option confirm off"	---关闭提示信息
:: "open ftp://user:pwd@ip:port user"	---访问用户名 ，pwd:用户密码 ，ip:ip地址，port：端口号 默认22
:: "option transfer binary" ---使用二进制格式传送
:: log=log_file.txt ---日志文件地址
:: "exit"	---运行完退出


exit