【bzoj1047】【单调队列】【HAOI2007】理想的正方形

Description

有一个a*b的整数组成的矩阵，现请你从中找出一个n*n的正方形区域，使得该区域所有数中的最大值和最小值的差最小。

Input

第一行为3个整数，分别表示a,b,n的值第二行至第a+1行每行为b个非负整数，表示矩阵中相应位置上的数。每行相邻两数之间用一空格分隔。

Output

仅一个整数，为a*b矩阵中所有“n*n正方形区域中的最大整数和最小整数的差值”的最小值。

Sample Input

5 4 2
1 2 5 6
0 17 16 0
16 17 2 1
2 10 2 1
1 2 2 2

Sample Output

1

HINT

问题规模

（1）矩阵中的所有数都不超过1,000,000,000

（2）20%的数据2<=a,b<=100,n<=a,n<=b,n<=10

（3）100%的数据2<=a,b<=1000,n<=a,n<=b,n<=100

求滑动区间的最值，自然想到要用单调队列，只是变成了二维的罢了。先竖着跑（把长度为n的一段给“连起来”），再横着跑（横着把连完后的“竖段”给连起来），这样就得到了各个矩阵中的最值了。

var
  f,f1,f2:array[1..1000,1..1000]of longint;
  d,w:array[1..1000]of longint;
  a,b,n,i,j,l,r,ans:longint;
 
procedure qmax;
begin
  for i:=1 to a do
  begin
    l:=1; r:=0;
    for j:=1 to b do
    begin
      while (l<=r)and(d[r]<=f1[i,j]) do dec(r);
      inc(r); d[r]:=f1[i,j]; w[r]:=j;
      while (l<=r)and(w[l]<j-n+1) do inc(l);
      f1[i,j]:=d[l];
    end;
  end;
 
  for j:=1 to b do
  begin
    l:=1; r:=0;
    for i:=1 to a do
    begin
      while (l<=r)and(d[r]<=f1[i,j]) do dec(r);
      inc(r); d[r]:=f1[i,j]; w[r]:=i;
      while (l<=r)and(w[l]<i-n+1)do inc(l);
      f1[i,j]:=d[l];
    end;
  end;
end;
 
begin
  readln(a,b,n);
  for i:=1 to a do
  for j:=1 to b do
    read(f[i,j]);
 
  f1:=f;
  qmax;
  f2:=f1;
 
  for i:=1 to a do
  for j:=1 to b do
    f1[i,j]:=-f[i,j];
 
  qmax;
  ans:=maxlongint;
  for i:=n to a do
  for j:=n to b do
  if f1[i,j]+f2[i,j]<ans then
    ans:=f1[i,j]+f2[i,j];
 
  writeln(ans);
end.