王爽汇编课程设计2(完整代码＋虚拟机演示)

最新推荐文章于 2024-03-19 22:12:16 发布
最新推荐文章于 2024-03-19 22:12:16 发布
阅读量265 收藏 2
点赞数
分类专栏： 汇编
版权声明：本文为博主原创文章，遵循 CC 4.0 BY-SA 版权协议，转载请附上原文出处链接和本声明。
本文链接：https://blog.csdn.net/NoahBBQ/article/details/108807647
版权

终于把完整代码写了，太懒了。

assume cs:code,ds:data,ss:stack

data segment
   db 128 dup(0)
data ends

stack segment
  db 128 dup(0)
stack ends

code segment
    start: mov ax,stack
           mov ss,ax
           mov sp,128

           mov bx,offset Boot_end-offset Boot

           call cpy_introduce_toDiskA
           call cpy_boot_toDiskA

           mov ax,4c00h
           int 21h
;=======================================================
introduce:
          mov bx,0
          mov ss,bx
          mov sp,7c00h

          call sav_old_int9
          call cpy_boot_FromDiskA

          mov bx,0
          push bx
          mov bx,7e00h
          push bx
          retf
;======================================================
cpy_boot_FromDiskA:
          mov bx,0
          mov es,bx
          mov bx,7e00h

          mov al,2    ;读取的扇区数
          mov ch,0    ;磁道号
          mov cl,2    ;扇区号
          mov dl,0    ;驱动器号，0:软驱A
          mov dh,0    ;磁头号(对于软盘即面号，因为一个面用一个磁头来读写)
          mov ah,2    ;2表示读扇区,3表示写扇区
          int 13h
     
          ret
;=======================================================
sav_old_int9:
             mov bx,0
             mov es,bx

             push es:[9*4]
             pop es:[200h]
             push es:[9*4+2]
             pop es:[202h]

             ret


          db 512 dup(0)
         
introduce_end:nop
;=======================================================
cpy_introduce_toDiskA:
            mov bx,cs  
            mov es,bx
            mov bx,offset introduce

            mov al,1   ;读取的扇区数
            mov ch,0   ;磁道号
            mov cl,1   ;扇区号
            mov dl,0   ;磁头号(面号)
            mov dh,0   ;软驱A
            mov ah,3   ;写扇区  ,软驱A 0道0面1扇区
            int 13h
            
            ret


;======================================================
 cpy_boot_toDiskA: 
            mov bx,cs
            mov es,bx
            mov bx,offset Boot

            mov al,2
            mov ch,0
            mov cl,2
            mov dl,0
            mov dh,0
            mov ah,3
            int 13h

            ret


;======================================================
Boot:      jmp BOOT_START

;======================================================
;======================================================
;======================================================

OPTION_1     db '1) reset pc ',0      ;show_string
OPTION_2     db '2) start system ',0
OPTION_3     db '3) clock',0
OPTION_4     db '4) set clock ',0


ADDRESS_OPTION dw  offset OPTION_1-offset Boot + 7e00h  ;ADDRESS_OPTION[0]
               dw  offset OPTION_2-offset Boot + 7e00h
               dw  offset OPTION_3-offset Boot + 7e00h
               dw  offset OPTION_4-offset Boot + 7e00h


TIME_CMOS      db 9,8,7,4,2,0
TIME_STYLE     db 'YY/MM/DD HH:MM:SS',0

STRING_STACK   db 12 dup('0'),0  
;======================================================
;======================================================
;======================================================
BOOT_START: call init_reg
            call clear_screen
            call show_option

            jmp choose_option
               
            mov ax,4c00h
            int 21h
;=====================================================
choose_option:
            call clear_buff
            mov ah,0
            int 16h
            cmp al,'1'
            je isChooseOne
            cmp al,'2'
            je isChooseTwo
            cmp al,'3'
            je isChooseThree
            cmp al,'4'
            je isChooseFour
        
            jmp choose_option
;====================================================
isChooseOne:
            mov di,160*3
            mov byte ptr es:[di],'1'
            mov bx,0ffffh
            push bx
            mov bx,0
            push bx
            retf

            jmp choose_option
  
isChooseTwo:
            mov di,160*3
            mov byte ptr es:[di],'2'
            call start_system
            jmp choose_option

isChooseThree:
            mov di,160*3
            mov byte ptr es:[di],'3'
            call show_clock
            jmp BOOT_START    ;返回主屏幕

