《汇编语言》王爽——第九章 实验9

本题是想让我们编写一个程序

在屏幕中间分别显示绿色,绿底红色,白底蓝色的字符串'welcome to masm'

 

通过阅读分析得知,我们需要将字符串以及颜色属性写入到显示缓存区(显存)，运行程序的时候就会自动显示在界面上面。

而显存的内存地址是B8000H-BFFFFH之间，也就是说只要向这段空间写入数据都会显示出来。

分析：

1.要想在屏幕中间显示，我们需要算出地址.

由于总共是80列*25行，所以我们要在第11行，12行，13行的中间段写入数据，这样就能显示到中间来了。又因为每行有80个字符,我们需要写16个字符(16个字节的字符串+16字节的颜色属性),所以前32后32中间刚好16,这样就可以计算了：我们要放到位置也就是第一个w的位置是：160*11+64=1824,1824转化为16进制是720，720+b8000=b8720H.

也即是在b8720h这个位置开始写第一个'w'

2.注意格式，低位写入的是字符串（ASCLL码）高位写入颜色属性

3.计算颜色属性.三种颜色16进制码如下

db 02h,24h,71h

4.代码逻辑

我这里用了两重循环：大循环三次,分别对于三行；小循环十六次，对应16个字节的字符串以及16字（32字节）的目标地址。

完整代码如下:

assume cs:code,ds:data,ss:stack
data segment
db 'welcome to masm!'  ;定义显示的字符串(16字节)
db 02h,24h,71h		   ;定义三种颜色属性 
data ends

stack segment ;栈段用来存放cx做多重循环
dw 8 dup(0)
stack ends

code segment
start:
mov ax,data
mov ds,ax
mov ax,stack
mov ss,ax
mov sp,10h

mov bx,0
mov ax,0b872h  		  ;算出中间位置段地址
mov es,ax
mov bp,10h ;作为颜色数据的指针
mov cx,3  			  ;3次大循环
s:
push cx
mov si,0;作为字符串的指针
mov di,0;作为目标地址的指针
mov cx,16 ;小循环16次

s0:
mov al,ds:[si] ;获取字符串的数据
mov es:[di+bx],al ;将字符串的数据低位保存到目标地址
inc di 		   ;目标地址前进
mov al,ds:[bp] ;获取颜色属性数据
mov es:[di+bx],al ;将颜色属性数据高位保存到目标地址
inc di		   ;目标地址前进
inc si         ;字符串前进
loop s0

pop cx 
add bx,0a0h ;进行下一行
inc bp     ;颜色也要变化
loop s 
mov ax,4c00h
int 21h

code ends 
end start