isChooseFour:
            mov di,160*3
            mov byte ptr es:[di],'4'
            call set_clock
            jmp choose_option

;====================================================
start_system:
             mov bx,0
             mov es,bx
             mov bx,7c00h

             mov al,1
             mov ch,0
             mov cl,1
             mov dl,80h
             mov dh,0
             mov ah,2
             int 13h

             mov bx,0
             push bx
             mov bx,7c00h
             push bx
             retf    ;pop ip=7c00h pop cx=0
             ret
;====================================================
set_clock:    call clear_string_stack
              call show_string_stack
              call get_string
              call set_time
              ret
;====================================================
set_time:    mov bx,offset TIME_CMOS-offset Boot +7e00H
             mov si,offset STRING_STACK-offset Boot+7e00h
             mov cx,6

setTime:     mov dx,ds:[si]                      ;ASCII码
             sub dh,30h                          ;ds:[si]=12
             sub dl,30h                          ;dh=2
             shl dl,1                            ;dl=1
             shl dl,1
             shl dl,1
             shl dl,1
             and dh,00001111b                  ;这步可以不要，不影响
             or dl,dh

             mov al,ds:[bx]
             out 70h,al
             mov al,dl
             out 71h,al                         ;把BCD码写入

             add si,2
             inc bx
             loop setTime
             ret
;====================================================

;====================================================
get_string:  mov si,offset STRING_STACK-offset Boot+7e00h
             mov bx,0                       ;Top

getString:   call clear_buff

             mov ah,0
             int 16h

             cmp al,'0'
             jb notNumber
             cmp al,'9'
             ja notNumber
             call char_push
             call show_string_stack

             jmp getString

getStringRet:ret                        ;这里大小写错了，找了20分钟
notNumber:   cmp ah,0eh
             je isBackSpace               ;BackSpace
             cmp ah,1ch
             je getStringRet
             jmp getString

isBackSpace:  call char_pop
              call show_string_stack
              jmp getString
;====================================================
char_pop:     cmp bx,0
              je charPopRet
              dec bx
              mov byte ptr ds:[si+bx],'0'
charPopRet:   ret
;====================================================
char_push:    cmp bx,11   ;记录字符个数，一共11个，最后一个当作0
              ja charPushRet
              mov ds:[si+bx],al
              inc bx
 
charPushRet:  ret

;====================================================
show_string_stack:
              push si
              push di

              mov si,offset STRING_STACK-offset Boot+7e00h
              mov di,160*4

              call show_string
              pop di
              pop si
              ret
;====================================================
clear_string_stack:
                push bx
                push cx
                push es
                push si
                push di

                mov si,offset STRING_STACK-offset Boot +7e00h
                mov dx,3030h

                mov cx,6      ;6*2=12个字符都是0

clearStringStack:
                mov ds:[si],dx
                add si,2
                loop clearStringStack

                pop di
                pop si
                pop es
                pop cx
                pop bx
                ret



;====================================================
show_clock: call show_style

            call set_new_int9

            mov bx,offset TIME_CMOS-offset Boot+7e00h

showTime:   mov si,bx
            mov di,160*20
            mov cx,6

showDate:   mov al,ds:[si]
            out 70h,al
            in al,71h

            mov ah,al
            shr ah,1
            shr ah,1
            shr ah,1
            shr ah,1
            and al,00001111b

            add ah,30h
            add al,30h

            mov es:[di],ah
            mov es:[di+2],al
            
            add di,6
            inc si
            loop showDate
            jmp showTime

showTimeRet:call set_old_int9

            ret
;====================================================
set_old_int9:
            push bx
            push es

            mov bx,0
            mov es,bx

            cli
            push es:[200h]
            pop es:[9*4]
            push es:[202h]
            pop es:[9*4+2]
            sti

            pop es
            pop bx
            ret
;====================================================
set_new_int9:
            push bx
            push es

            mov bx,0
            mov es,bx

            cli
            mov word ptr es:[9*4],offset new_int9-offset Boot+7e00h
            mov word ptr es:[9*4+2],0
            sti

            pop es
            pop bx
            ret
;====================================================
new_int9:  push ax
           
           call clear_buff

           in al,60h   ;把扫描码从60h端口读出
           pushf
           call dword ptr cs:[200h]

           cmp al,01h     ;Esc
           je isEsc
           cmp al,3bh
           jne int9Ret
           call change_time_color

int9Ret:   pop ax
           iret

isEsc:     pop ax
           add sp,4    ;刚开始中断的时候 标志寄存器入栈 if=0,tf=0，CS,IP入栈。所以栈顶要向下移4个字节，才是flag的正确值
           popf      
           jmp showTimeRet

           
;====================================================
change_time_color:
           push bx
           push cx
           push es

           mov bx,0b800h    ;这个地方又写成08b00,哎，真傻。
           mov es,bx
           mov bx,160*20+1

           mov cx,17
changeTimeColor:
           inc byte ptr es:[bx]
           add bx,2
           loop changeTimeColor

           pop es
           pop cx
           pop bx
           ret
;====================================================
show_style:
            mov si,offset TIME_STYLE-offset Boot +7e00h
            mov di,160*20

            call show_string
            ret
;====================================================
clear_buff: mov ah,1       ;用来查询键盘缓冲区，对键盘扫描但不等待
            int 16h        ;并设置ZF标志。若有按键操作（即键盘缓冲区不空）,zf=0,无键按下则zf=1
            jz clearBuffRet
            mov ah,0
            int 16h        ;清除键盘缓存区的字符
            jmp clear_buff

clearBuffRet:ret

show_option:
            mov bx,offset ADDRESS_OPTION - offset Boot + 7e00h
            mov di,160*10+30*2
            mov cx,4

showOption: mov si,ds:[bx]  ;si存放了OPTION_n的偏移地址
            call show_string
            add bx,2
            add di,160
            loop showOption

            ret
;=====================================================
show_string:push dx
            push ds
            push es
            push si
            push di

showString: mov dl,ds:[si]
            cmp dl,0
            je showStringRet
            mov es:[di],dl      ;es=0b800h
            add di,2
            inc si
            jmp showString

showStringRet:pop di
              pop si
              pop es
              pop ds
              pop dx
              ret
;=====================================================
clear_screen:
            mov bx,0
            mov dx,0700h   ;07h(黑底白字), 00表示无字符
            mov cx,2000
clearScreen:mov es:[bx],dx
            add bx,2
            loop clearScreen
            ret
;=====================================================
init_reg:   mov bx,0b800h
            mov es,bx
            
            mov bx,0
            mov ds,bx
            ret

            db 512 dup(0)

Boot_end: nop


             
;=======================================================
cpy_Boot:
           mov ax,cs
           mov ds,ax
           mov si,offset Boot

           mov bx,0
           mov es,bx
           mov di,7e00h

           mov cx,offset Boot_end-offset Boot
           cld 
           rep movsb

           ret
code ends
end start

下面是演示视频
在这里插入图片描述
这个程序总体可以分成两部分，一部分是引导程序，另一部分就功能得实现。在然后从上到下，慢慢细分。

NoahBBQ
关注
  • 0
    点赞
  • 踩
  • 2
    收藏
    觉得还不错? 一键收藏
  • 0
    评论
专栏目录
王爽《汇编语言》课程设计2（不涉及软盘版本）
weixin_41944412的博客
06-24 987
assume cs:code,ds:data,ss:stack stack segment db 128 dup (0) stack ends data segment db 256 dup (0) data ends code segment start: mov ax,stack mov ss,ax mov sp,128 ...
王爽 汇编语言第二版 课程设计2
01-20 2501
王爽汇编语言 课程设计2 掌握一门编程语言最重要的就是实践，王爽老的师的课程设计二，如果完整写出来要400行至800行代码，独立完成这个课程设计，会使你熟练16位汇编，掌握8086汇编精髓。这个课程设计不方便调试，独立完成的话要费一点时间，也许你会认为汇编已经过时了，没有必要浪费时间认真学，但是学习汇编语言，是解理计算机原理的捷径，汇编语言是万国语言的基础。如果只懂高级语言，那么只能做人家设计好...
汇编语言（第4版）王爽 课程设计2 详细实现（一、虚拟模式DOS运行篇）
最新发布
m0_73327328的博客
03-19 1902
由于虚拟模式的限制，我们编写的许多逻辑暂时不能被检验，而因为《汇编语言》编写时间较早，其所依赖的运行环境如今只能够依靠虚拟机来搭建。比如实模式DOS，搭建步骤比较繁琐，因此我将其它的部分放在下一篇文章中进行讲解。事实上，我们实现的程序属于《汇编语言》课程设计2中任务程序部分，其中的完整任务还涉及到将该任务程序安装到软盘等操作，这些也都需要在实模式下才能运行，所以统一放到下一篇文章进行实现。
汇编语言第三版王爽课程设计2
01-02
本程序基本实现了该课程设计的要求，可能还存在一些问题，有待改善
王爽汇编课程设计2
03-03
完全自我独立完成的王爽汇编语言课程设计2，虽然自我比较满意，比较完整，可以给初学者一个参考，大虾们也可提提建议。 （本程序在Virtual PC 上通过，杀毒软件提示病毒，但具体原因你知道的，请不要担心）
汇编语言-王爽-课程设计2——并使用Bochs实现演示效果
goodcrony的博客
06-15 1330
使用工具： 1、DOSBox 0.74，用于编译程序，测试程序主要功能 2、Bochs 2.6.9，用于模拟加载软盘，使用软盘或者硬盘启动系统 3、Linux虚拟机，用于虚拟软化读写，实现和bochs中的dos虚拟机进行数据交互 演示结果： 程序1效果： 程序2效果： 程序4效果： 程序3效果： 操作流程： 1、DOSBox编译程序生成kcsj2.exe ...
王爽《汇编语言》课程设计2源程序.asm
08-25
王爽《汇编语言》课程设计2源程序.asm。测试环境：VMware创建XP虚拟机和软盘镜像，运行编译后的可执行文件.exe。重启XP虚拟机查看效果。
王爽《汇编语言第2版》课程设计2原代码
04-23
这个代码用masm编译，用link连接成一个exe文件，在纯DOS下运行后，就能用软盘进行启动。代码比课本要求多了一个功能，就是可以用光带移动来选择菜单。代码浅显易懂，而且配有大量的注释。
王爽汇编中课程设计2
08-18
《王爽汇编中课程设计2》是一份深入学习汇编语言的重要参考资料，它由知名计算机科学家王爽教授精心设计，旨在帮助学习者巩固和深化对汇编语言的理解。汇编语言是计算机科学的基础，是程序员与硬件直接对话的语言，...
王爽——汇编课程设计一
03-20
王爽----汇编语言 课程设计一（含代码）
vmware王爽汇编语言学习环境搭建
04-12
windows10中最强大王爽汇编语言学习环境 使用说明： http://blog.csdn.net/vs9841/article/details/49047599
王爽 汇编语言 第二版 课程设计二
04-20
王爽 汇编语言 第二版 从课程设计二 该程序需在虚拟机上实现，因为要对硬盘进行读写，如果在真机上实现，可能会损坏硬盘上数据。
王爽《汇编语言》的源代码
10-18
王爽写的汇编语言的源代码，全部是书本上的配套的源程序，希望对大家有所帮助，也非常感谢使用
王爽汇编语言课程设计2
Control Complexity
05-18 1030
王爽汇编语言 第二版 课程设计2编写一个可以自行启动的计算机，不需要在现有操作系统环境中运行的程序一、相关资料 系统启动初始化完成后最终调用19h，该中断读取软盘的第一扇区或硬盘的第一扇区到0:7c00开始的512个字节的内存空间中，并将cs:ip指向0:7c00执行。 更详细参考王爽汇编语言第二版，课程设计2，p.312二、设计思路将安装程序分为三个段， 1、第一个段为安装程序，负责将第二个段写入
王爽课程设计2的ASM代码
feekee的自留研习地
08-09 568
如下： assume cs:codesg,ds:datasg,ss:stacksg datasg segment db 4 dup (0) datasg ends stacksg segment dw 32 dup (0) stacksg ends codesg segment start:;write to the floppy mov ax,cs mov es,a
王爽汇编语言课程设计1
06-11
王爽的汇编语言课程设计1是一道比较经典的大学汇编语言课程设计题目，其内容为实现一个简单的计算器程序。该程序的功能要求如下： 1. 实现加、减、乘、除四则运算。 2. 实现二进制、十进制、十六进制之间的转换。 ...

“相关推荐”对你有帮助么？

  • 非常没帮助
  • 没帮助
  • 一般
  • 有帮助
  • 非常有帮助
提交
评论
添加红包

请填写红包祝福语或标题

个

红包个数最小为10个

元

红包金额最低5元

当前余额3.43元 前往充值 >
需支付：10.00元
成就一亿技术人!
领取后你会自动成为博主和红包主的粉丝 规则
hope_wisdom
发出的红包
实付元
使用余额支付
点击重新获取
扫码支付
钱包余额 0

抵扣说明：

1.余额是钱包充值的虚拟货币，按照1:1的比例进行支付金额的抵扣。
2.余额无法直接购买下载，可以购买VIP、付费专栏及课程。

余额充值